Fast Exporting from DataSet to Excel

The code generates error at da.Fill(ds); as the database customer is not there in project. How to cater this?

"yyyy-MM-dd HH:mm:ss.fff"

2016-12-27 11:14

do you have answer for this?
<a href="http://www.codeproject.com/Questions/821400/Export-to-Excel-Two-DataGridView?arn=0">Export to Excel : Two DataGridView</a>[<a href="http://www.codeproject.com/Questions/821400/Export-to-Excel-Two-DataGridView?arn=0" target="_blank" title="New Window">^</a>]

Private Shared Sub ReleaseComObjects(ByVal objList As List(Of Object))
	'GC.Collect()
	'GC.WaitForPendingFinalizers()
	For Each obj In objList
		If obj Is Nothing Then Continue For
		Try
			Select Case True
				Case TypeOf obj Is Microsoft.Office.Interop.Excel.Workbook
					obj.Close()
				Case TypeOf obj Is Microsoft.Office.Interop.Excel.ApplicationClass
					obj.Quit()
			End Select
		Catch
		End Try
		Runtime.InteropServices.Marshal.FinalReleaseComObject(obj)
		'obj = Nothing
	Next
	'GC.Collect()
	'GC.WaitForPendingFinalizers()
End Sub


Public Sub InteropExportDatasetToExcel(ByVal dataSet As DataSet, ByVal outputPath As String, Optional ByVal hideWorkbook As Boolean = False)
	Dim excelApp As Microsoft.Office.Interop.Excel.ApplicationClass = Nothing
	Dim excelWorkbooks As Microsoft.Office.Interop.Excel.Workbooks = Nothing
	Dim excelWorkbook As Microsoft.Office.Interop.Excel.Workbook = Nothing
	Dim excelSheets As Microsoft.Office.Interop.Excel.Sheets = Nothing

	Const colCharset As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
	Dim finalColLetter As String = String.Empty
	Dim colCharsetLen As Integer = colCharset.Length

	Try
		Threading.Thread.CurrentThread.CurrentCulture = Globalization.CultureInfo.CreateSpecificCulture("en-US")
		excelApp = New Microsoft.Office.Interop.Excel.ApplicationClass
		excelApp.DisplayAlerts = False
		excelWorkbooks = excelApp.Workbooks
		excelWorkbook = excelWorkbooks.Add(Type.Missing)
		excelSheets = excelWorkbook.Sheets
		Dim sheetIndex As Integer = 0
		Dim col, row As Integer

		Dim excelSheetTmp As Object  '' As Microsoft.Office.Interop.Excel.Worksheet
		Dim excelSheet As Object     '' As Microsoft.Office.Interop.Excel.Worksheet
		Dim excelRange As Object     '' As Microsoft.Office.Interop.Excel.Range
		Dim excelRangeFont As Object '' As Microsoft.Office.Interop.Excel.Range
		Dim excelFont As Object      '' As Microsoft.Office.Interop.Excel.Font

		For Each dt As DataTable In dataSet.Tables
			sheetIndex += 1
			Dim rawData(dt.Rows.Count, dt.Columns.Count - 1) As Object
			For col = 0 To dt.Columns.Count - 1
				rawData(0, col) = dt.Columns(col).ColumnName
			Next
			For col = 0 To dt.Columns.Count - 1
				For row = 0 To dt.Rows.Count - 1
					rawData(row + 1, col) = dt.Rows(row).ItemArray(col)
				Next
			Next
			If dt.Columns.Count > colCharsetLen Then finalColLetter = colCharset.Substring((dt.Columns.Count - 1) \ colCharsetLen - 1, 1)
			finalColLetter += colCharset.Substring((dt.Columns.Count - 1) Mod colCharsetLen, 1)
			excelSheetTmp = excelSheets(sheetIndex)
			excelSheet = excelSheets.Add(excelSheetTmp, Type.Missing, 1, Microsoft.Office.Interop.Excel.XlSheetType.xlWorksheet)
			excelSheet.Name = dt.TableName
			excelRange = excelSheet.Range(String.Format("A1:{0}{1}", finalColLetter, dt.Rows.Count + 1), Type.Missing)
			excelRange.Value2 = rawData
			excelRangeFont = excelSheet.Rows(1, Type.Missing)
			excelFont = excelRangeFont.Font
			excelFont.Bold = True
			ReleaseComObjects(New List(Of Object) From {excelFont, excelRangeFont, excelRange, excelSheet, excelSheetTmp})
		Next
		excelWorkbook.SaveAs(outputPath, Microsoft.Office.Interop.Excel.XlFileFormat.xlWorkbookNormal, Type.Missing, Type.Missing, Type.Missing, Type.Missing, _
							 Microsoft.Office.Interop.Excel.XlSaveAsAccessMode.xlExclusive, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing)
	Catch ex As Exception
		ex.Data(0) = outputPath
		Throw
	Finally
		If Not hideWorkbook Then
			excelApp.Visible = True
			excelWorkbook.Activate()
			AddHandler excelApp.WorkbookBeforeClose, Sub()
														 Try
															 excelApp.Visible = False
															 ReleaseComObjects(New List(Of Object) From {excelSheets, excelWorkbooks, excelApp})
														 Catch ex As Exception
															 Throw
														 End Try
													 End Sub
		Else
			ReleaseComObjects(New List(Of Object) From {excelSheets, excelWorkbook, excelWorkbooks, excelApp})
		End If
	End Try
End Sub