Click here to Skip to main content
15,885,065 members
Articles / Web Development / HTML

A Class to Print and Print Preview a DataGrid or DataGridView Control

Rate me:
Please Sign up or sign in to vote.
4.76/5 (38 votes)
24 Jan 2016CPOL2 min read 479.5K   9.8K   131   127
A class to add to your application to generate nicely formatted prints from a DataGrid.

Introduction

The System.Windows.Forms.DataGrid control is one of the most powerful and frequently used controls in the .NET arsenal and this class (DataGridPrinter) adds functionality to allow you to generate print and print previews from your datagrid in a tidy and customizable layout.

Image 1

To Draw a Grid, First Draw a Square

Image 2

The basic operation when drawing a datagrid is to draw a rectangle and fit text inside it. To do this, I have a single subroutine called DrawCellString which draws a string inside a cell according to the alignment and format parameters passed in.

VB
Public Function DrawCellString(ByVal s As String, _
      ByVal HorizontalAlignment As CellTextHorizontalAlignment, _
      ByVal VerticalAlignment As CellTextVerticalAlignment, _
      ByVal BoundingRect As Rectangle, _
      ByVal DrawRectangle As Boolean, _
      ByVal Target As Graphics, _
      ByVal PrintFont As Font)


        Dim x As Single, y As Single

        If DrawRectangle Then
            Target.DrawRectangle(_GridPen, BoundingRect)
        End If

        '\\ Set the text alignment
        If HorizontalAlignment = 
              CellTextHorizontalAlignment.LeftAlign Then
            _Textlayout.Alignment = StringAlignment.Near
        ElseIf HorizontalAlignment = 
                   CellTextHorizontalAlignment.RightAlign _
        Then
             _Textlayout.Alignment = StringAlignment.Far
        Else
             _Textlayout.Alignment = StringAlignment.Center
        End If

        Dim BoundingRectF As New RectangleF(BoundingRect.X + _CellGutter, _ 
                                BoundingRect.Y + _CellGutter,  _ 
                                BoundingRect.Width - (2 * _CellGutter),  _ 
                                BoundingRect.Height - (2 * _CellGutter))

        Target.DrawString(s, PrintFont, System.Drawing.Brushes.Black, _ 
                          BoundingRectF, _Textlayout)

End Function

There are two class level variables that are used to define how a cell is drawn: CellGutter specifies a margin (in pixels) between the edge of the string bounding box and the GridPen is the pen used to draw the box.

Now You Can Draw a Box, You Can Draw a Row

There are two types of rows you need to print in order to print a grid: a row of column headers and a row of data. This class always starts each new page with a row of column headers.

VB
Private Sub PrintGridHeaderLine(ByVal e As _
          System.Drawing.Printing.PrintPageEventArgs)

    Dim Top As Double = _PageContentRectangle.Top
    Dim Bottom As Double = Top + _Rowheight + (2 * _CellGutter)

    Top = RoundTo(Top, 2)
    Bottom = RoundTo(Bottom, 2)

    Dim nColumn As Integer

    For nColumn = 0 To GridColumnCount() - 1
        Dim rcCell As New Rectangle(_ColumnBounds(nColumn).Left, Top, _
                             _ColumnBounds(nColumn).Width, Bottom - Top)
        Call DrawCellString(GetColumnHeadingText(nColumn),  _
                            CellTextHorizontalAlignment.CentreAlign, _
                            CellTextVerticalAlignment.MiddleAlign, _
                            rcCell, True, e.Graphics, _PrintFont)
    Next
End Sub

This is fairly straightforward. The only tricky bit is getting the title of the column from the datagrid which is done thus:

VB
Private Function GetColumnHeadingText(ByVal Column As Integer) As String

    If TypeOf _DataGrid.DataSource Is DataTable Then
        Return CType(_DataGrid.DataSource, _
                    DataTable).Columns(Column).ToString
    ElseIf TypeOf _DataGrid.DataSource Is DataSet Then
        Return CType(_DataGrid.DataSource, DataSet).Tables( _
                  _DataGrid.DataMember).Columns(Column).ToString
    ElseIf TypeOf _DataGrid.DataSource Is DataView Then
        Return CType(_DataGrid.DataSource, _
                DataView).Table.Columns(Column).ToString
    Else
        'TODO : Get the column caption....
    End If
End Function

And to print a row of data, we do the same thing but with the row content of the current row:

VB
Private Sub PrintGridLine(ByVal e As _
         System.Drawing.Printing.PrintPageEventArgs, _ 
              ByVal RowNumber As Integer)

        Dim RowFromTop As Integer = RowNumber + 1 - _CurrentPrintGridLine
        Dim Top As Double = _PageContentRectangle.Top + (RowFromTop * _
                                         ((_CellGutter * 2) + _Rowheight))
        Dim Bottom As Double = Top + _Rowheight + (2 * _CellGutter)

        Top = RoundTo(Top, 2)
        Bottom = RoundTo(Bottom, 2)

        Dim Items() As Object

            If TypeOf _DataGrid.DataSource Is DataTable Then
                Items = CType(_DataGrid.DataSource, _
                        System.Data.DataTable).DefaultView.Item(_
                                         RowNumber - 1).Row.ItemArray
            ElseIf TypeOf _DataGrid.DataSource Is DataSet Then
                Items = CType(_DataGrid.DataSource, _
                              System.Data.DataSet).Tables(     _
                                _DataGrid.DataMember).DefaultView.Item(_
                                             RowNumber - 1).Row.ItemArray
            ElseIf TypeOf _DataGrid.DataSource Is DataView Then
                Items = CType(_DataGrid.DataSource, _
                         System.Data.DataView).Table.DefaultView.Item( _
                                             RowNumber - 1).Row.ItemArray
            Else
                'TODO : Get the content for the current row from the data 
                '       source ....
            End If

            Dim nColumn As Integer
            For nColumn = 0 To Items.Length - 1
                Dim rcCell As New Rectangle(_ColumnBounds(nColumn).Left, Top,_
                       _ColumnBounds(nColumn).Width, Bottom - Top)
                Call DrawCellString(Items(nColumn).ToString, _ 
                               CellTextHorizontalAlignment.CentreAlign, _ 
                               CellTextVerticalAlignment.MiddleAlign,  _ 
                               rcCell, True, e.Graphics, _PrintFont)
            Next
End Sub

Fitting It All Onto a Page

Image 3

The printed page is divided into three areas: the header, the body and the footer. There is also an InterSectionSpacing property that specifies a gap to use between the sections. These are all expressed as percentages of the page height and setting any of them to zero will omit that section.

The body section is worked out from what remains of the page height when the header, footer and inter section spacing have been added up and this is used to calculate how many rows can possibly fit on each page:

VB
Private Function RowsPerPage(ByVal GridLineFont As Font, _
                            ByVal e As Graphics) As Integer

    Return (_PageContentRectangle.Height / _
            ((_CellGutter * 2) + _Rowheight)) - 2

End Function

Settings that Change the Look of the Grid

Image 4

The color and width of the lines around the sections can be set with the HeaderPen, FooterPen and GridPen properties respectively.

Image 5

The font to use for each of the sections can be set with the HeaderFont, FooterFont and PrintFont properties respectively.

Using the Class to Preview and Print a DataGrid

If you have a datagrid on a form that you want to preview and optionally print using this class, you can add a System.Windows.Forms.PrintPreviewDialog to your form and a Print menu and add the following code to it:

VB
Private GridPrinter As DataGridPrinter

Private Sub MenuItem_File_print_Click(ByVal sender As Object, _
                               ByVal e As System.EventArgs) _
                               Handles MenuItem_File_print.Click

    If GridPrinter Is Nothing Then
        GridPrinter = New DataGridPrinter(Me.DataGrid1)
    End If

    With GridPrinter
        .HeaderText = "Some text"
        .HeaderHeightPercent = 10
        .FooterHeightPercent = 5
        .InterSectionSpacingPercent = 2
        '\\ Set any other properties to
        'affect the look of the grid...
    End With

    With Me.PrintPreviewDialog1
        .Document = GridPrinter.PrintDocument
        If .ShowDialog = DialogResult.OK Then
            GridPrinter.Print()
        End If
    End With
End Sub

If you wish to use a newer DataGridView control instead of a DataGrid control, there is a constructor that takes that as a parameter instead. Everything else will work the same way.

History

  • 2006-04-06: Created
  • 2016-01-24: Added constructor/code to use a DataGridView class as the grid data source

License

This article, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)


Written By
Software Developer
Ireland Ireland
C# / SQL Server developer
Microsoft MVP (Azure) 2017
Microsoft MVP (Visual Basic) 2006, 2007

Comments and Discussions

 
AnswerRe: Great Work! Pages Across vs Columns Per Page? Pin
Duncan Edwards Jones9-Dec-08 20:48
professionalDuncan Edwards Jones9-Dec-08 20:48 
GeneralRe: Great Work! Pages Across vs Columns Per Page? Pin
David Gindler10-Dec-08 10:51
David Gindler10-Dec-08 10:51 
GeneralEmpty page Pin
Penko Mitev21-Sep-08 10:07
Penko Mitev21-Sep-08 10:07 
GeneralRe: Empty page Pin
Duncan Edwards Jones21-Sep-08 10:30
professionalDuncan Edwards Jones21-Sep-08 10:30 
GeneralRe: Empty page Pin
Penko Mitev21-Sep-08 23:20
Penko Mitev21-Sep-08 23:20 
GeneralRe: Empty page Pin
Duncan Edwards Jones22-Sep-08 0:49
professionalDuncan Edwards Jones22-Sep-08 0:49 
GeneralRe: Empty page Pin
Penko Mitev22-Sep-08 3:05
Penko Mitev22-Sep-08 3:05 
GeneralRe: Empty page Pin
Penko Mitev22-Sep-08 6:47
Penko Mitev22-Sep-08 6:47 
I considered another trick - to create a copy of the datagridview, based on the original one.

Dim TodayTasksTable As New DataTable
     '-- add rows to data table
     TodayTasksTable.Columns.Add()
      TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     ' TodayTasksTable.Columns.Add()
     '  TodayTasksTable.Columns.Add()

     For i As Integer = 0 To TodayTasksGrid.Rows.Count - 1
         Dim id As Integer = TodayTasksGrid.Rows.Item(i).Cells.Item(0).Value
         Dim title As String = TodayTasksGrid.Rows.Item(i).Cells.Item(1).Value

         TodayTasksTable.Rows.Add(id, title)


     Next


     ' MsgBox(TodayTasksTable.Rows.Count)



     Dim TodayTasksGridView As New DataGridView
     TodayTasksGridView.DataSource = TodayTasksTable


     Dim GridPrinter As New DataGridPrinter.DataGridPrinter(TodayTasksGridView)

     Dim headerColor As Color = Color.AliceBlue
     Dim footerColor As Color = Color.AliceBlue
     Dim gridColor As Color = Color.AliceBlue
     Dim oneBrush As Brush = Brushes.White




     With GridPrinter
         .HeaderText = "Днешни задачи"
         .HeaderHeightPercent = 5
         .FooterHeightPercent = 5
         .InterSectionSpacingPercent = 5
         .HeaderPen = New Pen(CType(headerColor, System.Drawing.Color))
         .FooterPen = New Pen(CType(footerColor, System.Drawing.Color))
         .GridPen = New Pen(CType(gridColor, System.Drawing.Color))
         .HeaderBrush = CType(oneBrush, Brush)
         .EvenRowBrush = CType(oneBrush, Brush)
         .OddRowBrush = CType(oneBrush, Brush)
         .FooterBrush = CType(oneBrush, Brush)
         .ColumnHeaderBrush = CType(oneBrush, Brush)
         .PagesAcross = 1
     End With


     With Me.PrintPreviewDialog1
         .Document = GridPrinter.PrintDocument

         If .ShowDialog = DialogResult.OK Then
             GridPrinter.Print()
         End If
     End With
 End Sub


Unfortunately, without having idea why, it is getting an error in DataGridPrinter.vb on line 408.

The error is well-known -> Index was outside of array bounds(I think it was formed this way).

Here is the code from there.

Dim ColumnCount As Integer = GridColumnCount()
         MsgBox(ColumnCount)

         For nColumn = 0 To ColumnCount - 1

             Dim rcLastCell As Rectangle
             If _DataSourceKind = DataSourceKind.DataGrid Then
                 rcLastCell = _DataGrid.GetCellBounds(0, nColumn)
             Else
               ' Here is the error
                 rcLastCell = New Rectangle(0, 0, _DataGridView.Columns(nColumn).Width, 0)
             End If

             If rcLastCell.Width > 0 Then
                 TotalWidth += rcLastCell.Width
             End If
         Next



As you can see I put MsgBox on the ColumnCount to see the result and it is ok -> 2 columns(id + title).

As I do not know a lot of your code, I am writting here, because maybe others had experienced this problem.

Regards, Penko
Bulgaria
GeneralRe: Empty page Pin
Duncan Edwards Jones30-Sep-08 0:35
professionalDuncan Edwards Jones30-Sep-08 0:35 
GeneralRe: Empty page Pin
Penko Mitev30-Sep-08 0:36
Penko Mitev30-Sep-08 0:36 
GeneralThanx Pin
jalpam15-Sep-08 20:16
jalpam15-Sep-08 20:16 
GeneralRe: Thanx Pin
Duncan Edwards Jones15-Sep-08 20:52
professionalDuncan Edwards Jones15-Sep-08 20:52 
GeneralHi Pin
T. Ravindran31-Aug-08 21:37
T. Ravindran31-Aug-08 21:37 
GeneralRe: Hi Pin
Duncan Edwards Jones2-Sep-08 10:09
professionalDuncan Edwards Jones2-Sep-08 10:09 
QuestionChoose which columns to print? Pin
Tim Hall25-Mar-08 7:51
Tim Hall25-Mar-08 7:51 
AnswerRe: Choose which columns to print? Pin
Duncan Edwards Jones25-Mar-08 18:34
professionalDuncan Edwards Jones25-Mar-08 18:34 
GeneralRe: Choose which columns to print? Pin
Tim Hall27-Mar-08 8:19
Tim Hall27-Mar-08 8:19 
GeneralRe: Choose which columns to print? Pin
Duncan Edwards Jones27-Mar-08 16:17
professionalDuncan Edwards Jones27-Mar-08 16:17 
QuestionProblem with receiving data from datagridview Pin
yazadzhiev29-Feb-08 2:50
yazadzhiev29-Feb-08 2:50 
GeneralRe: Problem with receiving data from datagridview Pin
Duncan Edwards Jones29-Feb-08 9:57
professionalDuncan Edwards Jones29-Feb-08 9:57 
GeneralError with DataSet Pin
it-bergmann12-Dec-07 1:32
it-bergmann12-Dec-07 1:32 
GeneralRe: Error with DataSet Pin
it-bergmann12-Dec-07 4:06
it-bergmann12-Dec-07 4:06 
QuestionColumn Head and Margins Pin
craver8411-Nov-07 7:56
craver8411-Nov-07 7:56 
GeneralPrint Option Dialog Pin
luckydyno10-Nov-07 1:16
luckydyno10-Nov-07 1:16 
GeneralRe: Print Option Dialog Pin
Duncan Edwards Jones11-Nov-07 0:26
professionalDuncan Edwards Jones11-Nov-07 0:26 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Praise Praise    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.