Click here to Skip to main content
15,892,161 members
Articles / Programming Languages / C++

Implement Phonetic ("Sounds-like") Name Searches with Double Metaphone Part I: Introduction & C++ Implementation

Rate me:
Please Sign up or sign in to vote.
4.91/5 (21 votes)
19 Mar 2007CPOL15 min read 148.7K   2.8K   60  
Introduces the Double Metaphone algorithm for phonetic comparison of proper names, and provides a practical C++ implementation for use in the reader's projects.
Option Explicit

dim wordMap

 'Create the dictionary which will contain the phonetic key->word map
 Set wordMap = CreateObject("Scripting.Dictionary")
 
 'Read the namelist file
 Dim oFile
 Dim oStream
 Dim word
 Dim words
 Dim mphone
 Dim primaryKey
 Dim alternateKey
 
 Set oFile = CreateObject("Scripting.FileSystemObject")
 Set oStream = oFile.OpenTextFile("..\namelist.txt")
 Set mphone = CreateObject("MetaphoneCOM.DoubleMetaphoneString")
 
 WScript.Echo "Loading name data; this will take several seconds..."
 
 While Not oStream.AtEndOfStream
     word = oStream.ReadLine
     mphone.ComputeMetaphoneKeysScr word, primaryKey, alternateKey
     
     'Add an entry to the dictionary for each key
     If Not wordMap.Exists(primaryKey) Then
         'No words associated with this key, so create an empty entry for it
         wordMap.Add primaryKey, Array()
     End If
     
     'Get the array of words for the key, then grow it by one and add
     'the word we just read
     words = wordMap.Item(primaryKey)
     ReDim Preserve words(UBound(words) + 1)
     words(UBound(words)) = word
     wordMap.Item(primaryKey) = words
     
     If Len(alternateKey) > 0 Then
         'Alternate key also computed
         If Not wordMap.Exists(alternateKey) Then
             'No words associated with this key, so create an empty entry for it
             wordMap.Add alternateKey, Array()
         End If
         
         'Get the array of words for the key, then grow it by one and add
         'the word we just read
         words = wordMap.Item(alternateKey)
         ReDim Preserve words(UBound(words) + 1)
         words(UBound(words)) = word
         wordMap.Item(alternateKey) = words
     End If
 Wend
 oStream.Close
 
 'Begin the search
dim searchWord
dim results
Dim wordIdx
Dim listIdx
dim resultsString

'Hack the dictionary object for use a a Set, which does not allow duplicate entries, to
'de-dupe the list of results
set results = CreateObject("Scripting.Dictionary")

while true
   searchWord = InputBox("Enter name to search for", "VBScript Word Lookup", "Nelson")
   if searchWord = "" then
      WScript.Quit()
   end if
   searchWord = Trim(searchWord)
   If Len(searchWord) = 0 Then
      MsgBox "You must enter a search word"
      WScript.Quit()
   End If
   
   mphone.ComputeMetaphoneKeysScr searchWord, primaryKey, alternateKey
   results.RemoveAll
   
   If wordMap.Exists(primaryKey) Then
      words = wordMap.Item(primaryKey)
      
      For wordIdx = 0 To UBound(words)
         Results(words(wordIdx)) = true
      Next
   End If
   
   If Len(alternateKey) > 0 Then
     'Also an alternate key.  Search with that
     If wordMap.Exists(alternateKey) Then
         words = wordMap.Item(alternateKey)
         
         For wordIdx = 0 To UBound(words)
            Results(words(wordIdx)) = true
         Next
     End If
   End If
   
   'The Keys property of the results dictionary contains a list of unique words from
   'the results
   resultsString = "Found " & results.Count & " matches:" & vbCrLf
   
   for each word in results.Keys
      resultsString = resultsString & vbTab & word & vbCrLf
   next
   
   MsgBox resultsString, , "VBScript Word Lookup"
wend

By viewing downloads associated with this article you agree to the Terms of Service and the article's licence.

If a file you wish to view isn't highlighted, and is a text file (not binary), please let us know and we'll add colourisation support for it.

License

This article, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)


Written By
Web Developer
United States United States
My name is Adam Nelson. I've been a professional programmer since 1996, working on everything from database development, early first-generation web applications, modern n-tier distributed apps, high-performance wireless security tools, to my last job as a Senior Consultant at BearingPoint posted in Baghdad, Iraq training Iraqi developers in the wonders of C# and ASP.NET. I am currently an Engineering Director at Dell.

I have a wide range of skills and interests, including cryptography, image processing, computational linguistics, military history, 3D graphics, database optimization, and mathematics, to name a few.

Comments and Discussions