Set Primary Display (ChangeDisplaySettingsEx)

Imports System.Runtime.InteropServices

Class clsPrimaryScreen
    Public Shared Function NewDevMode() As WinAPI.DEVMODE
        Dim dm As New WinAPI.DEVMODE()
        dm.dmDeviceName = New [String](New Char(30) {})
        dm.dmFormName = New [String](New Char(30) {})
        dm.dmSize = CUShort(Marshal.SizeOf(dm))
        Return dm
    End Function
    Public Shared Function SetPrimary(Optional ByVal oNewPrimary As Screen = Nothing) As Boolean
        ' Only tested on dual monitors but may (should) work on more.
        Dim result As WinAPI.DisplaySetting_Results = 0
        Dim OldPrimary As String = Screen.PrimaryScreen.DeviceName
        Dim NewPrimary As String = ""
        If oNewPrimary Is Nothing Then
            For Each oScreen As Screen In Screen.AllScreens
                If Not oScreen.Primary Then
                    oNewPrimary = oScreen
                    Exit For
                End If
            Next
        End If
        If Not oNewPrimary Is Nothing Then
            NewPrimary = oNewPrimary.DeviceName
        ElseIf oNewPrimary.Primary Then
            Return True
        Else
            Return False
        End If

        ' Offset. All monitors must change position based on these offsets to maintain relative position to each other.
        Dim iOffsetX As Integer = 0 - oNewPrimary.WorkingArea.Location.X
        Dim iOffsetY As Integer = 0 - oNewPrimary.WorkingArea.Location.Y

        ' Get settings needed for new monitor positions after primary change.
        Dim lSettings As New List(Of clsScreenSettings)
        Dim oSetting As clsScreenSettings
        For Each oScr As Screen In Screen.AllScreens
            oSetting = New clsScreenSettings
            oSetting.DeviceName = oScr.DeviceName
            oSetting.X = oScr.WorkingArea.Location.X + iOffsetX
            oSetting.Y = oScr.WorkingArea.Location.Y + iOffsetY
            lSettings.Add(oSetting)
        Next

        Dim oDevMode As DEVMODE
        ' Set new primary position and primary flag
        For Each oSetting In lSettings
            If oSetting.DeviceName <> NewPrimary Then Continue For
            Dim oDevFlags As DeviceFlags
            oDevFlags = CType(CInt(WinAPI.DeviceFlags.CDS_SET_PRIMARY) Or CInt(WinAPI.DeviceFlags.CDS_UPDATEREGISTRY) Or CInt(WinAPI.DeviceFlags.CDS_NORESET), DeviceFlags)
            oDevMode = NewDevMode()
            oDevMode.dmFields = WinAPI.DEVMODE_Flags.DM_POSITION
            oDevMode.dmPosition.x = oSetting.X
            oDevMode.dmPosition.y = oSetting.Y
            result = DirectCast(WinAPI.ChangeDisplaySettingsEx(oSetting.DeviceName, oDevMode, 0, oDevFlags, 0), WinAPI.DisplaySetting_Results)

            ' Apply Changes. If we don't apply changes now the screens' positions will be off.
            oDevMode = NewDevMode()
            result = DirectCast(WinAPI.ChangeDisplaySettingsEx(OldPrimary, oDevMode, 0, CType(WinAPI.DeviceFlags.CDS_RESET, DeviceFlags), 0), WinAPI.DisplaySetting_Results)
            If result <> DisplaySetting_Results.DISP_CHANGE_SUCCESSFUL Then Return False
            Exit For
        Next

        ' Set the posotion of all non-primary screens.
        For Each oSetting In lSettings
            If oSetting.DeviceName = NewPrimary Then Continue For
            Dim oDevFlags As DeviceFlags
            oDevFlags = CType(CInt(WinAPI.DeviceFlags.CDS_UPDATEREGISTRY) Or CInt(WinAPI.DeviceFlags.CDS_NORESET), DeviceFlags)
            oDevMode = NewDevMode()
            oDevMode.dmFields = WinAPI.DEVMODE_Flags.DM_POSITION
            oDevMode.dmPosition.x = oSetting.X
            oDevMode.dmPosition.y = oSetting.Y
            result = DirectCast(WinAPI.ChangeDisplaySettingsEx(oSetting.DeviceName, oDevMode, 0, oDevFlags, 0), WinAPI.DisplaySetting_Results)
        Next

        ' Apply Changes
        oDevMode = NewDevMode()
        result = DirectCast(WinAPI.ChangeDisplaySettingsEx(OldPrimary, oDevMode, 0, CType(WinAPI.DeviceFlags.CDS_RESET, DeviceFlags), 0), WinAPI.DisplaySetting_Results)
        If result <> DisplaySetting_Results.DISP_CHANGE_SUCCESSFUL Then Return False

        Return True
    End Function
End Class
Class clsScreenSettings
    Public X As Integer
    Public Y As Integer
    Public DeviceName As String
End Class