Visual Basic

Public Shared Function FindNextNode(ByVal node As TreeNode) As TreeNode
    If node Is Nothing Then Throw New ArgumentNullException("node")
    
    ' If the node has any children, return the first child:
    If node.GetNodeCount(False) <> 0 Then
        Return node.Nodes(0)
    End If
    
    ' Otherwise, return the next node of the nearest ancestor which has one:
    While node IsNot Nothing
        Dim nextNode As TreeNode = node.NextNode
        If nextNode IsNot Nothing Then Return nextNode
        node = node.Parent
    End While
    
    ' If we get here, we're at the end of the tree:
    Return Nothing
End Function

Public Shared Function FindPreviousNode(ByVal node As TreeNode) As TreeNode
    If node Is Nothing Then Throw New ArgumentNullException("node")
    
    Dim result As TreeNode = node.PrevNode
    If result Is Nothing Then
        ' No previous sibling; move to the parent node:
        result = node.Parent
    Else
        ' Find the last descendant of the previous sibling:
        Dim childCount As Integer = result.GetChildCount(False)
        While childCount <> 0
            result = result.Nodes(childCount - 1)
            childCount = result.GetChildCount(False)
        End While
    End If
    
    Return result
End Function

Option Explicit

Private Const S_OK = &H0
Private Const S_FALSE = &H1
Private Const E_INVALIDARG = &H80070057

Private Const MAX_PATH = 260
Private Const SHGFP_TYPE_CURRENT = 0
Private Const CSIDL_MYPICTURES = &H27

Private Declare Function SHGetFolderPath Lib "shfolder" _
    Alias "SHGetFolderPathA" _
    (ByVal hwndOwner As Long, ByVal nFolder As Long, _
    ByVal hToken As Long, ByVal dwFlags As Long, _
    ByVal pszPath As String) As Long

Private Function GetFolderPath(ByVal csidl As Long) As String
    Dim path As String
    Dim returnValue As Long
    
    path = String(MAX_PATH, 0)
    returnValue = SHGetFolderPath(0, csidl, 0, SHGFP_TYPE_CURRENT, path)
    
    Select Case returnValue
        Case S_OK
            GetFolderPath = Left(path, InStr(1, path, Chr(0)) - 1)
        
        Case S_FALSE
            ' The CSIDL in nFolder is valid, but the folder does not exist.
            ' Use CSIDL_FLAG_CREATE to have it created automatically
            GetFolderPath = vbNullString
        
        Case E_INVALIDARG
            ' nFolder is invalid
            Err.Raise 5, "csidl", "Invalid folder"
    End Select
End Function

Public Function GetPicturesFolderPath() As String
    GetPicturesFolderPath = GetFolderPath(CSIDL_MYPICTURES)
End Function

The long and sad story of the Shell Folders key – The Old New Thing[^]:

In other words, the "Shell Folders" key exists solely to permit four programs written in 1994 to continue running on the RTM version of Windows 95.