Object-Oriented database design with the DatabaseObjects library

' ___________________________________________________
'
'  � Hi-Integrity Systems 2007. All rights reserved.
'  www.hisystems.com.au - Toby Wicks
' ___________________________________________________
'

Option Strict On
Option Explicit On 

''' --------------------------------------------------------------------------------
''' <summary>
''' This class can be used in conjunction with the DatabaseObjects class to simplify
''' the process of using the DatabaseObjects library. This class implements the 
''' IDatabaseObject interface and provides the basic "plumbing" code required by the 
''' interface. For this reason, inheriting from this class is preferable to 
''' implementing the IDatabaseObject interface directly.
''' </summary>
''' --------------------------------------------------------------------------------
''' 
Public MustInherit Class DatabaseObject
    Implements IDatabaseObject

    Private pbIsSaved As Boolean
    Private pobjDistinctValue As Object
    Private pobjParentCollection As DatabaseObjects

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Initializes a new DatabaseObject with the parent collection that this object is 
    ''' associated with.
    ''' </summary>
    ''' 
    ''' <example> 
    ''' <code>
    ''' 'Code from a class that has inherited from DatabaseObjects
    ''' 'So that this object has a reference to the parent
    ''' Protected Overrides Function ItemInstance() As DatabaseObjects.IDatabaseObject
    ''' 
    '''     Return New Product(Me)
    ''' 
    ''' End Function
    ''' </code>
    ''' </example>
    ''' --------------------------------------------------------------------------------
    ''' 
    Protected Sub New(ByVal objParentCollection As DatabaseObjects)

        If objParentCollection Is Nothing Then
            Throw New ArgumentNullException
        End If

        pobjParentCollection = objParentCollection

    End Sub

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Returns the parent collection (DatabaseObjects instance) that this object is 
    ''' associated with.
    ''' </summary>
    ''' --------------------------------------------------------------------------------
    ''' 
    Protected ReadOnly Property ParentCollection() As DatabaseObjects
        Get

            Return pobjParentCollection

        End Get
    End Property

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Returns the database associated with this object.
    ''' </summary>
    ''' --------------------------------------------------------------------------------
    '''
    Protected ReadOnly Property ParentDatabase() As Database
        Get

            Return pobjParentCollection.Database

        End Get
    End Property

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Extracts the fields to save to the database from the objItem.SaveFields function.
    ''' The fields are then written to the database using either an SQL INSERT or UPDATE 
    ''' depending on whether the object has already been saved. If the collection has 
    ''' implemented IDatabaseObjects.KeyFieldName then objItem's key is also validated to
    ''' ensure it is not null and unique within the collection.
    ''' If the parent collection has implemented Subset then this object should exist 
    ''' within the parent collection. If not, a duplicate key error may occur if the key 
    ''' is being used in another subset in the same table. If a record is being amended 
    ''' (MyBase.IsSaved is True) then the function will "AND" the parent collection's 
    ''' Subset conditions and the DistinctValue value to create the WHERE clause in the 
    ''' UPDATE statement. Therefore, the combination of the IDatabaseObjects.Subset and 
    ''' IDatabaseObject.DistinctValue conditions MUST identify only one record in the 
    ''' table. Otherwise multiple records will be updated with the same data. If data is
    ''' only inserted and not amended (usually a rare occurance) then this requirement 
    ''' is unnecessary.
    ''' </summary>
    ''' 
    ''' <example> 
    ''' <code>
    ''' 'Make the inherited "Protected Sub Save" public
    ''' Public Overrides Sub Save()
    ''' 
    '''     MyBase.Save()
    ''' 
    ''' End Sub
    ''' </code>
    ''' </example>    
    ''' --------------------------------------------------------------------------------
    ''' 
    Protected Overridable Sub Save()

        ParentDatabase.ObjectSave(ParentCollection, Me)

    End Sub

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Returns the distinct value that uniquely identifies this object in the 
    ''' database. If a new object is saved or an existing object is loaded then this 
    ''' property is automatically set by the library. 
    ''' Typically, this is the value of an identity or auto increment database field.
    ''' </summary>
    ''' --------------------------------------------------------------------------------
    '''
    Protected Overridable Property DistinctValue() As Object Implements IDatabaseObject.DistinctValue
        Get

            Return pobjDistinctValue

        End Get

        Set(ByVal Value As Object)

            pobjDistinctValue = Value

        End Set
    End Property

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Returns whether this object has been saved to the database. If a new object is 
    ''' saved (which uses an auto increment field) or an existing object is loaded then 
    ''' this property is automatically set to true by the library.
    ''' </summary>
    ''' --------------------------------------------------------------------------------
    '''
    Protected Overridable Property IsSaved() As Boolean Implements IDatabaseObject.IsSaved
        Get

            Return pbIsSaved

        End Get

        Set(ByVal Value As Boolean)

            pbIsSaved = Value

        End Set
    End Property

    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Should copy the database fields from objFields to this object's variables. 
    ''' objFields is populated with all of the fields from the associated record.
    ''' </summary>
    ''' 
    ''' <example> 
    ''' <code>
    ''' Protected Overrides Sub LoadFields(ByVal objFields As DatabaseObjects.SQL.SQLFieldValues)
    ''' 
    '''     pstrCode = objFields("ProductCode").Value
    '''     pstrDescription = objFields("ProductDescription").Value
    ''' 
    ''' End Sub
    ''' </code>
    ''' </example>
    ''' --------------------------------------------------------------------------------
    ''' 
    Protected MustOverride Sub LoadFields(ByVal objFields As SQL.SQLFieldValues) Implements IDatabaseObject.LoadFields


    ''' --------------------------------------------------------------------------------
    ''' <summary>
    ''' Should return an SQLFieldValues object populated with the  
    ''' fields to be written to the database. The first argument of the 
    ''' SQLFieldValues.Add function is the database field name, the second is the 
    ''' field's value.
    ''' </summary>
    ''' 
    ''' <example> 
    ''' <code>
    ''' Protected Overrides Function SaveFields() As DatabaseObjects.SQL.SQLFieldValues
    ''' 
    '''     SaveFields = New SQL.SQLFieldValues
    '''     SaveFields.Add("ProductCode", pstrCode)
    '''     SaveFields.Add("ProductDescription", pstrDescription)
    ''' 
    ''' End Function
    ''' </code>
    ''' </example>
    ''' --------------------------------------------------------------------------------
    ''' 
    Protected MustOverride Function SaveFields() As SQL.SQLFieldValues Implements IDatabaseObject.SaveFields

End Class