Get a File ContentType from a Windows Forms App

Introduction

I do most of my development in ASP.NET, but recently, I needed to convert a large number of articles from *.asp files into a format that we could store in our database. Part of this conversion involved storing all the images and files from the *.asp pages into the database in a binary format. There are many good articles on the web about how to accomplish this task, however all of them seem to involve the process of selecting the file in a web form, and then uploading that file for storage in the database. That process looks something like this:

Private Sub UploadFile() 
   Dim iLength As Integer =  CType( _
         File1.PostedFile.InputStream.Length, Integer)   
   If iLength = 0 Then Exit Sub 'not a valid file   

   Dim sContentType As String =  File1.PostedFile.ContentType   
   Dim sFileName As String, i As Integer   
   Dim bytContent As Byte()   
   ReDim bytContent(iLength) 'byte array, set to file size   

   'strip the path off the filename   

   i = InStrRev(File1.PostedFile.FileName.Trim, "\")   
   If i = 0 Then   
      sFileName = File1.PostedFile.FileName.Trim   
   Else   
      sFileName = Right(File1.PostedFile.FileName.Trim,  _
          Len(File1.PostedFile.FileName.Trim) - i)   
   End If   
   Try   
      File1.PostedFile.InputStream.Read(bytContent, 0,  iLength)   
      With cmdInsertFile   
         .Parameters("@FileName").Value = sFileName   
         .Parameters("@FileSize").Value = iLength   
         .Parameters("@FileData").Value = bytContent   
         .Parameters("@ContentType").Value =  sContentType   
         .ExecuteNonQuery()   
      End With   
   Catch ex As Exception   
      dbConn.Close()   
   End Try   
End Sub 

The ContentType Snagfu

That code above is all fine and dandy, and was an excellent jumping off point for me to begin storing the files from a WindowsForms application. The Windows application doesn't suffer from the same file access restrictions as the ASP.NET application does. I can access the file directly (which is the point of doing it this way). So first, I'll need a quick change to the way we access the file. It is not being passed through a web form, so I'll just pass the Path the the file as a parameter.

Private Sub UploadFile(Byval filename as String)

Then, instead of using a stream from the posted file, we create a FileStream from the file itself.

Dim Fs As FileStream = New FileStream(filename, _
     FileMode.Open, FileAccess.Read)
Dim iLength As Integer = CType(Fs.Length, Integer)
..
..
Fs.Read(bytContent, 0, iLength)

Ah, finally, all we need now is to get the ContentType. But as you'll quickly notice, there is no ContentType property associated with FileStream. Now what?

The Registry To The Rescue - Almost

My first thought was to handle this own my own, and start making up a simple lookup table of all the common file formats - .zip, .doc, .xls, .jpg, .jpeg - I quickly realized that this list was going to get enormous very quickly. This wasn't going to work. Our employees upload files from hundreds of applications, I'd never get them all.

Then a friend tipped me off (Thanks TheLearnedOne) - he said to look in the registry, under \\HKEY_CLASSES_ROOT. I looked, and therein was a list of file extensions! And under the file extensions was a key called ContentType. Hooray! An answer! Or so I thought. As it turns out, there is not a ContentType key under ALL the file types, only some of them. Which means this method would only help SOME of the time. Since I like to keep my job ALL of the time, I needed a better answer. It wasn't far away.

The Registry To The Rescue - Again

The registry idea was a good one. I did a search on ContentType and came up with this path ( \\HKEY_CLASSES_ROOT\MIME\Database\Content Type\). Finally, here is a complete listing of every ContentType available. And under each one, a key with the file extenstion that maps to that ContentType. Since I have a filename, all I have to do is match the key to the ContentType, and we have a winner.

Public Function GetMIMEType(_
    ByVal filepath As String) As String 
 Dim regPerm  As RegistryPermission = _
       New RegistryPermission(RegistryPermissionAccess.Read, _
       "\\HKEY_CLASSES_ROOT")
 Dim classesRoot As RegistryKey = Registry.ClassesRoot
 Dim fi = New FileInfo(filepath)
 Dim dotExt As String = LCase(fi.Extension)
 Dim typeKey As RegistryKey = classesRoot.OpenSubKey(_
      "MIME\Database\Content Type")
 Dim keyname As String 

For Each keyname In typeKey.GetSubKeyNames()
 Dim curKey As RegistryKey = classesRoot.OpenSubKey( _
      "MIME\Database\Content Type\" & keyname)
 If LCase(curKey.GetValue("Extension")) = dotExt Then
    'Debug.WriteLine("Content type was " & keyname)
     Return keyname
 End If
Next 
End Function   

Using the code

I'm not even going to post a download file here. Just copy the code from above, and paste it into your VB.NET application. I'm sure it can be easily converted to C# as well. You may need to add the following lines to your application as well:

Imports System.Security.Permissions
Imports Microsoft.Win32

In Closing

By the way, here is the final modified code. This of course assumes that you have code defined in order to access your database, and a stored procedure to store the file in the database. Like I said, there are many good articles on the web regarding this process, so I won't repeat them here.

Private Sub UploadFile(ByVal filename as String) 
   Dim Fs As FileStream = New FileStream(filename, _
      FileMode.Open, FileAccess.Read)
   Dim iLength As Integer = CType(Fs.Length, Integer)  
   If iLength = 0 Then Exit Sub 'not a valid file   

   Dim sContentType As String =  GetMIMEType(filename)   
   Dim sFileName As String, i As Integer   
   Dim bytContent As Byte()   
   ReDim bytContent(iLength) 'byte array, set to file size   

   'strip the path off the filename   

   i = InStrRev(FileName.Trim, "\")   
   If i = 0 Then   
      sFileName = FileName.Trim   
   Else   
      sFileName = Right(FileName.Trim,  Len(FileName.Trim) - i)   
   End If   
   Try   
      fs.Read(bytContent, 0,  iLength)   
      With cmdInsertFile   
         .Parameters("@FileName").Value = sFileName   
         .Parameters("@FileSize").Value = iLength   
         .Parameters("@FileData").Value = bytContent   
         .Parameters("@ContentType").Value =  sContentType   
         .ExecuteNonQuery()   
      End With   
   Catch ex As Exception   
      dbConn.Close()   
   End Try   
End Sub