Editable DataGrid Binding - VS 2003 RAD approach (ASP.NET 1.1) - EditGrid

Public Class WebForm1
    Inherits System.Web.UI.Page

#Region " Web Form Designer Generated Code "

    'This call is required by the Web Form Designer.
    <System.Diagnostics.DebuggerStepThrough()> Private Sub InitializeComponent()
        Me.DatasetEditGrid1 = New EditGrid.DatasetEditGrid
        CType(Me.DatasetEditGrid1, System.ComponentModel.ISupportInitialize).BeginInit()
        '
        'DatasetEditGrid1
        '
        Me.DatasetEditGrid1.DataSetName = "DatasetEditGrid"
        Me.DatasetEditGrid1.Locale = New System.Globalization.CultureInfo("en-US")
        CType(Me.DatasetEditGrid1, System.ComponentModel.ISupportInitialize).EndInit()

    End Sub
    Protected WithEvents DatasetEditGrid1 As EditGrid.DatasetEditGrid
    Protected WithEvents DataGrid1 As System.Web.UI.WebControls.DataGrid

    'NOTE: The following placeholder declaration is required by the Web Form Designer.
    'Do not delete or move it.
    Private designerPlaceholderDeclaration As System.Object

    Private Sub Page_Init(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Init
        'CODEGEN: This method call is required by the Web Form Designer
        'Do not modify it using the code editor.
        InitializeComponent()
    End Sub

#End Region

    Private Sub Page_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        If Not Me.IsPostBack Then

            'Fill values into your dataset.
            'If using a database data source, replace this with your adapter.fill
            With Me.DatasetEditGrid1.EditGrid
                .AddEditGridRow("Robert", "Site 1", True)
                .AddEditGridRow("Bill", "Site 2", False)
                .AddEditGridRow("Joe", "Site1", True)
            End With

            'Cache dataset. (You can also use session to cache)
            Me.ViewState("DatasetEditGrid1") = Me.DatasetEditGrid1
        Else
            'Point to the cached dataset.
            Me.DatasetEditGrid1 = CType(Me.ViewState("DatasetEditGrid1"), DatasetEditGrid)
        End If
    End Sub

    Private Sub DataGrid1_EditCommand(ByVal source As Object, ByVal e As System.Web.UI.WebControls.DataGridCommandEventArgs) Handles DataGrid1.EditCommand
        Me.DataGrid1.EditItemIndex = e.Item.ItemIndex
    End Sub

    Private Sub DataGrid1_UpdateCommand(ByVal source As Object, ByVal e As System.Web.UI.WebControls.DataGridCommandEventArgs) Handles DataGrid1.UpdateCommand
        UpdateDatasetFromGrid()
        Me.DataGrid1.EditItemIndex = -1
    End Sub

    'Relate the Dataset's Column Names to the Column Index in the Datagrid
    Private Enum DatasetColumnNameToGridColumnIndex
        Name = 1
        Location = 2
        ClockedIn = 3
    End Enum

    'Reverse bind from the datagrid to the dataset.
    Private Sub UpdateDatasetFromGrid()
        For Each ColName As DatasetColumnNameToGridColumnIndex In System.Enum.GetValues(GetType(DatasetColumnNameToGridColumnIndex))
            SetDatasetValuesFromGrid(Me.DatasetEditGrid1.EditGrid, ColName.ToString, Me.DataGrid1.Items(Me.DataGrid1.EditItemIndex), ColName)
        Next

        'Normally you would save (adapter.update) to the database here.
    End Sub

    'Generic Code to do Reverse binding from a DataGridItem cell to its corresponding DataTable item.
    Private Sub SetDatasetValuesFromGrid(ByVal DataTable As DataTable, ByVal DataTableColumnName As String, ByVal DataGridItem As DataGridItem, ByVal DataGridCellIndex As Integer)
        For Each control As Control In DataGridItem.Cells(DataGridCellIndex).Controls
            If TypeOf control Is CheckBox Then
                Me.DatasetEditGrid1.EditGrid(DataGridItem.DataSetIndex)(DataTableColumnName) = CType(control, CheckBox).Checked
                Exit For
            ElseIf TypeOf control Is TextBox Then
                Me.DatasetEditGrid1.EditGrid(DataGridItem.DataSetIndex)(DataTableColumnName) = CType(control, TextBox).Text
                Exit For
            End If
        Next
    End Sub

    Private Sub DataGrid1_CancelCommand(ByVal source As Object, ByVal e As System.Web.UI.WebControls.DataGridCommandEventArgs) Handles DataGrid1.CancelCommand
        Me.DataGrid1.EditItemIndex = -1
    End Sub

    'Always bind the grid to the dataset just before rendering.  This will show the most recent state.
    Private Sub DataGrid1_PreRender(ByVal sender As Object, ByVal e As System.EventArgs) Handles DataGrid1.PreRender
        'Bind the Grid.
        Me.DataGrid1.DataBind()
    End Sub

End Class