DateTimePicker appears flat

private void OverrideDropDown(Graphics g)
 {
            if (!this.ShowUpDown)
            {
                Rectangle rect = new Rectangle(this.Width - DropDownButtonWidth, 0, DropDownButtonWidth, this.Height);
                ControlPaint.DrawComboButton(g, rect, ButtonState.Flat);
            }
            else
            {
                Rectangle rect = new Rectangle(this.Width - DropDownButtonWidth,
                    0, DropDownButtonWidth, this.Height/2);
                ControlPaint.DrawScrollButton(g, rect, ScrollButton.Up, ButtonState.Flat);
                rect.Y += this.Height / 2;
                ControlPaint.DrawScrollButton(g, rect, ScrollButton.Down, ButtonState.Flat);
         
            }
        }

[DllImport("user32.dll", CharSet = CharSet.Auto)]
private static extern IntPtr SendMessage(IntPtr hwnd, int Msg, IntPtr wParam, IntPtr lParam);

...
SendMessage(this.Handle, WM_ERASEBKGND, hDC, IntPtr.Zero);
 
...
SendMessage(this.Handle, WM_PRINTCLIENT, ptrClientDC, IntPtr.Zero);

Caio Proiete
MCT, MCSD, MCDBA, MCAD .NET, MCSD .NET

Imports System
Imports System.Windows.Forms
Imports System.Drawing
Imports System.Drawing.Drawing2D
Imports System.Runtime.InteropServices
 
Public class FlatDateTimePicker
 
  Inherits DateTimePicker
 
	Private Class ComboInfoHelper
	
		Private Declare Function GetComboBoxInfo Lib "user32.dll" (hwndCombo As Int32, ByRef info As ComboBoxInfo) As Boolean
 
		Private Structure RECT 
			public Left    As Int32
			public Top     As Int32
			public Right   As Int32
			public Bottom  As Int32
		End Structure
 
    Private Structure ComboBoxInfo
      Public cbSize      As Int32
      Public rcItem      As RECT
      Public rcButton    As RECT
      Public stateButton As IntPtr
      Public hwndCombo   As IntPtr
      Public hwndEdit    As IntPtr
      Public hwndList    As IntPtr
    End Structure
 
    Public Shared Function GetComboDropDownWidth() As Int32
			Dim cb As ComboBox = new ComboBox()
			Dim width As Int32 = GetComboDropDownWidth(cb.Handle)
			cb.Dispose()
      Return Width
		End Function
		
    Public Shared Function GetComboDropDownWidth(ByVal handle As IntPtr) As Int32
      Dim cbi As ComboBoxInfo = New ComboBoxInfo()
      cbi.cbSize = Marshal.SizeOf(cbi)
			GetComboBoxInfo(handle.ToInt32, cbi)
      Dim Width As Int32 = cbi.rcButton.Right - cbi.rcButton.Left
      Return Width
    End Function
	
	End Class
	
  Private Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA"(hwnd As Int32, wMsg As Int32, wParam As Int32, lParam As Int32) As Int32
  
  Private Declare Function GetWindowDC Lib "user32.dll"(hwnd As Int32) As IntPtr
  
  Private Declare Function ReleaseDC   Lib "user32.dll"(hwnd As Int32, hDC As Int32) As Int32
 
  Const WM_ERASEBKGND                As Int32   = &H14
  Const WM_PAINT                     As Int32   = &HF
  Const WM_NC_HITTEST                As Int32   = &H84
  Const WM_NC_PAINT                  As Int32   = &H85
  Const WM_PRINTCLIENT               As Int32   = &H318
  Const WM_SETCURSOR                 As Int32   = &H20
 

  Private BorderPen                  As Pen     = New Pen(Color.Black, 2)
  Private BorderPenControl           As Pen     = New Pen(SystemColors.ControlDark, 2)
  Private DroppedDown                As Boolean = False
  Private InvalidateSince            As Int32   = 0
  Private Shared DropDownButtonWidth As Int32   = 17
 
	Shared Sub New()
		'2 pixel extra is for the 3D border around the pulldown button on the left and right
		DropDownButtonWidth = ComboInfoHelper.GetComboDropDownWidth() + 2	
	End Sub
 
  Public Sub New()
    MyBase.New()
    Me.SetStyle(ControlStyles.DoubleBuffer, True)
    Me.SetStyle(ControlStyles.AllPaintingInWmPaint, True)
  End Sub
 
  Protected Overrides Function IsInputKey(ByVal keyData As System.Windows.Forms.Keys) As Boolean
    If keyData = (Keys.Tab Or Keys.Shift) Then
      Return True
    ElseIf keyData = Keys.Tab Then
      Return True
    Else
      Return MyBase.IsInputKey(keyData)
    End If
  End Function
	
  Protected Overrides Sub OnValueChanged(ByVal eventargs As EventArgs)
    MyBase.OnValueChanged(eventargs)
    Me.Invalidate()
  End Sub
 
  Protected Overrides Sub WndProc(ByRef m As Message)
    Dim hDC As IntPtr = IntPtr.Zero
    Dim gdc As Graphics = Nothing
    Select Case m.Msg
      Case WM_NC_PAINT
        hDC = GetWindowDC(m.HWnd.ToInt32)
        gdc = Graphics.FromHdc(hDC)
        SendMessage(Me.Handle.ToInt32, WM_ERASEBKGND, hDC.ToInt32, 0)
        SendPrintClientMsg()
        SendMessage(Me.Handle.ToInt32, WM_PAINT, IntPtr.Zero.ToInt32, 0)
        OverrideControlBorder(gdc)
        m.Result = New IntPtr(1)  'Indicate msg has been processed
        ReleaseDC(m.HWnd.ToInt32, hDC.ToInt32)
        gdc.Dispose()
      Case WM_PAINT
        MyBase.WndProc(m)
        hDC = GetWindowDC(m.HWnd.ToInt32)
        gdc = Graphics.FromHdc(hDC)
        OverrideDropDown(gdc)
        OverrideControlBorder(gdc)
        ReleaseDC(m.HWnd.ToInt32, hDC.ToInt32)
        gdc.Dispose()
      Case WM_SETCURSOR
        MyBase.WndProc(m)
        ' The value 3 is discovered by trial on error, and cover all kinds of scenarios
        ' InvalidateSince < 2 wil have problem if the control is not in focus and dropdown is clicked
        If DroppedDown And (InvalidateSince < 3) Then
          Invalidate()
          InvalidateSince = InvalidateSince + 1
        End If
      Case Else
        MyBase.WndProc(m)
    End Select
  End Sub
 
  Private Sub SendPrintClientMsg()
    'We send this message for the control to redraw the client area
    Dim gClient As Graphics = Me.CreateGraphics()
    Dim ptrClientDC As IntPtr = gClient.GetHdc()
    SendMessage(Me.Handle.ToInt32, WM_PRINTCLIENT, ptrClientDC.ToInt32, 0)
    gClient.ReleaseHdc(ptrClientDC)
    gClient.Dispose()
  End Sub
 
  Private Sub OverrideDropDown(ByVal g As Graphics)
    If Not Me.ShowUpDown Then
      Dim rect As Rectangle = New Rectangle(Me.Width - DropDownButtonWidth, 0, DropDownButtonWidth, Me.Height)
      ControlPaint.DrawComboButton(g, rect, ButtonState.Flat)
    End If
  End Sub
 
  Private Sub OverrideControlBorder(ByVal g As Graphics)
    If Not Me.Focused Or Not Me.Enabled Then
      g.DrawRectangle(BorderPenControl, New Rectangle(0, 0, Me.Width, Me.Height))
    Else
      g.DrawRectangle(BorderPen, New Rectangle(0, 0, Me.Width, Me.Height))
    End If
  End Sub
 
  Protected Overrides Sub OnDropDown(ByVal eventargs As EventArgs)
    InvalidateSince = 0
    DroppedDown = True
    MyBase.OnDropDown(eventargs)
  End Sub
	
  Protected Overrides Sub OnCloseUp(ByVal eventargs As EventArgs)
    DroppedDown = False
    MyBase.OnCloseUp(eventargs)
  End Sub
 
  Protected Overrides Sub OnLostFocus(ByVal e As System.EventArgs)
    MyBase.OnLostFocus(e)
    Me.Invalidate()
  End Sub
 
  Protected Overrides Sub OnGotFocus(ByVal e As System.EventArgs)
    MyBase.OnGotFocus(e)
    Me.Invalidate()
  End Sub
		
  Protected Overrides Sub OnResize(ByVal e As EventArgs)
    MyBase.OnResize(e)
    Me.Invalidate()
  End Sub
 
End Class