Outlook VBA - automatically create a folder based on date

You can use the Folders.Add method [^] method to create the folders either based on Now or on Outlook.MailItem.CreationDate (the latter might be useful if you want to retrospectively move stuff)

If I've misunderstood, and it's a folder on your C: drive you want to create then you can use the MkDir statement[^]

Edit: Other functions you might find useful
FolderExists method [^]
Folders object (Outlook) [^]

Edit - some actual code

Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
    Dim dateFormat As String    'Comment 1

    'dateFormat = Format(Now, "yyyy-mm-dd H-mm")
    dateFormat = Format(itm.CreationTime, "yyyy-mm-dd") 'Comment 2

    Dim objAtt As Outlook.Attachment
    Dim saveFolder As String
    Dim getsender As String

    saveFolder = "C:\Users\UserName\Desktop\Attachments\" & dateFormat & "\" 'Comment 3
    
    CreateFolderIfNotExists saveFolder  'Comment 4
    
    For Each objAtt In itm.Attachments
        If InStr(objAtt.FileName, ".pdf") > 0 Then
            objAtt.SaveAsFile saveFolder & objAtt.DisplayName
        End If
        'Set objAtt = Nothing   'Comment 5
     Next
End Sub


Public Sub CreateFolderIfNotExists(folderName As String)
    'Parameter folderName must be a fully qualifed path including drive
    'All errors are assumed to be handled by the calling code
    
    Dim fs As Object 'Using late binding to avoid having to include a reference to Microsoft Scripting Runtime
    Set fs = CreateObject("Scripting.FileSystemObject")
    
    If Not fs.folderexists(folderName) Then
        fs.createfolder (folderName)    'Comment 6
    End If
End Sub

Points to note - see the comment points in the code:
Comment 1:
I've explicitly given dateFormat a type. I believe that to be best practice

Comment 2:
I've used the date that the email was created - this will allow you to retrospectively save attachments for older emails in the correct folders. Note the difference in the format I have used compared to yours.

Comment 3:
I've added the appropriate date to the saveFolder name

Comment 4:
I've put the code to check for a folder and create it into a separate subroutine

Comment 5:
There is no need to set objAtt to Nothing after saving the PDF. It will be reassigned by the loop immediately afterwards. You exit the sub after the loop is complete so it will go out of scope and eventually be cleared out of memory anyway.

Comment 6:
I suggested using MkDir in my original answer, but I already have a FileSystemObject so I've used CreateFolder instead here.

Another Edit!

Here is a snippet of code that will get all items in your inbox and dump the sender details to the Immediate window

Dim objMails As Outlook.Items
Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
Dim objMail As Outlook.MailItem
For Each objMail In objMails
    Debug.Print objMail.Sender, objMail.SenderEmailAddress
Next

Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
    Dim dateFormat As String
    
    'If any errors occur jump to the label "errhandler"
    On Error GoTo errhandler

    dateFormat = Format(itm.CreationTime, "yyyy-mm-dd")

    Dim objAtt As Outlook.Attachment
    Dim saveFolder As String
    Dim getsender As String

    saveFolder = "C:\Users\UserName\Desktop\Attachments\" & dateFormat & "\"
    
    CreateFolderIfNotExists saveFolder
    
    For Each objAtt In itm.Attachments
        If InStr(objAtt.Filename, ".pdf") > 0 Then
            objAtt.SaveAsFile saveFolder & objAtt.DisplayName
        End If
     Next
     
cleanexit:
    
    'We are going to ignore any errors as we exit. This must be after the clean exit label
    On Error Resume Next
    
    'If you need to tidy up any objects this is where to put that code e.g.
    Set objAtt = Nothing
    
    'This next line is essential
    Exit Sub
     
errhandler:
     
    'Always put something in here e.g.
    MsgBox "An error has occurred: " & Err.Description
    
    'I usually go to a clean exit label to close down any connections etc
    'Alternatively just allow the routine to exit here
    GoTo cleanexit
     
End Sub