Click here to Skip to main content
11,634,631 members (74,218 online)
Click here to Skip to main content
Add your own
alternative version

Using a Wiki for knowledge sharing and SQL Server database documentation

, 7 Feb 2004 303.7K 2.5K 194
This article describes using a Wiki for knowledge sharing and database schema documentation.
wiki_src.zip
attachments
images
Help
edit_comment.gif
Thumbs.db
Wiki
DatabaseSchema.gif
DeprecatedBanner.gif
FindPage.gif
HelpBanner.gif
Key.gif
NoTick.gif
Thumbs.db
Tick.gif
UserPreferences.gif
ow
css
images
banner_logo.gif
banner_search.gif
banner_title.gif
breadcrumb_divider.gif
dashed_line.gif
delico.gif
edit_icon.gif
find_icon.gif
grey_box_left.gif
grey_box_line.gif
grey_box_right.gif
hidden_off.gif
hidden_on.gif
icons
doc
asp.gif
avi.gif
bmp.gif
chm.gif
doc.gif
empty.gif
gif.gif
gz.gif
htm.gif
html.gif
jpeg.gif
jpg.gif
mov.gif
mp3.gif
mpeg.gif
mpg.gif
pdf.gif
png.gif
ppt.gif
Thumbs.db
txt.gif
wav.gif
xls.gif
xml.gif
xsl.gif
zip.gif
emoticon-8.gif
emoticon-ambivalent.gif
emoticon-b.gif
emoticon-c.gif
emoticon-cat.gif
emoticon-d.gif
emoticon-e.gif
emoticon-f.gif
emoticon-g.gif
emoticon-h.gif
emoticon-i.gif
emoticon-k.gif
emoticon-l.gif
emoticon-laugh.gif
emoticon-m.gif
emoticon-n.gif
emoticon-p.gif
emoticon-s.gif
emoticon-sad.gif
emoticon-smile.gif
emoticon-star.gif
emoticon-surprised.gif
emoticon-t.gif
emoticon-tongue-in-cheek.gif
emoticon-u.gif
emoticon-unsure.gif
emoticon-wink.gif
emoticon-wink_old.gif
emoticon-y.gif
icon-error.gif
icon-info.gif
icon-warning.gif
Thumbs.db
wiki-ftp.gif
wiki-http.gif
wiki-mailto.gif
wiki-news.gif
wiki-telnet.gif
wiki-wiki.gif
icon_edit.gif
icon_print.gif
icon_revisions.gif
logo.gif
logo_aggregator.gif
logo_tiny.gif
popup.gif
popup2.gif
poweredby.gif
revs.gif
rss_button.gif
Thumbs.db
undo.gif
valid-css.gif
valid-xhtml10.gif
xml.gif
my
xsl
mystyle.xsl
ow.xsl
owattach.xsl
owinc.xsl
owrss09.xsl
owrss091.xsl
owrss10.xsl
owrss10aggr.xsl
owrss10export.xsl
owscriptingnews.xsl
xmldisplay.xsl
data
wiki.mdb
wikidb.mdf
<%
'
' ---------------------------------------------------------------------------
' Copyright(c) 2000-2002, Laurens Pit
' All rights reserved.
'
' Redistribution and use in source and binary forms, with or without
' modification, are permitted provided that the following conditions
' are met:
'
'   * Redistributions of source code must retain the above copyright
'     notice, this list of conditions and the following disclaimer.
'   * Redistributions in binary form must reproduce the above
'     copyright notice, this list of conditions and the following
'     disclaimer in the documentation and/or other materials provided
'     with the distribution.
'   * Neither the name of OpenWiki nor the names of its contributors
'     may be used to endorse or promote products derived from this
'     software without specific prior written permission.
'
' THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
' "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
' LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
' FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
' REGENTS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
' INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
' BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
' LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
' CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
' LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
' ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
' POSSIBILITY OF SUCH DAMAGE.
'
' ---------------------------------------------------------------------------
'      $Source: /usr/local/cvsroot/openwiki/dist/owbase/ow/owregexp.asp,v $
'    $Revision: 1.3 $
'      $Author: pit $
' ---------------------------------------------------------------------------
'
' These functions simulate the m and s operations as available in the
' programming language perl. You can usually literally copy perl regular
' expressions and expect them to work with these functions.
'
' In perl you can do something like:
'
'     s/A(.*?)B(.*?)C/&MyMethod($1, $2)/ge
'
' When the match is made this will call the sub "MyMethod", pass it
' the two matched variables, and finally the match is substituted
' by whatever the sub returns.
'
' The function s below can behave in a similar manner. The perl expression
' shown above would be written as:
'
'     myText = s(myText, "A(.*?)B(.*?)C", "&MyMethod($1, $2)", True, True)
'
' In ASP the sub must return the value to be substituted via the global
' parameter sReturn. E.g.
'
'     Sub MyMethod(pParam1, pParam2)
'         If pParam1 = pParam2 Then
'             sReturn = "Same"
'         Else
'             sReturn = "Different"
'         End If
'     End Sub
'

' Global register which subs (called by s) should use to return their value.
Dim sReturn

' Reuse regular expression object
On Error Resume Next
Dim gRegEx
Set gRegEx = New RegExp
If Not IsObject(gRegEx) Then
    Response.Write("<h2>Error:</h2><p>Probable cause: Registry permission problem.</p>")
    Response.Write("This is a known problem with Microsoft.<br />" _
                 & "You can find more information about this problem in the following  " _
                 & "<a href=""http://support.microsoft.com/support/kb/articles/Q274/0/38.ASP"">Microsoft knowledge base article</a>.")
    Response.End
End If
On Error Goto 0


Function m(pText, pPattern, pIgnoreCase, pGlobal)
    If IsNull(pText) Then
        m = False
        Exit Function
    End If
    gRegEx.IgnoreCase = pIgnoreCase
    gRegEx.Global     = pGlobal
    gRegEx.Pattern    = pPattern
    m = gRegEx.Test(pText)
End Function


Function s(pText, pSearchPattern, pReplacePattern, pIgnoreCase, pGlobal)
    'Response.Write("<br /><br />Text: " & Server.HTMLEncode(pText))
    'Response.Write("<br />Patterns: " & Server.HTMLEncode(pSearchPattern) & " --> " & Server.HTMLEncode(pReplacePattern))

    If IsNull(pText) Then
        s = ""
        Exit Function
    End If

    gRegEx.IgnoreCase = pIgnoreCase
    gRegEx.Global     = pGlobal
    gRegEx.Pattern    = pSearchPattern
    If (Left(pReplacePattern, 1) <> "&") Then
        s = gRegEx.Replace(pText, pReplacePattern)
    Else
        Dim vText, vPrevLastIndex, vPrevNewPos
        Dim vMatch, vMatches, vSubMatch, i, vCmd, vReplacement

        vText          = pText
        vPrevLastIndex = 0
        vPrevNewPos    = 0

        pReplacePattern = Mid(pReplacePattern, 2)

        Set vMatches = gRegEx.Execute(pText)
        For Each vMatch In vMatches
            vCmd = pReplacePattern

            i = 0
            For Each vSubMatch in vMatch.SubMatches
                'Response.Write("<br />SubMatch: " & Server.HTMLEncode(vSubMatch))
                vCmd = Replace(vCmd, "$" & (i + 1), """" & Replace(vSubMatch, """", """""") & """")
                i = i+ 1
            Next

            'Response.Write("<br />REGEXP CMD: " & Server.HTMLEncode(vCmd))

            sReturn = ""
            vCmd = Replace(vCmd, vbCRLF, """ & vbCRLF & """)
            Execute("Call " & vCmd)
            vReplacement = sReturn

            ' replace vMatch.Value in vText by vReplacement
            vPrevNewPos = vPrevNewPos + (vMatch.FirstIndex - vPrevLastIndex)
            vText = Mid(vText, 1, vPrevNewPos) & vReplacement & Mid(vText, vPrevNewPos + vMatch.Length + 1)
            vPrevNewPos = vPrevNewPos + Len(vReplacement) + 1
            vPrevLastIndex = vMatch.FirstIndex + vMatch.Length + 1
        Next
        s = vText
    End If
End Function

%>

By viewing downloads associated with this article you agree to the Terms of Service and the article's licence.

If a file you wish to view isn't highlighted, and is a text file (not binary), please let us know and we'll add colourisation support for it.

License

This article has no explicit license attached to it but may contain usage terms in the article text or the download files themselves. If in doubt please contact the author via the discussion board below.

A list of licenses authors might use can be found here

Share

About the Author

Jonathan Hodgson
Web Developer
United Kingdom United Kingdom
Jonathan Hodgson works as Software Developer in London, UK.

He started programming in the '80s on a trusty 48k Spectrum before moving to PC development in the early 90s. During the working week most of his time is spent involved in application development both Windows and Web-based; .NET, C#, ASP.NET, SQL Server.

He is a Microsoft Certified Software Developer (MCSD) and MCP for developing web applications using ASP.NET in C# and is always looking for new projects and challenges to work on.

http://www.jonathanhodgson.co.uk/

You may also be interested in...

| Advertise | Privacy | Terms of Use | Mobile
Web03 | 2.8.150728.1 | Last Updated 8 Feb 2004
Article Copyright 2004 by Jonathan Hodgson
Everything else Copyright © CodeProject, 1999-2015
Layout: fixed | fluid