Click here to Skip to main content
15,867,568 members
Articles / Programming Languages / VBScript

Use Date & Time in Batch/Log Files

Rate me:
Please Sign up or sign in to vote.
2.83/5 (6 votes)
1 Feb 2008CPOL1 min read 176.8K   14   15
Use date and time in batch/log files

Introduction

Have you ever tried to use date and time in logfiles or batch/command files?
This is not easy without special software. For me, this was a problem because I needed a separate logfile every time an event happened. I also needed this to create backup schedules. The possibilities of batch command are too limited, and different language OS will react differently, so it is hard to roll such batch files out in a multi language OS environment.

Solution

The solution is very simple. I run a VB script where it is easy to get date time and other parameters. These values are stored in environment variables which can be used in batch files.
Because these environment variables are only valid in that particular shell, we need to call the batch file within the VB Script.

Copy the following code in a file called RunNow.cmd:

VBScript
'***********************************************
'
' RunNow.vbs
' (c) 2008 Computech.
'     Initially Version 2003.
'     2/2/2008 Extra Functionality
' Written by Peter Verijke
'
'***********************************************
Dim dDay, dLDOM, dLDOY, dLFOW, dLFOM
Dim ArgObj
Dim BatchFile
Dim sCommand

Dim WshShell ' as object
Dim objEnv ' as collection
Dim sGetMyVar  ' as string

' Get the Arguments object
Set ArgObj = WScript.Arguments

' Test to make sure there is at least one command line arg - the command
If ArgObj.Count < 1 Then
    DisplayHelpMessage
    WScript.Quit
End If

BatchFile = ArgObj(0)

Set WshShell = WScript.CreateObject("WScript.Shell")
Set objEnv = WshShell.Environment("PROCESS")

dNow = Now()
dLDOM = DateSerial(Year(dNow),Month(dNow) + 1,0)
dLDOY = DateSerial(Year(dNow) + 1, 1,0)
'Friday of this week
dLFOW = (dNow + (5 - Weekday(dNow, vbMonday)))
'Last Friday of Month
dLFOM = (dLDOM + (5 - Weekday(dLDOM, vbMonday)))

objEnv("Year") = Year(dNow)
objEnv("Month") = Right("0" & Month(dNow), 2)
objEnv("Day") = Right("0" & Day(dNow), 2)
objEnv("Hour") = Right("0" & Hour(dNow), 2)
objEnv("Minute") = Right("0" & Minute(dNow), 2)
objEnv("Second") = Right("0" & Second(dNow), 2)

'Day of Week
objEnv("DOW") = Weekday(dNow, vbMonday)
'Day of Week Name
objEnv("DOWN") = WeekDayName(WeekDay(dNow), 1)
'Week of Month
objEnv("WOM") = -Int(-((WEEKDAY(dNow-DAY(dNow)+1, 2) + DAY(dNow) -1) / 7))
'Last Day of Month
objEnv("LDOM") = Right("0" & Day(dLDOM), 2)
'Last Day of Year
objEnv("LDOY") = Right("0" & Day(dLDOY), 2)
'Last Friday of Week
objEnv("LFOW") = Right("0" & Day(dLFOW), 2)
'Last Friday of Month
objEnv("LFOM") = Right("0" & Day(dLFOM), 2)

sCommand = "%COMSPEC% /C " 

WshShell.Run(sCommand + BatchFile) 

WScript.Quit

'************************
'
' Display Help Message
'
'************************
Sub DisplayHelpMessage()
    Dim sHelpMessage
    sHelpMessage = "Usage:" & vbCrLf
    sHelpMessage = sHelpMessage & Wscript.FullName & _
	" RunNow <CommandFile|BatchFile>" & vbCrLf
    sHelpMessage = sHelpMessage & _
	"Optionally use environment variables in file: _
	%Year% %Month% %Day% %Hour% %Minute% %Second%" & vbCrLf
    sHelpMessage = sHelpMessage & _
	"%DOW% %DOWN% %WOM% %LDOM% %LDOY% %LFOW% %LFOM%" & vbCrLf
    WScript.Echo sHelpMessage
End Sub

Usage

As you can see in the source Help Message, it is sufficient to use the environment variables %Year% %Month% %Day% %Hour% %Minute% or %Second% in your batch files. To give an example: you could make a command file called mydir.cmd with the following contents:

dir > MyLog%Year%%Month%%Day%-%Hour%%Minute%%Second%.log 

Instead of running this file directly, run via the VB Script:

RunNow.vbs mydir.cmd 

Now, there are also some extra environment variables like Last Day of Month, Week of Month etc. These variables can also be used for naming or comparing to take other actions in batch files. I use it to create Day, Week and Month Backups for some data.

That's it.

I hope this will be useful to you.

License

This article, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)


Written By
Founder Computech bvba
Belgium Belgium
I´m a freelance ICT consultant and Technical Project Manager for the last 15 years already.
Before that, I was a Software Developer for the Pharmaceutical and Petrochemical industry.
I developed a very wide knowledge in the ICT world due to my intrest.
This includes Networking (Lan, Wan), Routing Switching Bridging, etc...
Windows environment, which has no secrets for me.
Developing: To many languages to mension here.
Of course, the latest one on the list is dot net.

Comments and Discussions

 
GeneralJust made use of this Pin
Offbeatmammal31-Dec-08 10:30
Offbeatmammal31-Dec-08 10:30 
Questionhow can i use this? Pin
blajarbot4-Jan-07 20:26
blajarbot4-Jan-07 20:26 
GeneralAM or PM Pin
Anonymous22-Jan-05 16:03
Anonymous22-Jan-05 16:03 
GeneralRe: AM or PM Pin
Anonymous22-Jan-05 16:39
Anonymous22-Jan-05 16:39 
GeneralRe: AM or PM Pin
____0113-Jan-07 16:44
____0113-Jan-07 16:44 
QuestionCan be done with batch commands alone Pin
Paul Bartlett17-Dec-03 23:27
Paul Bartlett17-Dec-03 23:27 
AnswerRe: Can be done with batch commands alone Pin
RabidCow18-Dec-03 9:11
RabidCow18-Dec-03 9:11 
GeneralRe: Can be done with batch commands alone Pin
funny thing18-Dec-03 9:54
funny thing18-Dec-03 9:54 
GeneralRe: Can be done with batch commands alone Pin
Peter Verijke18-Dec-03 23:13
Peter Verijke18-Dec-03 23:13 
GeneralRe: Can be done with batch commands alone Pin
Anonymous25-Mar-05 0:36
Anonymous25-Mar-05 0:36 
GeneralRe: Can be done with batch commands alone Pin
Anonymous8-Aug-05 8:45
Anonymous8-Aug-05 8:45 
AnswerRe: Can be done with batch commands alone Pin
Peter Verijke18-Dec-03 22:32
Peter Verijke18-Dec-03 22:32 
GeneralRe: Can be done with batch commands alone Pin
Paul Bartlett19-Dec-03 0:30
Paul Bartlett19-Dec-03 0:30 
GeneralRe: Can be done with batch commands alone Pin
aaac00724-Dec-03 2:32
aaac00724-Dec-03 2:32 
GeneralRe: Can be done with batch commands alone Pin
Anonymous9-Mar-04 19:01
Anonymous9-Mar-04 19:01 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Praise Praise    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.