Use date & time in batch/log files

Introduction

Did you ever tried to use date and time in logfiles or batch/command files.
This is not easy without special software.
For me this was a problem because I needed a separate logfile every time when an event happened.
I also needed this to create backup schedules.
The possibilities of batch command is to limited, and different language OS will react different, so it is hard to roll such batch files out in a multi language OS environment.

Solution

Te solution is very simpel.
I run a VB script where it is easy to get date time and other parameters.
These values are stored in environment variables which can be used in batch files.
Because these environment variables are only valid in that particular shell, we need to call the batch file within the VB Script.

Copy the following code in a file called RunNow.cmd

 
'***********************************************
'
' RunNow.vbs
' (c) 2008 Computech.
'     Initialy Version 2003.
'     2/2/2008 Extra Functionality
' Written by Peter Verijke
'
'***********************************************
Dim dDay, dLDOM, dLDOY, dLFOW, dLFOM
Dim ArgObj
Dim BatchFile
Dim sCommand

Dim WshShell ' as object
Dim objEnv ' as collection
Dim sGetMyVar  ' as string

' Get the Arguments object
Set ArgObj = WScript.Arguments

' Test to make sure there is at least one command line arg - the command
If ArgObj.Count < 1 Then
    DisplayHelpMessage
    WScript.Quit
End If

BatchFile = ArgObj(0)

Set WshShell = WScript.CreateObject("WScript.Shell")
Set objEnv = WshShell.Environment("PROCESS")

dNow = Now()
dLDOM = DateSerial(Year(dNow),Month(dNow) + 1,0)
dLDOY = DateSerial(Year(dNow) + 1, 1,0)
'Friday of this week
dLFOW = (dNow + (5 - Weekday(dNow, vbMonday)))
'Last Friday of Month
dLFOM = (dLDOM + (5 - Weekday(dLDOM, vbMonday)))

objEnv("Year") = Year(dNow)
objEnv("Month") = Right("0" & Month(dNow), 2)
objEnv("Day") = Right("0" & Day(dNow), 2)
objEnv("Hour") = Right("0" & Hour(dNow), 2)
objEnv("Minute") = Right("0" & Minute(dNow), 2)
objEnv("Second") = Right("0" & Second(dNow), 2)

'Day of Week
objEnv("DOW") = Weekday(dNow, vbMonday)
'Day of Week Name
objEnv("DOWN") = WeekDayName(WeekDay(dNow), 1)
'Week of Month
objEnv("WOM") = -Int(-((WEEKDAY(dNow-DAY(dNow)+1, 2) + DAY(dNow) -1) / 7))
'Last Day of Month
objEnv("LDOM") = Right("0" & Day(dLDOM), 2)
'Last Day of Year
objEnv("LDOY") = Right("0" & Day(dLDOY), 2)
'Last Friday of Week
objEnv("LFOW") = Right("0" & Day(dLFOW), 2)
'Last Friday of Month
objEnv("LFOM") = Right("0" & Day(dLFOM), 2)


sCommand = "%COMSPEC% /C " 

WshShell.Run(sCommand + BatchFile) 

WScript.Quit

'************************
'
' Display Help Message
'
'************************
Sub DisplayHelpMessage()
    Dim sHelpMessage
    sHelpMessage = "Usage:" & vbCrLf
    sHelpMessage = sHelpMessage & Wscript.FullName & " RunNow <CommandFile|BatchFile>" & vbCrLf
    sHelpMessage = sHelpMessage & "Optionally use environment variables in file: %Year% %Month% %Day% %Hour% %Minute% %Second%" & vbCrLf
    sHelpMessage = sHelpMessage & "                                              %DOW% %DOWN% %WOM% %LDOM% %LDOY% %LFOW% %LFOM%" & vbCrLf
    WScript.Echo sHelpMessage
End Sub

Usage

As you can see in the source Help Message, it is sufficient to use the environment variables %Year% %Month% %Day% %Hour% %Minute% or %Second% in your batch files. To give an example: You could make a command file called mydir.cmd with the following contents

dir > MyLog%Year%%Month%%Day%-%Hour%%Minute%%Second%.log 

Instead of running this file directly, run via the VB Script:

RunNow.vbs mydir.cmd 

There is also now some extra environment variables like Last Day of Month, Week of Month etc..
These variables can also be used for naming or comparing to take other actions in batch files.
I use it to create for some data Day, Week and Month Backups.

Thats it.

I hope this will be usefull to you.

Peter Verijke

You must Sign In to use this message board.

FAQ    Noise Tolerance Very HighHighMediumLowVery Low   Layout Expand Posts & RepliesThread ViewNo JavascriptNo JS + Preview   Per page 102550

Msgs 1 to 15 of 15 (Total in Forum: 15) (Refresh) FirstPrevNext

Just made use of this Offbeatmammal 11:30 31 Dec '08   Neat script - thanks. I've just made use of it (see example here) and I added another environment variable 'MonthName objEnv("MN") = MonthName(Month(dNow)) Regards ~Offbeatmammal Sign In·View Thread·PermaLink how can i use this? blajarbot 21:26 4 Jan '07   i'm new for this asp language.. i want to use this as my final project in my study... could you explain it to me how i can use it? step by step... i already try to copy & paste it to notepad and save it as runnow.cmd and mydir.cmd but at the bottom line you wrote that use via vbscript.. i dont get it.. runnow.vbs ? .cmd or .vbs ? thanks for the help.. ordinary man looking for better future Sign In·View Thread·PermaLink AM or PM Anonymous 17:03 22 Jan '05   I hope you can put AM or PM to the code. Please its important to me. Sign In·View Thread·PermaLink Re: AM or PM Anonymous 17:39 22 Jan '05   :::I hope you can put AM or PM to the code. :::Please its important to me. problem solved! anyway thanks to you all guys. nice tips and code. Sign In·View Thread·PermaLink Re: AM or PM ____01 17:44 13 Jan '07   hiiiiiiii.............. can i ask for the code for AM or PM? Sign In·View Thread·PermaLink Can be done with batch commands alone Paul Bartlett 0:27 18 Dec '03   If you have command extensions enabled, then DATE /T will display the date. You can make use of this with the FOR /F command, e.g. FOR /F "tokens=1-3 delims=/ " %a IN ('DATE /T') DO SET FILENAME=Log%c%b%a.txt will execute the command: SET FILENAME=Log20031218.txt (if you've got UK English date formats). Note that in a batch file, the a, b and c variables need two percent signs, i.e. %%a, %%b and %%c wherever they appear Sign In·View Thread·PermaLink Re: Can be done with batch commands alone RabidCow 10:11 18 Dec '03   (from the help for the set command) %DATE% - expands to current date using same format as DATE command. %TIME% - expands to current time using same format as TIME command. So: set f=%date:/=%%time::=% :: Thu 12182003120939.93 set f=Log%f:~8,4%%f:~4,4%-%f:~12,6%.txt :: Log20031218-120939.txt Sign In·View Thread·PermaLink Re: Can be done with batch commands alone funny thing 10:54 18 Dec '03   Guys, he's a consultant, he has to write *something* regardless of whether it's needed or not. C'mon, give him a break LOL Sign In·View Thread·PermaLink Re: Can be done with batch commands alone Peter Verijke 0:13 19 Dec '03   RabidCow, Well done, nice. But my answer is the same as to Paul. There are no guaranties this will work, because of regional settings. This will only work if your regional settings are set ok. In my case I have to adapt the second command line. Difference with Paul his method is that you do have seconds here. The VBscript method works independant of the regional settings. Regards Peter Sign In·View Thread·PermaLink Re: Can be done with batch commands alone Anonymous 1:36 25 Mar '05   REM Get Date as YYYYMMDD Date/t | findstr /I / && Goto English for /F "tokens=1-3 delims=. " %%i in ('Date/t') do Set ToDay=%%k%%j%%i Goto Label :English for /F "tokens=1-3 delims=/ " %%i in ('Date/t') do Set ToDay=%%k%%i%%j :Label Sign In·View Thread·PermaLink Re: Can be done with batch commands alone Anonymous 9:45 8 Aug '05   This was very helpful. Since I am using it on servers whose environment I control, it was the simplest and most elegant of the three solutions on this site. All of these solutions are excellent. Sign In·View Thread·PermaLink Re: Can be done with batch commands alone Peter Verijke 23:32 18 Dec '03   Paul, Thanks for the tip, but the VB Script has some advantages over your method. - The date format is no issue when using that script. This is important when using in a global environment. To make it work on my computer I need to do: FOR /F "tokens=1-4 delims=/ " %a IN ('DATE /T') DO SET FILENAME=Log%d%c%b.txt This is because date /t gives the following output vr 19/12/2003 As you probably know, this depends on the systems regional settings. The script file is independent of this setting. - You can also use Time (Hours, Minutes Seconds) You can get hours and minutes to in a similar way you showed with the “for” command, but then you do not have seconds, and you also have the regional issue’s again. Mind you, without policies in place in a network, there is no guaranty which regional settings a user has on his workstation. Regards Peter Sign In·View Thread·PermaLink Re: Can be done with batch commands alone Paul Bartlett 1:30 19 Dec '03   You are quite right about the limitations of my approach, but I think your first few words say it all: Peter Verijke wrote: Thanks for the tip My comment was merely intended to highlight a powerful but underused tool. I've blogged another use of it here[^]. Sign In·View Thread·PermaLink Re: Can be done with batch commands alone aaac007 3:32 24 Dec '03   for /F "tokens=2,3,4 delims=/ " %%i in ('date/t') do set d=%%k%%i%%j echo date variable - set d = %d% for /F "tokens=1,2,3 delims=:. " %%i in ('time/t') do set t=%%i%%j%%k echo time variable - set t = %t% This is what I've used for several years.. you may need to adjust the settings based on your Regional settings Sign In·View Thread·PermaLink Re: Can be done with batch commands alone Anonymous 20:01 9 Mar '04   aaac007 wrote: for /F "tokens=2,3,4 delims=/ " %%i in ('date/t') do set d=%%k%%i%%j echo date variable - set d = %d% for /F "tokens=1,2,3 delims=:. " %%i in ('time/t') do set t=%%i%%j%%k echo time variable - set t = %t% Needed something quick and easy to copy a folder for daily backups. Your code block works great - thanks! My batch file: @ECHO OFF TITLE FILE - FOLDER COPY :BEGIN SET CURFOLDERPATH="K:/Inetpub/wwwroot/elearn/" SET NEWFOLDERPATH="K:/Inetpub/wwwroot/elearn-" FOR /F "tokens=2,3,4 delims=/ " %%i in ('date/t') do set d=%%k%%i%%j FOR /F "tokens=1,2,3 delims=:. " %%i in ('time/t') do set t=%%i%%j%%k ECHO Copy Folder: ECHO. ECHO 1.) COPY FOLDER. ECHO 2.) QUIT ECHO. CHOICE /C:12 /N Enter Selection: IF ERRORLEVEL ==2 GOTO END IF ERRORLEVEL ==1 GOTO XCOPYDIR :XCOPYDIR XCOPY %CURFOLDERPATH%*.* %NEWFOLDERPATH%%d%%t% /E/W/F/H/K/I PAUSE :END Exit Sign In·View Thread·PermaLink

Last Visit: 16:39 22 Nov '09     Last Update: 16:39 22 Nov '09 1