Click here to Skip to main content
Click here to Skip to main content
Articles » Database » Database » Databases » Downloads
 
Add your own
alternative version

Object-Oriented database design with the DatabaseObjects library

, 31 Jan 2007
Demonstrates creating object-oriented database systems with the DatabaseObjects library.
databaseobjects_demo_net.zip
VB.NET
demo
source
Northwind
NorthwindDB
bin
Northwind.vbproj.user
AxInterop.SHDocVw.dll
DatabaseObjects.dll
Interop.SHDocVw.dll
Northwind.exe
NorthwindDatabase.dll
NorthwindDatabase.vbproj.user
Attributes
bin
Database
DatabaseObjects.vbproj.user
Misc
SQL
DatabaseObjects.dll
Data
mysql_northwind.zip
Documentation
DatabaseObjects.chm
databaseobjects_demo_vb6.zip
VB6
demo
regsvr32.exe
source
Northwind
Northwind.vbg
NorthwindDB
ControlAnchor.cls
frmMain.frm
frmMain.frx
frmOrder.frm
frmOrder.frx
frmProducts.frm
frmProducts.frx
frmProductSearch.frm
frmProductSearch.frx
frmProductSearchExtended.frm
frmProductSearchExtended.frx
frmSuppliers.frm
frmSuppliers.frx
Northwind.exe
northwind.RES
Northwind.vbp
Categories.cls
Category.cls
Data.bas
LateBoundObject.cls
NorthwindDatabase.cls
NorthwindDatabase.OBJ
NorthwindDB.dll
NorthwindDB.vbp
Order.cls
OrderDetail.cls
OrderDetails.cls
Orders.cls
Product.cls
Products.cls
ProductSearch.cls
Supplier.cls
Suppliers.cls
bin
Database.cls
DBO.vbp
GlobalDatabase.cls
GlobalDatabaseObjects.cls
IDatabaseObject.cls
IDatabaseObjects.cls
IGlobalDatabaseObjects.cls
ISQLStatement.cls
modMisc.bas
SQLAlterTable.cls
SQLAutoIncrementValue.cls
SQLCondition.cls
SQLConditionFieldCompare.cls
SQLConditionInSelect.cls
SQLConditions.cls
SQLConditionSelect.cls
SQLCreateIndex.cls
SQLCreateTable.cls
SQLDelete.cls
SQLDropIndex.cls
SQLDropTable.cls
SQLFieldValue.cls
SQLFieldValues.cls
SQLIndexExists.cls
SQLIndexField.cls
SQLIndexFields.cls
SQLInsert.cls
SQLSelect.cls
SQLSelectField.cls
SQLSelectFields.cls
SQLSelectGroupByField.cls
SQLSelectGroupByFields.cls
SQLSelectOrderByField.cls
SQLSelectOrderByFields.cls
SQLSelectTable.cls
SQLSelectTableJoin.cls
SQLSelectTableJoinCondition.cls
SQLSelectTableJoinConditions.cls
SQLSelectTableJoins.cls
SQLSelectTables.cls
SQLTableExists.cls
SQLTableField.cls
SQLTableFields.cls
SQLUpdate.cls
SQLUpdateCopyField.cls
SQLUpdateCopyFields.cls
DatabaseObjects_vb6.dll
mysql_northwind.zip
images
templates
databaseobjects_classdiagram.jpg
logo.jpg
databaseobjects_src_net.zip
DatabaseObjects.vbproj.user
DatabaseObjects.dll
databaseobjects_src_vb6.zip
Database.cls
DBO.vbp
GlobalDatabase.cls
GlobalDatabaseObjects.cls
IDatabaseObject.cls
IDatabaseObjects.cls
IGlobalDatabaseObjects.cls
ISQLStatement.cls
modMisc.bas
SQLAlterTable.cls
SQLAutoIncrementValue.cls
SQLCondition.cls
SQLConditionFieldCompare.cls
SQLConditionInSelect.cls
SQLConditions.cls
SQLConditionSelect.cls
SQLCreateIndex.cls
SQLCreateTable.cls
SQLDelete.cls
SQLDropIndex.cls
SQLDropTable.cls
SQLFieldValue.cls
SQLFieldValues.cls
SQLIndexExists.cls
SQLIndexField.cls
SQLIndexFields.cls
SQLInsert.cls
SQLSelect.cls
SQLSelectField.cls
SQLSelectFields.cls
SQLSelectGroupByField.cls
SQLSelectGroupByFields.cls
SQLSelectOrderByField.cls
SQLSelectOrderByFields.cls
SQLSelectTable.cls
SQLSelectTableJoin.cls
SQLSelectTableJoinCondition.cls
SQLSelectTableJoinConditions.cls
SQLSelectTableJoins.cls
SQLSelectTables.cls
SQLTableExists.cls
SQLTableField.cls
SQLTableFields.cls
SQLUpdate.cls
SQLUpdateCopyField.cls
SQLUpdateCopyFields.cls
DatabaseObjects_vb6.dll
' ___________________________________________________
'
'  � Hi-Integrity Systems 2007. All rights reserved.
'  www.hisystems.com.au - Toby Wicks
' ___________________________________________________
'

Option Strict On
Option Explicit On 

Imports DatabaseObjects

''' --------------------------------------------------------------------------------
''' <summary>
''' This is the controller class that initializes the lock table and the user
''' ID that is to be associated with all locking operations. In most situations,  
''' only one instance of this class is ever created and this instance is passed into
''' the constructor for all DatabaseObjectLockable and DatabaseObjectUsingAttributesLockable 
''' instances.
''' </summary>
''' --------------------------------------------------------------------------------
''' 
Public Class DatabaseObjectLockController

    Private pstrCurrentUserID As String
    Private pstrLockTableName As String
    Private pobjConnection As Database.ConnectionController

    Public Sub New(ByVal objDatabase As Database, ByVal strLockTableName As String, ByVal strCurrentUserID As String)

        If objDatabase Is Nothing Then
            Throw New ArgumentNullException("Database")
        ElseIf strCurrentUserID = String.Empty Then
            Throw New ArgumentNullException("User")
        ElseIf strLockTableName = String.Empty Then
            Throw New ArgumentNullException("Lock table name")
        End If

        pobjConnection = objDatabase.Connection
        pstrCurrentUserID = strCurrentUserID
        pstrLockTableName = strLockTableName

        EnsureTableExists()

    End Sub

    Private Function EnsureTableExists() As Boolean

        Dim bTableExists As Boolean
        Dim objTableExists As New SQL.SQLTableExists(pstrLockTableName)

        pobjConnection.Start()

        With pobjConnection.Execute(objTableExists)
            bTableExists = .Read
            .Close()
        End With

        If Not bTableExists Then
            pobjConnection.ExecuteNonQuery(CreateTable)
            pobjConnection.ExecuteNonQuery(CreateTableIndex)
        End If

        pobjConnection.Finished()

    End Function

    Friend ReadOnly Property IsLocked(ByVal strTableName As String, ByVal objObject As IDatabaseObject) As Boolean
        Get

            Return Me.LockRecordExists(strTableName, objObject)

        End Get
    End Property

    Friend ReadOnly Property IsLockedByCurrentUser(ByVal strTableName As String, ByVal objObject As IDatabaseObject) As Boolean
        Get

            Return Me.LockRecordExists(strTableName, objObject, _
                New SQL.SQLCondition("UserID", SQL.ComparisonOperator.EqualTo, pstrCurrentUserID))

        End Get
    End Property

    Friend ReadOnly Property LockedByUserID(ByVal strTableName As String, ByVal objObject As IDatabaseObject) As String
        Get

            If Not Me.IsLocked(strTableName, objObject) Then
                Throw New MethodAccessException("Object is not locked")
            End If

            Dim objSelect As New SQL.SQLSelect

            objSelect.Fields.Add("UserID")
            objSelect.Tables.Add(pstrLockTableName)
            objSelect.Where.Add("TableName", SQL.ComparisonOperator.EqualTo, strTableName)
            objSelect.Where.Add("RecordID", SQL.ComparisonOperator.EqualTo, CStr(objObject.DistinctValue))

            pobjConnection.Start()
            Dim objReader As IDataReader = pobjConnection.Execute(objSelect)
            objReader.Read()

            LockedByUserID = CStr(objReader(0))

            objReader.Close()
            pobjConnection.Finished()

        End Get
    End Property

    Private Function LockRecordExists( _
        ByVal strTableName As String, _
        ByVal objObject As IDatabaseObject, _
        Optional ByVal objAdditionalCondition As SQL.SQLCondition = Nothing) As Boolean

        Dim objSelect As New SQL.SQLSelect

        objSelect.Fields.Add(String.Empty, SQL.AggregateFunction.Count)
        objSelect.Tables.Add(pstrLockTableName)
        objSelect.Where.Add("TableName", SQL.ComparisonOperator.EqualTo, strTableName)
        objSelect.Where.Add("RecordID", SQL.ComparisonOperator.EqualTo, CStr(objObject.DistinctValue))
        If Not objAdditionalCondition Is Nothing Then
            objSelect.Where.Add(objAdditionalCondition)
        End If

        pobjConnection.Start()
        Dim objReader As IDataReader = pobjConnection.Execute(objSelect)
        objReader.Read()

        LockRecordExists = CInt(objReader(0)) <> 0

        objReader.Close()
        pobjConnection.Finished()

    End Function

    Friend Sub Lock(ByVal strTableName As String, ByVal objObject As IDatabaseObject)

        If Me.IsLocked(strTableName, objObject) Then
            Throw New MethodAccessException("Table already locked")
        End If

        Dim objInsert As New SQL.SQLInsert
        objInsert.TableName = pstrLockTableName
        objInsert.Fields.Add("TableName", strTableName)
        objInsert.Fields.Add("RecordID", CStr(objObject.DistinctValue))
        objInsert.Fields.Add("UserID", pstrCurrentUserID)

        pobjConnection.Start()
        pobjConnection.ExecuteNonQuery(objInsert)
        pobjConnection.Finished()

    End Sub

    Friend Sub UnLock(ByVal strTableName As String, ByVal objObject As IDatabaseObject)

        'If the table is locked by someone else
        If Not Me.IsLockedByCurrentUser(strTableName, objObject) Then
            Throw New MethodAccessException("Table already locked")
        End If

        Dim objDelete As New SQL.SQLDelete
        objDelete.TableName = pstrLockTableName
        objDelete.Where.Add("TableName", SQL.ComparisonOperator.EqualTo, strTableName)
        objDelete.Where.Add("RecordID", SQL.ComparisonOperator.EqualTo, CStr(objObject.DistinctValue))
        objDelete.Where.Add("UserID", SQL.ComparisonOperator.EqualTo, pstrCurrentUserID)

        pobjConnection.Start()
        pobjConnection.ExecuteNonQuery(objDelete)
        pobjConnection.Finished()

    End Sub

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Provides a means by which to ensure all locks have been removed for this user
    ''' in situations where an unexpected exception occurs and/or the user logs out of 
    ''' system.
    ''' </summary>
    ''' --------------------------------------------------------------------------------
    Public Sub UnlockAll()

        Dim objDelete As New SQL.SQLDelete
        objDelete.TableName = pstrLockTableName
        objDelete.Where.Add("UserID", SQL.ComparisonOperator.EqualTo, pstrCurrentUserID)

        pobjConnection.Start()
        pobjConnection.ExecuteNonQuery(objDelete)
        pobjConnection.Finished()

    End Sub

    Private Function CreateTable() As SQL.SQLStatement

        Dim objTable As New SQL.SQLCreateTable

        objTable.Name = pstrLockTableName
        objTable.Fields.Add("TableName", SQL.DataType.VariableCharacter, 50)
        objTable.Fields.Add("RecordID", SQL.DataType.VariableCharacter, 20)
        objTable.Fields.Add("UserID", SQL.DataType.VariableCharacter, 20)

        Return objTable

    End Function

    Private Function CreateTableIndex() As SQL.SQLStatement

        Dim objIndex As New SQL.SQLCreateIndex

        objIndex.Name = "Primary"
        objIndex.TableName = pstrLockTableName
        objIndex.Fields.Add("TableName")
        objIndex.Fields.Add("RecordID")
        objIndex.Fields.Add("UserID")

        Return objIndex

    End Function

End Class

By viewing downloads associated with this article you agree to the Terms of Service and the article's licence.

If a file you wish to view isn't highlighted, and is a text file (not binary), please let us know and we'll add colourisation support for it.

License

This article has no explicit license attached to it but may contain usage terms in the article text or the download files themselves. If in doubt please contact the author via the discussion board below.

A list of licenses authors might use can be found here

Share

About the Author

Toby Wicks

United States United States
No Biography provided

| Advertise | Privacy | Terms of Use | Mobile
Web03 | 2.8.1411023.1 | Last Updated 31 Jan 2007
Article Copyright 2005 by Toby Wicks
Everything else Copyright © CodeProject, 1999-2014
Layout: fixed | fluid