Custom Configuration Sections in .NET 2.0

Imports System.Configuration
Public Class ConfigurationSample
   Inherits System.Configuration.ConfigurationSection

   Private m_cfg As Configuration

#Region " Instance methods "
   Public Sub Encript(ByVal encript As Boolean)
      If encript Then
         Me.SectionInformation.ProtectSection("DataProtectionConfigurationProvider")
      Else
         Me.SectionInformation.UnprotectSection()
      End If
      Me.Save()
   End Sub

   Public Sub Save()
      Me.SectionInformation.ForceSave = True
      m_cfg.Save(ConfigurationSaveMode.Full)
   End Sub

#End Region

#Region " Properties "

   <ConfigurationProperty("oneProperty", _
                          DefaultValue:="a Default Value", _
                          IsRequired:=True, IsKey:=True)> _
   Public Property OneProperty() As String
      Get
         Return CStr(Me("oneProperty"))
      End Get
      Set(ByVal value As String)
         Me("oneProperty") = value
      End Set
   End Property

   <ConfigurationProperty("oneNumericValue", DefaultValue:=55)> _
   Public Property OneNumericValue() As Integer
      Get
         Return CInt(Me("oneNumericValue"))
      End Get
      Set(ByVal value As Integer)
         Me("oneNumericValue") = value
      End Set
   End Property

   <ConfigurationProperty("oneElement", IsRequired:=True)> _
   Public ReadOnly Property OneElement() As ConfigurationSampleElementClass
      Get
         Return DirectCast(Me("oneElement"), _
                           ConfigurationSampleElementClass)
      End Get
   End Property

#End Region

#Region " Shared methods "
   Private Const CS_SECTION As String = "sampleConfiguration"
   Private Shared m_current As ConfigurationSample

   Public Shared ReadOnly Property Current() As ConfigurationSample
      Get
         If m_current Is Nothing Then
            Dim cfg As Configuration
            Dim ctx As System.Web.HttpContext = System.Web.HttpContext.Current
            If ctx Is Nothing Then
               cfg = ConfigurationManager.OpenExeConfiguration(ConfigurationUserLevel.None)
            Else
               cfg = System.Web.Configuration.WebConfigurationManager.OpenWebConfiguration(ctx.Request.ApplicationPath)
            End If
            m_current = DirectCast(cfg.Sections(CS_SECTION), _
                                   ConfigurationSample)
            m_current.m_cfg = cfg
         End If
            Return m_current
            'You could use this code if all that you need is to read the configuration.
            'Return DirectCast(ConfigurationManager.GetSection(CS_SECTION), _
            '                          ConfigurationSample)
      End Get
   End Property

#End Region

End Class

Public Class ConfigurationSampleElementClass
   Inherits ConfigurationElement

   <ConfigurationProperty("anotherProperty", IsRequired:=True)> _
   Public Property AnotherProperty() As String
      Get
         Return CStr(Me("anotherProperty"))
      End Get
      Set(ByVal value As String)
         Me("anotherProperty") = value
      End Set
   End Property
End Class