Click here to Skip to main content
Click here to Skip to main content

How to do pointers in Visual Basic

, 3 Sep 2000
Rate this:
Please Sign up or sign in to vote.
Show how to use pointers in a C like manner

Introduction

Most people think that Visual Basic does not have pointers and hence is not capable of handling data structures that require pointers (by the way these data structures can be implemented using classes).

Well, they are right but not for very long. Since Visual Basic has access to the entire Win32 API it is not so difficult to equip it with pointers. Let's look at a simple code fragment in C and then at its Visual Basic equivalent.

#include <stdio.h>
#include <stdlib.h>

int main(int argc, char* argv[])
{
    int * ptr;                        //1               
    ptr=(int *)malloc(sizeof(int));   //2             
    *ptr=10;                          //3             
    printf("The address of ptr is %d and its values is %d\n",ptr,*ptr); //4
    free(ptr);                        //5
    return 0;
}

I have marked the lines with numbers so you ,the reader, can follow more easily.

The equivalent of the first line, in VB is:

dim ptr as long   'int * ptr; 

This was easy because it follows from the definition of the pointer. A pointer is just a variable whose value is the address of another variable. It is long because a pointer in MS Windows is 4 bytes.

The second line:

ptr=(int *)malloc(sizeof(int)); 

Well, how do we allocate memory dynamically in Visual Basic? malloc has no equivalent. Here we'll use the Win32 API function HeapAlloc(...).Please check the documentation for more information on it.

So here's our code:

Dim hHeap As Long hHeap = GetProcessHeap()
ptr=HeapAlloc(hHeap,0,2) 'an integer in Visual Basic is 2 bytes

We can even check if memory was allocated.

if ptr<>0 then 
    'memory was allocated
    'do stuff
end if

Now,

*ptr=10;

In Visual Basic we'll use the function CopyMemory which is declared like so:

Public Declare Sub CopyMemory Lib "kernel32" Alias _
    "RtlMoveMemory" (Destination As Any, Source As Any, _
    ByVal Length As Long)

Here's the little trick : I modify the parameters and have two more definitions.

'to write to memory
Public Declare Sub CopyMemoryWrite Lib "kernel32" Alias _
    "RtlMoveMemory" (Byval Destination As long, Source As Any, _
    ByVal Length As Long)

' to read from memory
Public Declare Sub CopyMemoryRead Lib "kernel32" Alias _
    "RtlMoveMemory" (Destination As Any,byval Source As Long, _
    ByVal Length As Long)

Now here's how,

*ptr=10;

translates into Visual Basic.

dim i as integer 
i=10
CopyMemoryWrite ptr,i,2 ' an intger is two bytes

Now towards line 5.

'printf("%d\n",*ptr);
dim j as integer
CopyMemoryRead j,ptr,2
MsgBox "The adress of ptr is " & cstr(ptr) & _
    vbCrlf & "and the value is " & cstr(j)

Now free the memory

HeapFree GetProcessHeap(),0,ptr

Here is the complete listing of the source code: (just copy it into a project and run it).

Option Explicit

Private Declare Sub CopyMemory Lib "kernel32" _
    Alias "RtlMoveMemory" (Destination As Any, _
    Source As Any, ByVal Length As Long)
Private Declare Function GetProcessHeap Lib "kernel32" () As Long
Private Declare Function HeapAlloc Lib "kernel32" _
    (ByVal hHeap As Long, ByVal dwFlags As Long,_
     ByVal dwBytes As Long) As Long
Private Declare Function HeapFree Lib "kernel32" _
    (ByVal hHeap As Long, ByVal dwFlags As Long, lpMem As Any) As Long
Private Declare Sub CopyMemoryWrite Lib "kernel32" Alias _
    "RtlMoveMemory" (ByVal Destination As Long, _
    Source As Any, ByVal Length As Long)
Private Declare Sub CopyMemoryRead Lib "kernel32" Alias _
    "RtlMoveMemory" (Destination As Any, _
    ByVal Source As Long, ByVal Length As Long)

Private Sub Form_Load()
    Dim ptr As Long   'int * ptr;
    Dim hHeap As Long
    hHeap = GetProcessHeap()
    ptr = HeapAlloc(hHeap, 0, 2) 'an integer in Visual Basic is 2 bytes
    If ptr <> 0 Then
    'memory was allocated
    'do stuff
        Dim i As Integer
        i = 10
        CopyMemoryWrite ptr, i, 2 ' an intger is two bytes
        Dim j As Integer
        CopyMemoryRead j, ptr, 2
        MsgBox "The adress of ptr is " & CStr(ptr) & _
            vbCrLf & "and the value is " & CStr(j)
        HeapFree GetProcessHeap(), 0, ptr
    End If
End Sub

Bonus

Here is a simple and not complete implementation of a linked list. (On the form put a Command button named Command1)

Option Explicit
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory"_
    (Destination As Any, Source As Any, ByVal Length As Long)
Private Declare Function GetProcessHeap Lib "kernel32" () As Long
Private Declare Function HeapAlloc Lib "kernel32" _
    (ByVal hHeap As Long, ByVal dwFlags As Long, _
    ByVal dwBytes As Long) As Long
Private Declare Function HeapFree Lib "kernel32" _ 
    (ByVal hHeap As Long, ByVal dwFlags As Long, _
    lpMem As Any) As Long
Private Declare Sub CopyMemoryPut Lib "kernel32" Alias _
    "RtlMoveMemory" (ByVal Destination As Long, _
    Source As Any, ByVal Length As Long)
Private Declare Sub CopyMemoryRead Lib "kernel32" Alias _
    "RtlMoveMemory" (Destination As Any, _
    ByVal Source As Long, ByVal Length As Long)

Dim pHead As Long
Private Type ListElement
    strData As String * 255 '==255 * 2=500 bytes  vbStrings are UNICODE !
    pNext As Long  '4 bytes
                'pointer to next ; ==0 if end of list
'----------------
'total: 504 bytes
End Type

Private Sub CreateLinkedList()
'add three items to list
' get the heap first
    Dim pFirst As Long, pSecond As Long 'local pointers
    Dim hHeap As Long
    hHeap = GetProcessHeap()
    'allocate memory for the first and second element
    pFirst = HeapAlloc(hHeap, 0, 504)
    pSecond = HeapAlloc(hHeap, 0, 504)
    If pFirst <> 0 And pSecond <> 0 Then
    'memory is allocated
        PutDataIntoStructure pFirst, "Hello", pSecond
        PutDataIntoStructure pSecond, "Pointers", 0
        pHead = pFirst
    End If
    'put he second element in the list
End Sub

Private Sub Command1_Click()
    CreateLinkedList
    ReadLinkedListDataAndFreeMemory
End Sub

Private Sub PutDataIntoStructure(ByVal ptr As Long, _
        szdata As String, ByVal ptrNext As Long)
Dim le As ListElement
    le.strData = szdata
    le.pNext = ptrNext
    CopyMemoryPut ptr, le, 504
End Sub

Private Sub ReadDataToStructure(ByVal ptr As Long, _ 
        struct As ListElement)
Dim le As ListElement
    CopyMemoryRead le, ptr, 504
    struct.strData = le.strData
    struct.pNext = le.pNext
End Sub

Private Sub ReadLinkedListDataAndFreeMemory()
Dim pLocal As Long
Dim hHeap As Long
Dim le As ListElement
Dim strData As String
    pLocal = pHead
    hHeap = GetProcessHeap()
    Do While pLocal <> 0
        ReadDataToStructure pLocal, le
        strData = strData & vbCrLf & le.strData
        HeapFree hHeap, 0, pLocal
        pLocal = le.pNext
    Loop
    MsgBox strData
End Sub

Private Sub Form_Load()

End Sub

License

This article has no explicit license attached to it but may contain usage terms in the article text or the download files themselves. If in doubt please contact the author via the discussion board below.

A list of licenses authors might use can be found here

Share

About the Author

Stefan Savev

Bulgaria Bulgaria
No Biography provided

Comments and Discussions

 
GeneralWhy Pinmembermitchell5020-Dec-06 15:27 
GeneralRe: Why Pinmembercodemind18-Nov-07 22:11 
QuestionHow to execute a .exe file from resource without extracting it to a file PinmemberRahul A. H.28-Oct-06 0:24 
AnswerRe: How to execute a .exe file from resource without extracting it to a file PinmemberMassimo Conti10-Dec-06 6:39 
GeneralEasier way to dynamic allocation Pinmemberx1372938819-Aug-06 20:53 
GeneralRe: Easier way to dynamic allocation Pinmemberdarkoverlordofdata21-Sep-06 4:37 
QuestionHow to allocate memory in A.exe, send to and deallocate in B.exe? [modified] Pinmemberehaerim7-Aug-06 11:00 
AnswerRe: How to allocate memory in A.exe, send to and deallocate in B.exe? Pinmemberehaerim8-Aug-06 6:02 
GeneralRe: How to allocate memory in A.exe, send to and deallocate in B.exe? PinmemberJustBurn23-Sep-06 18:10 
GeneralGreat! Pinmemberdivyakolus10-Oct-05 4:14 
GeneralOption Explicit Pinmemberhuseyin_akturk1-Feb-05 6:54 
GeneralRe: Option Explicit PinsussAnonymous11-May-05 5:23 
GeneralMemory Leak PinmemberRobert Fearn30-Nov-04 23:21 
GeneralCopyMemory in HTML/Browser VBScript Pinmemberomjar24-Aug-04 9:53 
Generalpointer to structure in visual basic PinmemberJoe_valenz11-Jun-04 13:16 
Generaldumping content of allocated data to a file PinsussAnonymous17-Mar-04 3:04 
Generalasp-serverside-messagebox Pinmemberomsss1-Feb-04 18:24 
Generalasp-serverside-messagebox PinsussAnonymous1-Feb-04 18:23 
GeneralName of a variable in a variable!!! PinsussSrikV20-Jan-04 17:41 
GeneralRe: Name of a variable in a variable!!! Pinsuss¨a¨a¨a12-Feb-04 9:05 
GeneralRe: Name of a variable in a variable!!! Pinmemberrohitfredrick8-Sep-05 13:13 
QuestionSize of a picture? PinsussAnonymous18-Nov-03 12:35 
Questionwhat is pHead Pinmemberhesterloli12-Nov-03 16:08 
Questionresolution by a pointer? Pinsussrfcapo16-Aug-03 4:21 
Generalsize of an object in vb PinsussAnonymous4-Apr-03 4:43 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.

| Advertise | Privacy | Mobile
Web01 | 2.8.140821.2 | Last Updated 4 Sep 2000
Article Copyright 2000 by Stefan Savev
Everything else Copyright © CodeProject, 1999-2014
Terms of Service
Layout: fixed | fluid