Click here to Skip to main content
14,302,993 members

Reading a text file in ASP.

Rate this:
4.96 (15 votes)
Please Sign up or sign in to vote.
4.96 (15 votes)
18 Mar 2009CPOL
How to read a text file on a server using VBScript in ASP

One of the most important tasks in any programming language is the ability to read and write files. The steps involved in ASP are no different than many other languages:

  1. Specify the location of the file
  2. Determine if the file exists
  3. Get a handle to the file
  4. Read the contents
  5. Close the file and release any resources used

File I/O in ASP can be done using the FileSystemObject component. When opening a text file you simply open it as a text stream, and it is this text stream that you use to access the contents of the file.

The FileSystemObject allows you to perform all file and folder handling operations. It can either return a file which can then be opened as a text stream, or it can return a text stream object directly.

In the following I present two different methods. The first method gets a file object and uses that to open the text stream, and the second method opens the text stream directly from the FileSystemObject.

Method 1:

<% Option Explicit

Const Filename = "/readme.txt"    ' file to read
Const ForReading = 1, ForWriting = 2, ForAppending = 3
Const TristateUseDefault = -2, TristateTrue = -1, TristateFalse = 0

' Create a filesystem object
Dim FSO
set FSO = server.createObject("Scripting.FileSystemObject")

' Map the logical path to the physical system path
Dim Filepath
Filepath = Server.MapPath(Filename)

if FSO.FileExists(Filepath) Then

    ' Get a handle to the file
    Dim file    
    set file = FSO.GetFile(Filepath)

    ' Get some info about the file
    Dim FileSize
    FileSize = file.Size

    Response.Write "<p><b>File: " & Filename & " (size " & FileSize  &_
                   " bytes)</b></p><hr>"
    Response.Write "<pre>"

    ' Open the file
    Dim TextStream
    Set TextStream = file.OpenAsTextStream(ForReading, TristateUseDefault)

    ' Read the file line by line
    Do While Not TextStream.AtEndOfStream
        Dim Line
        Line = TextStream.readline
    
        ' Do something with "Line"
        Line = Line & vbCRLF
    
        Response.write Line 
    Loop


    Response.Write "</pre><hr>"

    Set TextStream = nothing
    
Else

    Response.Write "<h3><i><font color=red> File " & Filename &_
                       " does not exist</font></i></h3>"

End If

Set FSO = nothing
%>

Method 2:

<% Option Explicit

Const Filename = "/readme.txt"    ' file to read
Const ForReading = 1, ForWriting = 2, ForAppending = 3
Const TristateUseDefault = -2, TristateTrue = -1, TristateFalse = 0

' Create a filesystem object
Dim FSO
set FSO = server.createObject("Scripting.FileSystemObject")

' Map the logical path to the physical system path
Dim Filepath
Filepath = Server.MapPath(Filename)

if FSO.FileExists(Filepath) Then

    Set TextStream = FSO.OpenTextFile(Filepath, ForReading, False, TristateUseDefault)

    ' Read file in one hit
    Dim Contents
    Contents = TextStream.ReadAll
    Response.write "<pre>" & Contents & "</pre><hr>"
    TextStream.Close
    Set TextStream = nothing
    
Else

    Response.Write "<h3><i><font color=red> File " & Filename &_
                   " does not exist</font></i></h3>"

End If

Set FSO = nothing
%>

License

This article, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)

Share

About the Author

Chris Maunder
Founder CodeProject
Canada Canada
Chris is the Co-founder, Administrator, Architect, Chief Editor and Shameless Hack who wrote and runs CodeProject. He is also co-founder of Developer Media and ContentLab.IO. He's been programming since the 80's and has been, in various guides, an astrophysicist, bacyard mechanic, mathematician, physicist, breeder of carnivorous plants, hydrologist, geomorphologist, defence intelligence researcher and then, when all that got a bit rough on the nerves, a web developer.

His programming experience includes C/C++, C#, SQL, MFC, ASP.NET, TypeScript and far, far too much FORTRAN. He has worked on PocketPCs, Old mainframes, new Macs, cheap phones, and a CRAY YMP C90 behemoth but finds notebooks take up less desk space.

He is kind to small animals and has a soft spot for cheesecake.

Chris was born and bred in Australia but splits his time between Toronto and Melbourne, depending on the weather. For relaxation he is obsessively into road cycling, physiology, occasionally snowboarding and rock climbing, and wishes he were a storm chaser.

Comments and Discussions

 
QuestionThis cat must be in tip-top shape! Pin
B. Clay Shannon21-Jan-14 12:58
professionalB. Clay Shannon21-Jan-14 12:58 
AnswerRe: This cat must be in tip-top shape! Pin
Chris Maunder21-Jan-14 13:19
adminChris Maunder21-Jan-14 13:19 
GeneralRe: This cat must be in tip-top shape! Pin
B. Clay Shannon21-Jan-14 13:34
professionalB. Clay Shannon21-Jan-14 13:34 
GeneralRe: This cat must be in tip-top shape! Pin
Chris Maunder21-Jan-14 13:35
adminChris Maunder21-Jan-14 13:35 
GeneralRe: This cat must be in tip-top shape! Pin
B. Clay Shannon21-Jan-14 13:36
professionalB. Clay Shannon21-Jan-14 13:36 
GeneralRe: This cat must be in tip-top shape! Pin
Chris Maunder21-Jan-14 14:55
adminChris Maunder21-Jan-14 14:55 
Questionreading text file from java Pin
goofy7827024-Sep-12 8:04
membergoofy7827024-Sep-12 8:04 
GeneralMy vote of 5 Pin
Chimeco17-Oct-11 4:56
memberChimeco17-Oct-11 4:56 
GeneralThanks for the helpful insights... Pin
Destiny77716-May-09 1:41
memberDestiny77716-May-09 1:41 
Questionhow to read 2nd Line Pin
Pushkar Joshi7-Mar-06 19:58
memberPushkar Joshi7-Mar-06 19:58 
Generalgood Pin
Anonymous25-Oct-05 2:31
memberAnonymous25-Oct-05 2:31 
GeneralReading Text in ASP Pin
HatakeKaKaShi11-Jul-05 17:20
memberHatakeKaKaShi11-Jul-05 17:20 
Generalread html file from remote location Pin
deshkar11-Feb-05 19:01
memberdeshkar11-Feb-05 19:01 
GeneralRe: read html file from remote location Pin
zulito14-Feb-05 1:43
memberzulito14-Feb-05 1:43 
Generalpage processing halts when accessing text files with ASP Pin
marsdust18-Oct-04 20:26
sussmarsdust18-Oct-04 20:26 
Generalread from HTM file Pin
Lisahan31-Aug-04 10:10
memberLisahan31-Aug-04 10:10 
GeneralRe: read from HTM file [modified] Pin
Zhelezov23-Apr-07 23:20
memberZhelezov23-Apr-07 23:20 
GeneralReading a text file in ASP Pin
Member 12174575-Jul-04 19:14
memberMember 12174575-Jul-04 19:14 
GeneralRe: Reading a text file in ASP Pin
Anonymous26-Jul-04 0:25
memberAnonymous26-Jul-04 0:25 
GeneralReading Remote Files Pin
Tim Kluger14-Jun-04 6:44
sussTim Kluger14-Jun-04 6:44 
Generalhelps Pin
Member 110924223-May-04 0:43
memberMember 110924223-May-04 0:43 
QuestionHow can i search in a text file Pin
emmatty11-May-04 0:49
memberemmatty11-May-04 0:49 
GeneralBinary Read Pin
TomazZ10-Mar-04 23:21
memberTomazZ10-Mar-04 23:21 
Generalcurly brace being converted to &amp;#123; Pin
Anonymous12-Feb-04 2:59
memberAnonymous12-Feb-04 2:59 
GeneralERROR (file not found) but it exists Pin
weasel12086-Jan-04 14:21
memberweasel12086-Jan-04 14:21 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Praise Praise    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.

Article
Posted 20 Jan 2000

Stats

703.8K views
3.9K downloads
53 bookmarked