Click here to Skip to main content
14,269,245 members

Pan and Zoom Very Large Images

Rate this:
4.85 (141 votes)
Please Sign up or sign in to vote.
4.85 (141 votes)
31 Oct 2009Ms-PL
Smoothly panning and zooming very large images can be a challenge. Here’s a control, with source code, that demonstrates one way of overcoming this challenge, as well as a few "Extra" image processing features.

Note: This was written against .NET 2.0, then manually converted to .NET 1.1.

Sample image

Introduction

I recently wrote an article showing a simple method for panning an image. The code worked very well for small to moderate sized images. However, when using very large images, the performance degraded significantly.

That article used a picture box within a panel, and used the auto scroll functionality of the panel to perform scrolling. I received quite a bit of feedback indicating the need for a version that could handle very large images and still pan very smoothly. I also received requests for ideas on how to zoom the image in and out. So, I got to work.

What I came up with is a control that could smoothly pan super-sized images, and also provided zoom functionality. My tests were with a 49MB GIF (7000 x 7000). The performance was very smooth. Of course, the control works equally as well with small images. The control is demonstrated in the included sample project.

This custom control does not use a picture box, nor does it inherit from one. Neither is there a panel or any "auto-scrolling". This is very different and very much a better way of panning an image (in my opinion). An added benefit to this example is the ability to zoom the image without resizing a picture box (which can get quite large in memory).

How It Works

  1. Only paints the part of the image currently visible.
  2. Double-buffering provides flicker free panning.
  3. GDI+ automatically scales the image for us.

Public Properties

  • Public Property PanButton() As System.Windows.Forms.MouseButtons
  • Public Property ZoomOnMouseWheel() As Boolean
  • Public Property ZoomFactor() As Double
  • Public Property Origin() As System.Drawing.Point

Public Shadows

  • Public Shadows Property Image() As System.Drawing.Image
  • Public Shadows Property initialimage() As System.Drawing.Image

Public Methods

  • Public Sub ShowActualSize()
  • Public Sub ResetImage()

Using the control is as simple as using a standard PictureBox. First, drop the control on a form, then when you need to show an image, you can do it this way:

Dim bmp As New Bitmap("Image.jpg")
Me.ImageViewer1.Image = bmp

Don't forget to change the filename!

It is important to note: If you are working with very large images, you should not pre-load them in the designer. This seriously bloats the project, and can result in "Out of Memory" issues. Instead, load your images during run-time.

Default Behavior

  • Panning the image: Click and hold the left mouse button while the cursor is over the image. Then, simply move your mouse around, with the button still depressed.
  • Zooming: Make sure the control has focus (click the image). Then, use your mouse wheel to zoom in and out.

Customized Usage

You can tell the control what button to use for panning, with the "PanButton" property. You can turn off the default zooming by setting the ZoomOnMouseWheel property to False.

You can manually set the zoom factor so you could implement your own zoom functionality (i.e., using a slider, or buttons).

You can move the image around programmatically by setting the origin. The origin property gets or sets the coordinates of the top left corner of the viewable window in relation to the original image. For example, if you wanted to see the bottom right corner of an image with a size of 5000 x 5000, and your viewable control size was 500 pixels x 500 pixels, you could set the origin to 4500, 4500. This assumes, of course, that you have a zoom factor of 1 (not zoomed in or out).

You could catch the paint event of the control and overlay your own graphics. Just be careful to take the zoom factor into consideration if you need to draw at precise coordinates in relation to the original image.

Scrollbars

Due to popular demand, scrollbars have now been implemented.

Double Buffering

Double buffering is accomplished by setting the control styles in the constructor as such:

Public Sub New()
     MyBase.New()
     'This call is required by the Windows Form Designer.
     InitializeComponent()
     'Add any initialization after the InitializeComponent() call
     Me.SetStyle(ControlStyles.AllPaintingInWmPaint, True)
     Me.SetStyle(ControlStyles.DoubleBuffer, True)
End Sub

Just In Time Painting?

Well, sort of. While we do have a copy of the image in memory, we only paint the area currently viewable.

Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
     e.Graphics.Clear(Me.BackColor)
     DrawImage(e.Graphics)
     MyBase.OnPaint(e)
End Sub

Protected Overrides Sub OnSizeChanged(ByVal e As EventArgs)
     DestRect = New System.Drawing.Rectangle(0, 0, _
                    ClientSize.Width, ClientSize.Height)
     MyBase.OnSizeChanged(e)
End Sub

Private Sub DrawImage(ByRef g As Graphics)
     If m_OriginalImage Is Nothing Then Exit Sub
     SrcRect = New System.Drawing.Rectangle(m_Origin.X, m_Origin.Y, _
                          ClientSize.Width / m_ZoomFactor, _
                          ClientSize.Height / m_ZoomFactor)
     g.DrawImage(m_OriginalImage, DestRect, SrcRect, GraphicsUnit.Pixel)
End Sub

Note that we are taking the current zoom factor into consideration when drawing. By using the DrawImage method of the Graphics object, GDI will scale the image from the source area to fit the destination area.

Panning the Image

The code for panning the image and keeping the zoom factor in mind, is as follows:

Private Sub ImageViewer_MouseMove(ByVal sender As Object, _
        ByVal e As System.Windows.Forms.MouseEventArgs) _
        Handles MyBase.MouseMove

     'Make sure we are panning on the correct mouse button
     If e.Button = m_MouseButtons Then
          Dim DeltaX As Integer = m_PanStartPoint.X - e.X
          Dim DeltaY As Integer = m_PanStartPoint.Y - e.Y

          'Set the origin of the new image
          m_Origin.X = m_Origin.X + (DeltaX / m_ZoomFactor)
          m_Origin.Y = m_Origin.Y + (DeltaY / m_ZoomFactor)

          'Make sure we don't go out of bounds
          If m_Origin.X < 0 Then m_Origin.X = 0
          If m_Origin.Y < 0 Then m_Origin.Y = 0

          If m_Origin.X > m_OriginalImage.Width - _
                         (ClientSize.Width / m_ZoomFactor) Then
               m_Origin.X = _m_OriginalImage.Width - _
                            (ClientSize.Width / m_ZoomFactor)
          End If
          If m_Origin.Y > m_OriginalImage.Height - _
                           (ClientSize.Height / m_ZoomFactor) Then
               m_Origin.Y = m_OriginalImage.Height - _
                           (ClientSize.Height / m_ZoomFactor)
          End If

          If m_Origin.X < 0 Then m_Origin.X = 0
          If m_Origin.Y < 0 Then m_Origin.Y = 0

          'reset the startpoints
          m_PanStartPoint.X = e.X
          m_PanStartPoint.Y = e.Y

          'Force a paint
          Me.Invalidate()
     End If
End Sub

Conclusion

Many of the concepts used within this example project are worthy of their own discrete articles. Therefore, I didn't go into any great detail about what double buffering is, nor did I dive into the intricacies of GDI+ in .NET. However, I hope that I have adequately covered the basics of how this control works, as well as how you can use it.

Please Note...

This is by no means meant to be a complete solution, nor is this code "production-ready". Then too, there are usually many ways to solve a problem; this is one. Hopefully, though, this sample has proven beneficial in some way. Perhaps, this article has given you a great idea about how to do this a better way, or an idea for expanding what is presented here. Great! That's why I wrote it. Please feel free to leave some feedback. Let me know how it went for you. If you do have an idea on how to improve this example or this article, please let me know that too.

P.S.: Don't forget to vote! If you don't have an account, make one!

Revisions and Bug Fixes ...

  • 02/04/2007
    • Added scrollbar functionality
    • Fixed null image bug
    • Fixed memory leak
    • Implemented several performance improving suggestions
    • Added ability to invert colors
    • Added ability to stretch image or set to actual pixels
    • Removed the hard coded image file and added dialogue box to test harness
  • 02/06/2007
    • Added a .NET 1.1 version
  • 30/10/2009
    • Deleted the .NET 1.1 zip file

TO DO

  1. Change Points to PointF and Rectangles to RectangleF to allow finer panning and scrolling when zoomed in very tight
  2. Update the article to dissect the app and explain why it works the way it does
  3. Update the code presented in the article

Thanks for your patience!

License

This article, along with any associated source code and files, is licensed under The Microsoft Public License (Ms-PL)

Share

About the Author

Anthony Queen
Software Developer (Senior)
United States United States
I started my career in software development back in 2000. Prior to that, I made my living as a detail drafter. My true start in programming, though, goes back much further. I first started learning to program when I was about 10 years old. It was back in ‘82 that I wrote my first application. It was a simple calculator program written on a TRS-80 that my uncle had. Since then, I’ve programmed in Basic, QuickBasic, Pascal, C++, VB 6, VB.NET, Java, HTML, and C #. I have a very diverse background. I’ve worked and written software for several types of companies, including manufacturing, engineering, and finance. I’ve had the opportunity to design and maintain a few enterprise level databases, I’ve written applications to run on windows CE, in a wireless manufacturing environment. I’ve also had opportunities to teach OOP methodologies, and design patterns. I thoroughly enjoy what I do, and my only regret is that I didn’t start sooner.

Comments and Discussions

 
GeneralRe: Thank you! Pin
Anthony Queen29-Oct-06 3:41
memberAnthony Queen29-Oct-06 3:41 
GeneralRe: Thank you! Pin
findusdwarf3-Nov-06 6:37
memberfindusdwarf3-Nov-06 6:37 
QuestionAdditional function? Pin
khoki25-Oct-06 22:07
memberkhoki25-Oct-06 22:07 
AnswerRe: Additional function? Pin
Anthony Queen26-Oct-06 4:26
memberAnthony Queen26-Oct-06 4:26 
GeneralRe: Additional function? Pin
MatejCerk9-Nov-06 8:36
memberMatejCerk9-Nov-06 8:36 
GeneralRe: Additional function? Pin
Anthony Queen14-Dec-06 3:50
memberAnthony Queen14-Dec-06 3:50 
GeneralRe: Additional function? Pin
Tom Dwyer13-Dec-06 17:57
memberTom Dwyer13-Dec-06 17:57 
AnswerRe: Additional function? Pin
Anthony Queen14-Dec-06 3:49
memberAnthony Queen14-Dec-06 3:49 
Ok, here's what I did. Please note, this is not production ready code, but is merely an attempt to demonstrate one possible way of overlaying map points.

clsMapPoint to the Imageviewer project. It looks like this:
'---------------------------------------------------------------
Public Class clsMapPoint
Private m_Location As System.Drawing.Point = New System.Drawing.Point(0, 0)
Private m_Name As String = ""
Private m_Description As String = ""
Private m_brush As System.Drawing.Brush = Brushes.Blue
Private m_Bitmap As New System.Drawing.Bitmap(20, 20)
Private m_currentRectangle As Rectangle
Private m_Width As Integer = 10
Private m_Height As Integer = 10
Private m_Highlight As Boolean

Public Property Location() As System.Drawing.Point
Get
Return m_Location
End Get
Set(ByVal value As System.Drawing.Point)
m_Location = value

End Set
End Property

Public Property Name() As String
Get
Return m_Name
End Get
Set(ByVal value As String)
m_Name = value
End Set
End Property

Public Property Description() As String
Get
Return m_Description
End Get
Set(ByVal value As String)
m_Description = value
End Set
End Property

Public Property BrushColor() As System.Drawing.Brush
Get
Return m_brush
End Get
Set(ByVal value As System.Drawing.Brush)
m_brush = value
End Set
End Property

Public Property Width() As Integer
Get
Return m_Width
End Get
Set(ByVal value As Integer)
m_Width = value
End Set
End Property

Public Property Height() As Integer
Get
Return m_Height
End Get
Set(ByVal value As Integer)
m_Height = value
End Set
End Property

Friend Function GetImage() As System.Drawing.Bitmap
Dim g As Graphics
g = Graphics.FromImage(m_Bitmap)
g.Clear(Color.Transparent)
Dim CurrentBrush As System.Drawing.Brush
If Highlight Then
CurrentBrush = Brushes.Red
Else
CurrentBrush = BrushColor
End If
g.FillEllipse(CurrentBrush, 0, 0, m_Width, m_Width)
Return m_Bitmap
End Function

Public Property Highlight()
Get
Return m_Highlight
End Get
Set(ByVal value)
m_Highlight = value
End Set
End Property
End Class


'---------------------------------------------------------------
'---------------------------------------------------------------

Second, I modified the MapViewerControl:

'---------------------------------------------------------------
'---------------------------------------------------------------

Public Class MapViewer
'Member Variables
Private m_MouseButtons As System.Windows.Forms.MouseButtons = Windows.Forms.MouseButtons.Left
Private m_OriginalImage As System.Drawing.Bitmap
Private m_PanStartPoint As System.Drawing.Point
Private m_Origin As New System.Drawing.Point(0, 0)
Private m_CenterPoint As New System.Drawing.Point(0, 0)
Private g As Graphics
Private SrcRect As System.Drawing.Rectangle
Private DestRect As System.Drawing.Rectangle
Private m_ZoomOnMouseWheel As Boolean = True
Private m_ZoomFactor As Double = 1.0
Private m_MapPoints As New Collections.Generic.SortedList(Of String, clsMapPoint)
Private M_MapPointPen As New System.Drawing.Pen(Color.Aquamarine)

Public Event MapPointClicked(ByVal MP As clsMapPoint)

Public Sub New()
' This call is required by the Windows Form Designer.
InitializeComponent()
' Add any initialization after the InitializeComponent() call.
Me.SetStyle(ControlStyles.OptimizedDoubleBuffer, True)
Me.SetStyle(ControlStyles.AllPaintingInWmPaint, True)
End Sub

#Region "Public/Private Shadows"
Public Shadows Property Image() As System.Drawing.Image
Get
Return m_OriginalImage
End Get
Set(ByVal Value As System.Drawing.Image)
If Value Is Nothing Then
m_OriginalImage = Nothing
Exit Property
End If
Dim r As New Rectangle(0, 0, Value.Width, Value.Height)
m_OriginalImage = Value
'Clone the image so we can set the pixelformat.
' This improves performance quite a bit
m_OriginalImage = m_OriginalImage.Clone(r, Imaging.PixelFormat.DontCare)
'Force a paint
Me.Invalidate()
End Set
End Property

Public Shadows Property initialimage() As System.Drawing.Image
Get
Return m_OriginalImage
End Get
Set(ByVal value As System.Drawing.Image)
Me.Image = value
End Set
End Property

Public Shadows Property BackgroundImage() As System.Drawing.Image
Get
Return Nothing
End Get
Set(ByVal Value As System.Drawing.Image)

End Set
End Property

#End Region

#Region "Protected Overrides"

Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
e.Graphics.Clear(Me.BackColor)
DrawImage(e.Graphics)
MyBase.OnPaint(e)
End Sub

Protected Overrides Sub OnSizeChanged(ByVal e As EventArgs)
DestRect = New System.Drawing.Rectangle(0, 0, ClientSize.Width, ClientSize.Height)
MyBase.OnSizeChanged(e)
End Sub

#End Region

#Region "Public Properties"
Public Property MapPoints() As Collections.Generic.SortedList(Of String, clsMapPoint)
Get
Return m_MapPoints
End Get
Set(ByVal value As Collections.Generic.SortedList(Of String, clsMapPoint))
m_MapPoints = value
End Set
End Property

Public Property PanButton() As System.Windows.Forms.MouseButtons
Get
Return m_MouseButtons
End Get
Set(ByVal value As System.Windows.Forms.MouseButtons)
m_MouseButtons = value
End Set
End Property

Public Property ZoomOnMouseWheel() As Boolean
Get
Return m_ZoomOnMouseWheel
End Get
Set(ByVal value As Boolean)
m_ZoomOnMouseWheel = value
End Set
End Property

Public Property ZoomFactor() As Double
Get
Return m_ZoomFactor
End Get
Set(ByVal value As Double)
m_ZoomFactor = value
If m_ZoomFactor > 16 Then m_ZoomFactor = 16
If m_ZoomFactor < 0.05 Then m_ZoomFactor = 0.05

Me.Invalidate()
End Set
End Property

Public Property Origin() As System.Drawing.Point
Get
Return m_Origin
End Get
Set(ByVal value As System.Drawing.Point)
m_Origin = value
Me.Invalidate()
End Set
End Property
#End Region

#Region "Public Methods"

Public Sub ShowActualSize()
m_ZoomFactor = 1
Me.Invalidate()
End Sub

Public Sub ResetImage()
m_Origin.X = 0
m_Origin.Y = 0
m_ZoomFactor = 1.0
Me.Invalidate()
End Sub

Public Sub ForceRefresh()
Me.Invalidate()
End Sub

#End Region

Private Sub DrawImage(ByRef g As Graphics)
If m_OriginalImage Is Nothing Then Exit Sub
SrcRect = New System.Drawing.Rectangle(m_Origin.X, m_Origin.Y, ClientSize.Width / m_ZoomFactor, ClientSize.Height / m_ZoomFactor)
g.InterpolationMode = Drawing2D.InterpolationMode.NearestNeighbor
g.SmoothingMode = Drawing2D.SmoothingMode.None
g.PixelOffsetMode = Drawing2D.PixelOffsetMode.None
g.DrawImage(m_OriginalImage, DestRect, SrcRect, GraphicsUnit.Pixel)
Drawpoints(g)
End Sub

Private Sub Drawpoints(ByRef g As Graphics)
Dim TranslatedPoint As System.Drawing.Point
For Each mp As clsMapPoint In MapPoints.Values
Dim mpImage As Bitmap = mp.GetImage
If SrcRect.Contains(mp.Location.X, mp.Location.Y) Then
TranslatedPoint = New System.Drawing.Point((mp.Location.X - m_Origin.X) * m_ZoomFactor, (mp.Location.Y - m_Origin.Y) * m_ZoomFactor)
g.DrawImageUnscaled(mpImage, TranslatedPoint)
End If
Next
End Sub

Private Function TranslatePoint(ByVal Loc As System.Drawing.Point) As System.Drawing.Point
Dim p As System.Drawing.Point
p.X = m_Origin.X + (Loc.X / m_ZoomFactor)
p.Y = m_Origin.Y + (Loc.Y / m_ZoomFactor)
Return p

End Function

Private Function translateLength(ByVal length As Integer) As Integer
Return length / m_ZoomFactor
End Function

Private Sub MapViewer_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Me.MouseClick
If e.Button = Windows.Forms.MouseButtons.Left Then
Dim mpRect As Rectangle
Dim TranslatedPoint As System.Drawing.Point
TranslatedPoint = TranslatePoint(e.Location)
For Each mp As clsMapPoint In m_MapPoints.Values
mpRect = New Rectangle(mp.Location.X, mp.Location.Y, _
translateLength(mp.Width), translateLength(mp.Height))

If mpRect.Contains(TranslatedPoint) Then
For Each mp2 As clsMapPoint In m_MapPoints.Values
mp2.Highlight = False
Next
mp.Highlight = True
Me.Invalidate()
RaiseEvent MapPointClicked(mp)
Exit For
End If
Next
End If
End Sub

Private Sub ImageViewer_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles MyBase.MouseDown
m_PanStartPoint = New Point(e.X, e.Y)
Me.Focus()
End Sub

Private Sub ImageViewer_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles MyBase.MouseMove
If e.Button = m_MouseButtons Then
Dim DeltaX As Integer = m_PanStartPoint.X - e.X
Dim DeltaY As Integer = m_PanStartPoint.Y - e.Y

'Set the origin of the new image
m_Origin.X = m_Origin.X + (DeltaX / m_ZoomFactor)
m_Origin.Y = m_Origin.Y + (DeltaY / m_ZoomFactor)

'reset the startpoints
m_PanStartPoint.X = e.X
m_PanStartPoint.Y = e.Y

'Force a paint
Me.Invalidate()
End If
End Sub

Private Sub ImageViewer_MouseWheel(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles MyBase.MouseWheel
If Not ZoomOnMouseWheel Then Exit Sub
' Get center point
m_CenterPoint.X = m_Origin.X + SrcRect.Width / 2
m_CenterPoint.Y = m_Origin.Y + SrcRect.Height / 2

'set new zoomfactor
If e.Delta > 0 Then
ZoomFactor = Math.Round(ZoomFactor * 1.1, 2)
ElseIf e.Delta < 0 Then
ZoomFactor = Math.Round(ZoomFactor * 0.9, 2)
End If

'Reset the origin to maintain center point
m_Origin.X = m_CenterPoint.X - ClientSize.Width / m_ZoomFactor / 2
m_Origin.Y = m_CenterPoint.Y - ClientSize.Height / m_ZoomFactor / 2
End Sub
End Class



'---------------------------------------------------------------
'---------------------------------------------------------------
I created a test harness to demonstrate how to use it.
Basically, I have the imageviewer, then 3 text boxes, and a button on the form.

They are named:
MapViewer1
txtName
txtX
txtY
Button1

Form1 contains the following code:
'---------------------------------------------------------------
'---------------------------------------------------------------

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
Me.MapViewer1.Image = New Bitmap("c:\test.jpg")

Dim mp As MapImageViewer.clsMapPoint
Dim x As Integer
For x = 0 To 50
mp = New MapImageViewer.clsMapPoint
mp.Location = New Drawing.Point(Rnd() * 1000, Rnd() * 1000)
mp.Name = x
mp.Description = x
mp.BrushColor = Brushes.MediumBlue
Me.MapViewer1.MapPoints.Add(mp.Name, mp)
Next
End Sub

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
Dim mp As MapImageViewer.clsMapPoint
If MapViewer1.MapPoints.ContainsKey(txtName.Text) Then
mp = MapViewer1.MapPoints(txtName.Text)
mp.Location = New System.Drawing.Point(txtX.Text, txtY.Text)
Else
mp = New MapImageViewer.clsMapPoint
mp.Name = txtName.Text
mp.Location = New System.Drawing.Point(txtX.Text, txtY.Text)
MapViewer1.MapPoints.Add(mp.Name, mp)
End If
MapViewer1.Refresh()
End Sub

Private Sub MapViewer1_MapPointClicked(ByVal MP As MapImageViewer.clsMapPoint) Handles MapViewer1.MapPointClicked
txtName.Text = MP.Name
txtX.Text = MP.Location.X
txtY.Text = MP.Location.Y
End Sub


'---------------------------------------------------------------
'---------------------------------------------------------------
I hope that helps get you started.
'---------------------------------------------------------------
'---------------------------------------------------------------




It's only when you look at an ant through a magnifying glass on a sunny day that you realise how often they burst into flames.



GeneralRe: Additional function? Pin
Anthony Queen14-Dec-06 3:54
memberAnthony Queen14-Dec-06 3:54 
GeneralJust an idea Pin
pojkoster16-Oct-06 22:03
memberpojkoster16-Oct-06 22:03 
GeneralRe: Just an idea Pin
Anthony Queen17-Oct-06 10:48
memberAnthony Queen17-Oct-06 10:48 
QuestionHow to open Very Large TIF image Pin
Abhay Menon16-Oct-06 4:38
memberAbhay Menon16-Oct-06 4:38 
AnswerRe: How to open Very Large TIF image Pin
Steve Erbach16-Oct-06 6:51
memberSteve Erbach16-Oct-06 6:51 
AnswerRe: How to open Very Large TIF image Pin
Anthony Queen17-Oct-06 11:03
memberAnthony Queen17-Oct-06 11:03 
GeneralScrollbars Pin
alanp516-Oct-06 3:28
memberalanp516-Oct-06 3:28 
GeneralRe: Scrollbars Pin
Anthony Queen17-Oct-06 10:47
memberAnthony Queen17-Oct-06 10:47 
GeneralRe: Scrollbars Pin
Anthony Queen30-Oct-06 3:09
memberAnthony Queen30-Oct-06 3:09 
GeneralRe: Scrollbars Pin
Anthony Queen7-Nov-06 6:40
memberAnthony Queen7-Nov-06 6:40 
QuestionRe: Scrollbars Pin
alanp526-Dec-06 9:14
memberalanp526-Dec-06 9:14 
AnswerRe: Scrollbars Pin
Anthony Queen29-Jan-07 4:49
memberAnthony Queen29-Jan-07 4:49 
GeneralRe: Scrollbars Pin
Anthony Queen6-Feb-07 6:15
memberAnthony Queen6-Feb-07 6:15 
GeneralCentering Zoom Pin
Tom Dwyer6-Oct-06 6:55
memberTom Dwyer6-Oct-06 6:55 
GeneralRe: Centering Zoom Pin
Anthony Queen6-Oct-06 15:51
memberAnthony Queen6-Oct-06 15:51 
GeneralRe: Centering Zoom Pin
tedwyer112-Oct-06 18:00
membertedwyer112-Oct-06 18:00 
GeneralRe: Centering Zoom Pin
Anthony Queen13-Oct-06 3:03
memberAnthony Queen13-Oct-06 3:03 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Praise Praise    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.

Article
Posted 28 Sep 2006

Stats

616.9K views
14.5K downloads
182 bookmarked