Drag and Drop items between ListView using treeview ?

Private sourceListView As ListView

Private Sub ListView_MouseDown(sender As System.Object, e As System.Windows.Forms.MouseEventArgs) _
    Handles ListView1.MouseDown, ListView5.MouseDown, ListView4.MouseDown, ListView3.MouseDown, ListView2.MouseDown
    ' Store source ListView for Drag & Drop
    sourceListView = CType(sender, ListView)
End Sub

Private Sub ListView_DragOver(sender As System.Object, e As System.Windows.Forms.DragEventArgs) _
    Handles ListView1.DragOver, ListView5.DragOver, ListView4.DragOver, ListView3.DragOver, ListView2.DragOver
    e.Effect = DragDropEffects.Move
End Sub

Private Sub ListView_ItemDrag(sender As System.Object, e As System.Windows.Forms.ItemDragEventArgs) _
    Handles ListView1.ItemDrag, ListView5.ItemDrag, ListView4.ItemDrag, ListView3.ItemDrag, ListView2.ItemDrag
    ' Set selected item Text to Drag & Drop operation
    sourceListView.DoDragDrop(sourceListView.SelectedItems(0).Text, DragDropEffects.Move)
End Sub

Private Sub TreeView_DragEnter(sender As System.Object, e As System.Windows.Forms.DragEventArgs) _
    Handles TreeView1.DragEnter
    e.Effect = DragDropEffects.Move
End Sub

Private Sub TreeView_DragDrop(sender As System.Object, e As System.Windows.Forms.DragEventArgs) _
    Handles TreeView1.DragDrop
    Dim destNode As TreeNode

    ' Get destinated TreeView Node
    destNode = TreeView1.GetNodeAt(TreeView1.PointToClient(New Point(e.X, e.Y)))

    If IsNothing(destNode) Then
        Return
    End If

    ' Gets dragged text
    Dim itemText As String
    itemText = DirectCast(e.Data.GetData(DataFormats.StringFormat), String)

    ' Assuming Node.Tag contains name of destinated ListView...
    Dim destListViewName As String
    destListViewName = destNode.Text

    ' ...find it on Form
    Dim destListView As ListView
    destListView = CType(Me.Controls.Find(destListViewName, True)(0), ListView)

    ' Add item to destinated ListView...
    destListView.Items.Add(itemText)

    ' ... and remove it from source ListView
    sourceListView.Items.Remove(sourceListView.FindItemWithText(itemText))
End Sub