Extended NumericUpDown control

• Download source and demo project - 21.1 KB

Introduction

If you have ever written a data-entry application, there's a big chance you used the NumericUpDown control. This control is great to provide a field to enter numeric values, with advanced features like up-down buttons and accelerating auto-repeat.

The other side of the coin is that NumericUpDown is not really mouse-aware. I experienced some bugs and bad behaviors:

• I need to select all the text when it gets focus (see below), but it misses some of the TextBox properties, like SelectedText, SelectionStart, SelectionLength (an AutoSelect property will be useful).
• Some of the standard events are not working properly (see below): MouseEnter, MouseLeave.
• Rotating the mouse wheel when the control is focused causes its value to change. A property to change this behavior, like InterceptArrowsKeys for up/down keys, will be useful.

That's why I decided to subclass it, fixing these points and adding missing features and properties.

Missing TextBox properties

I needed some missing TextBox properties when I was asked to select all the text in the control when it got the focus.

Yes, NumericUpDown exposes a Select(int Start, int Lenght) method you can call to select all text. At first try, I attached to the GotFocus event to call Select(0, x) but, hey, wait a moment... what should I use for x? It seems that any value is accepted, even if greater than the text length. OK, let's say x=100 and proceed. This works well with the keyboard focus keys (like TAB), but it's completely useless with the mouse: a mouse click raises the GotFocus event (where I select all the text), but as soon as you release the button, a zero-selection is done, leaving the control with no selection. OK, I thought, let's add a SelectAll on the MouseUp event too, but this way, the user cannot perform a partial selection anymore; each time the mouse button is released, all the text is selected. I need to know if a partial selection exists; in a TextBox, I can test it with SelectionLength > 0, so I need to access the underlying TextBox control.

Now comes the tricky part: NumericUpDown is a composite control, a TextBox and a button box. Looking inside it through the Reflector, we can find the internal field which holds the textbox part:

Friend upDownEdit As UpDownEdit  ' UpDownEdit inherits from TextBox

We'll obtain a reference to this field using Reflection; this is done in the control creator.

''' <summary>
''' object creator
''' </summary>
Public Sub New()
    MyBase.New()
    ' extract a reference to the underlying TextBox field
    _textbox = GetPrivateField(Me)
    If _textbox Is Nothing Then
        Throw New ArgumentNullException(Me.GetType.FullName _
                & ": Can't find internal TextBox field.")
    End If
    ' ...
End Sub


''' <summary>
''' Extracts a reference to the private underlying textbox field
''' </summary>
Private Shared Function GetPrivateField _
                    (ByVal ctrl As NumericUpDownEx) As TextBox
    ' find internal TextBox
    Dim textFieldInfo As Reflection.FieldInfo _
        = GetType(NumericUpDown).GetField("upDownEdit", _
                    Reflection.BindingFlags.FlattenHierarchy _
                    Or Reflection.BindingFlags.NonPublic _
                    Or Reflection.BindingFlags.Instance)
    ' take some caution... they could change field name
    ' in the future!
    If textFieldInfo Is Nothing Then
        Return Nothing
    Else
        Return TryCast(textFieldInfo.GetValue(ctrl), TextBox)
    End If
End Function

Now that we have the underlying TextBox, it is possible to export some missing properties:

<Browsable(False)> _
<DesignerSerializationVisibility( _
     DesignerSerializationVisibility.Hidden)> _
Public Property SelectionStart() As Integer
    Get
        Return _textbox.SelectionStart
    End Get
    Set(ByVal value As Integer)
        _textbox.SelectionStart = value
    End Set
End Property

And finally, we can have a perfectly working mouse management:

' MouseUp will kill the SelectAll made on GotFocus.
' Will restore it, but only if user have not made
' a partial text selection.
Protected Overrides Sub OnMouseUp(ByVal mevent As MouseEventArgs)
    If _autoSelect AndAlso _textbox.SelectionLength = 0 Then
        _textbox.SelectAll()
    End If
    MyBase.OnMouseUp(mevent)
End Sub

Mouse events not raised properly

The original MouseEnter and MouseLeave events are raised in couples: a MouseEnter immediately followed by a MouseLeave. Maybe that's why, to discourage their use, they are marked with a <Browsable(False)> attribute. Since I need the MouseEnter event to update my StatusBar caption, I investigated a little on this "bug".

As said above, NumericUpDown is a composite control (red rectangle in the following picture) containing a TextBox (left green rectangle) and some other controls:

The "control" area is the one between the red and the green rectangles; when you fly over it with the mouse, you'll receive the MouseEnter event while between the red and the green, then MouseLeave when inside the green rectangle. The same happens when you leave.

The better way to raise these events, now that we can access the underlying TextBox, is to re-raise the MouseEnter and MouseLeave events as raised from the TextBox itself; this is what NumericUpDownEx does.

MouseWheel management

NumericUpDown's management of the mouse wheel is, sometimes, really annoying. Suppose you have an application which displays some kind of chart, with a topmost dialog (toolbox) to let the user change some parameters of the graph. In this dialog, the only controls which can keep the focus are NumericUpDown ones:

After your user puts the focus inside one of them, the mouse wheel is captured by the NumericUpDown. When the user wheels to, say, scroll the graph, the effect is that the focused field value is changed; this behavior is really annoying.

A fix could be to kill the WM_MOUSEWHEEL message for the control, but this will kill even "legal" wheelings.

The NumericUpDown has a property which allows WM_MOUSEWHEEL messages to pass only if the mouse pointer is over the control, making sure that the user is wheeling to change the control value.

This is done by keeping track of the mouse state in the MouseEnter-MouseLeave events, then killing WM_MOUSEWHEEL messages accordingly.

How to use the control

Simply include NumericUpDownEx.vb in your project and use the control like you'll do with the standard NumericUpDown. If you have a C# project, you could reference the CoolSoft.NumericUpDownEx.dll assembly or, better, try to convert the code to C# (it should not be so difficult). I could provide a C# version upon request.

You must Sign In to use this message board.

FAQ    Noise Tolerance Very HighHighMediumLowVery Low   Layout Expand Posts & RepliesThread ViewNo JavascriptNo JS + Preview   Per page 102550

Msgs 1 to 15 of 15 (Total in Forum: 15) (Refresh) FirstPrevNext

Little improvement andrea@gmi 0:39 28 May '09   This few lines of code will add a support for SEPARATE up/down events: ''' <summary> ''' Event raised BEFORE value decrement ''' </summary> Public Event BeforeValueDecrement(ByVal sender As System.Object) ''' <summary> ''' Event raised BEFORE value increment ''' </summary> Public Event BeforeValueIncrement(ByVal sender As System.Object) Public Overrides Sub DownButton() RaiseEvent BeforeValueDecrement(Me) MyBase.DownButton() End Sub Public Overrides Sub UpButton() RaiseEvent BeforeValueIncrement(Me) MyBase.UpButton() End Sub In this way you can specify one or more "threshold levels", like this: Private Sub NumericUpDown1_BeforeValueDecrement(ByVal sender As System.Object) Handles NumericUpDown1.BeforeValueDecrement Dim upDown As NumericUpDown = DirectCast(sender, NumericUpDown) If upDown.Value = 1 Then upDown.Minimum = 0.1 upDown.Increment = 0.1 upDown.DecimalPlaces = 1 End If End Sub Private Sub NumericUpDown1_BeforeValueIncrement(ByVal sender As System.Object) Handles NumericUpDown1.BeforeValueIncrement Dim upDown As NumericUpDown = DirectCast(sender, NumericUpDown) If upDown.Value = 0.9 Then upDown.DecimalPlaces = 0 End If If upDown.Value = 1 Then upDown.Minimum = 0 upDown.Increment = 1 End If End Sub Now, the updown values sequence will be: 0.0 , 0.1, 0.2, 0.3, 0.4, 0.5 , 0.6, 0.7, 0.8, 0.9, 1, 2, 3, ... instead of 0, 1, 2, 3, ... I hope this may be useful... ciao Andrea Sign In·View Thread·PermaLink New version available Claudio Nicora 5:52 21 Jan '09   I just uploaded version 1.1 to my website (and soon here on CodeProject). It adds features like UpDownButtons autohide and some improvements... You can find it here: http://coolsoft.altervista.org/blog/2009/01/numericupdown-control-updated[^] Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org Sign In·View Thread·PermaLink Re: New version available Berryl Hesh 5:00 22 Jan '09   Hi Claudio. I get an "access denied" message when I try to download from your site. Can you please fix that? Thx, BH Sign In·View Thread·PermaLink Re: New version available Claudio Nicora 7:20 22 Jan '09   You're right Should be fixed now... Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org Sign In·View Thread·PermaLink UpDownButtons and MouseLeave M McCracken 11:24 9 Dec '08   I was trying to extend your control so that the up/down buttons are invisible until the user's mouse enters the control, and then they appear until the mouse leaves the control. To do this, I followed your example and looked at NumericUpDown in .NET Reactor, and discovered that the up/down buttons are encapsulated thus (pseudo C#): public class NumericUpDown : UpDownBase {} public class UpDownBase : ContainerControl { internal class UpDownButtons : Control {} internal class UpDownEdit : TextBox {} // as you noted } So my thinking was that I could do the same thing you did to capture MouseEnter and MouseLeave for my own purposes. I managed to get ahold of both the UpDownEdit and UpDownButtons controls using a slightly modified version of your GetPrivateField method: private static Control GetPrivateField(NumericUpDownExEx ctrl, string typeName) { // find internal Ctrl that matches theTargetType FieldInfo[] fieldInfos = typeof(NumericUpDown).GetFields(BindingFlags.FlattenHierarchy | BindingFlags.NonPublic | BindingFlags.Instance); foreach (FieldInfo fieldInf in fieldInfos) { if (fieldInf.FieldType.Name == typeName) return fieldInf.GetValue(ctrl) as Control; } return null; } To get the UpDownButtons member, I call this with: Control udButtons = GetPrivateField(this, "UpDownButtons"); This all works great, and I assign handlers to the MouseEnter and MouseLeave events of both the TextBox and the UpDownButtons. But what I found is that UpDownButtons *never* publishes MouseLeave! It looks like it means to based on my perusal of the UpDownButtons implementation via .NET Reactor, but I'm not sure. Not knowing when I've left the control is going to throw a monkey-wrench into my pop-up buttons idea. Have you played with this aspect of the control at all? Any ideas on where I should look? Sign In·View Thread·PermaLink Re: UpDownButtons and MouseLeave Claudio Nicora 23:48 9 Dec '08   Your idea is great, I've never thought about it. A quick test confirmed what you say, the UpDownButtons control didn't throw the MouseLeave event. Let's have a look with reflector: protected override void OnMouseLeave(EventArgs e) { this.mouseOver = UpDownBase.ButtonID.None; base.Invalidate(); this.parent.OnMouseLeave(e); } As you can see, it overrides the OnMouseLeave method to clear button highlighting and, at the end, it calls this.parent.OnMouseLeave and not base.OnMouseLeave as expected. Here parent is the NumericUpDown itself and not the UpDownButtons control; the MouseLeave event is not lost but thrown by the most external NumericUpDown container control. The UpDownEdit control (the textbox part) has a completely different story, since it does not override OnMouseLeave, throwing the MouseLeave event by itself. Yes, this event will be lost and generates the other side of the coin: the wrong "external" behaviour my control is trying to fix. As for your needings, I'll try to handle the external MouseLeave. Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org Sign In·View Thread·PermaLink Re: UpDownButtons and MouseLeave [modified] M McCracken 3:20 10 Dec '08   Thanks for doing that analysis, that is very helpful. After reading your response, I understood better what this control is doing, and with about 30 minutes of careful mousing using the Magnifier, I was able to come up with zone transitions for the mouse on this control. First let me define some zones, using your red/green box image as a map: A = outside the control B = inside the red box and outside the green box(es) C = inside the edit control's green box (this happens simultaneously with the mouse cursor changing to a text caret) D = inside the UpDownButton control's green box I also noticed the following: * There is a one-pixel (in my XP theme) strip between zones D and C, which is considered part of zone B. * There is NOT a border strip between zones D and A; leaving the UpDownButton control vertically or to the right goes straight to zone A without an intervening stop in zone B. Finally, for notation, let "NUD" mean a message at the NumericUpDown level; let "BTN" mean a message on the UpDownButton control; and let "TB" (TextBox) mean a message on the UpDownEdit control. Zone transitions: A-to-B: NUD MouseEnter B-to-A: NUD MouseLeave B-to-C: NUD MouseLeave, TB MouseEnter C-to-B: TB MouseLeave, NUD MouseEnter B-to-D: NUD MouseLeave, BTN MouseEnter D-to-B: NUD MouseLeave (!!!), NUD MouseEnter A-to-D: BTN MouseEnter D-to-A: NUD MouseLeave (!!!) As you can see, the transitions bear out your code analysis reliably. I should note, however, that moving the mouse faster than one pixel at a time can easily skip some of the Zone B-related transitions. So what does this all mean? It means it is going to be very difficult for me to deterministically figure out what the user is trying to do with his mouse so I can show/hide those buttons! EDIT: My mistake! This was very easy. I used a bool mouseIsOver_ to indicate when the mouse was inside this control or any of its sub-controls, and then handled mouse messages thus: Constructor: udTextBox.MouseEnter += new EventHandler(subControl_MouseTransition); udTextBox.MouseLeave += new EventHandler(subControl_MouseTransition); udButtons.MouseEnter += new EventHandler(subControl_MouseTransition); udButtons.MouseLeave += new EventHandler(subControl_MouseTransition); void subControl_MouseTransition(object sender, EventArgs e) { bool oldFlag = mouseIsOver_; mouseIsOver_ = RectangleToScreen(ClientRectangle).Contains(MousePosition); if (!oldFlag && mouseIsOver_) base.OnMouseEnter(e); else if (oldFlag && !mouseIsOver_) base.OnMouseLeave(e); } protected override void OnMouseEnter(EventArgs e) { subControl_MouseTransition(this, e); } protected override void OnMouseLeave(EventArgs e) { subControl_MouseTransition(this, e); } This notifies my owning form/panel/container (once) when the mouse enters, and (once) when the mouse leaves. To do special processing like showing/hiding the button control, we can just replace the calls to base.OnMouse{Enter|Leave} with calls to our own specialty stuff. Regardless, the base methods will get called at some point to repair the broken Mouse events NumericUpDown gave us. Thank you very much, Claudio, for helping me along this path. modified on Wednesday, December 10, 2008 8:39 AM Sign In·View Thread·PermaLink Re: UpDownButtons and MouseLeave [modified] Claudio Nicora 22:08 10 Dec '08   M McCracken wrote: void subControl_MouseTransition(object sender, EventArgs e) { bool oldFlag = mouseIsOver_; mouseIsOver_ = RectangleToScreen(ClientRectangle).Contains(MousePosition); Using Rectangle.Contains() is a great idea I've never thought; I was trying to increment/decrement an integer at each MouseEnter/MouseLeave event, but I was scared about missing some of them, going out of sync. I'll add your code (and credits) to the next revision of NumericUpDownEx. Thanks again Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org modified on Tuesday, January 13, 2009 3:57 AM Sign In·View Thread·PermaLink Re: UpDownButtons and MouseLeave Berryl Hesh 6:49 18 Jan '09   Ciao Claudio I'm just going to take a look at this now, and am particularly interested to get the implementation where the spinner buttons are only showing when the mouse is over. I want to try and use this as the basis for a DataGridViewNumericUpDownCell in a Time Sheet type of application. Since I'll need several columns of data input, the spinner buttons will make this look particularly and unnecessarily cluttered without such a feature. Do you have any idea when you might release the next revision? Thanks for sharing! Berryl Sign In·View Thread·PermaLink Re: UpDownButtons and MouseLeave Claudio Nicora 3:14 20 Jan '09   Berryl Hesh wrote: Do you have any idea when you might release the next revision? Hi Berryl, sorry for the late reply. I'm sorry to tell that hiding the spinner buttons is not so simple; in fact obtaining a reference to them is quite simple, as it quite similar to the existing GetPrivateField, changing "upDownEdit" with "upDownButtons". You'll quickly find that hiding (.Visible = False) makes the control become dirty, since the textbox part will not enlarge to fill the new space. The original UpDownBase has a private method, named PositionControls, which is called to perform internal controls layout, but it does not test control visibility (since they haven't thought that spinner will become hidden), so it's useless for this task. I already tested this with a no-go. Anyway next revision of this control will be published ASAP, with a better MouseOver detection algorithm. Thanks for your comment. Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org Sign In·View Thread·PermaLink Re: UpDownButtons and MouseLeave Berryl Hesh 8:18 20 Jan '09   Hi Claudio Too bad the spin buttons didn't turn out as easily solved as the prior messages in this thread indicated. MS has an article showing how to make a numeric up down data grid view cell, column, and control. It looks like they are handling the buttons in their overridden Paint method (DataGridViewNumericUpDownCell), but honestly I'm not sure. It's here, http://msdn.microsoft.com/en-us/library/aa730881(VS.80).aspx[^]. As an aside, I translated your NumericUpDownEx to C#. I'd put it in this message but that would make it way too long of a message for some readers. Let me know if you want it to post on your "cool" website (love that name). I can also send you that overridden Paint method. Thanks again for your post. Regards, Berryl Sign In·View Thread·PermaLink Formatting the value doshe 12:18 4 Dec '08   I would be nice to set a parameter for a "Format" string and/or a FormatProvider. Sign In·View Thread·PermaLink Re: Formatting the value Claudio Nicora 22:51 4 Dec '08   Simple formatting tasks could be done with the native properties: .DecimalPlaces .ThousandsSeparator .Hexadecimal If you need a complete formatting, well, this is not a trivial task. As you can see we inherit directly from NumericUpDown, this is not a custom control where we have full access to contained parts. You need to completely intercept (and change) the logic between the TextBox and the containing NumericUpDown. This way you could get the string value the control is trying to write in the textbox and format it; you must also get the value inserted by the user, parse it and set the Value property accordingly. I already tried to override OnValueChanged and OnTextBoxTextChanged methods with no results. An interesting reading should be this: http://www.codeproject.com/KB/vb/UpDownEx_with_measure.aspx[^] Hope this helps Thanks for your comment Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org Sign In·View Thread·PermaLink Great Member 4684745 7:38 25 Nov '08   Mouse wheelies have been the cause of many user mistakes, your control has put a stop to that. Thanks. Sign In·View Thread·PermaLink Re: Great Claudio Nicora 12:59 25 Nov '08   You're welcome Visit my website for some interesting .NET free tools: http://coolsoft.altervista.org Sign In·View Thread·PermaLink

Last Visit: 15:59 6 Jul '09     Last Update: 15:59 6 Jul '09 1