Click here to Skip to main content
12,748,322 members (39,591 online)
Click here to Skip to main content
Add your own
alternative version

Stats

576K views
70.8K downloads
324 bookmarked
Posted 17 Nov 2011

WPF: Webcam Control

, 18 Nov 2011 CPOL
Rate this:
Please Sign up or sign in to vote.
A WPF UserControl for displaying and recording video from a webcam
This is an old version of the currently published article.

Screenshot_1.png

Introduction

I have on several occasions scoured the net for a simple to use WPF webcam control and either my search queries were awful or I just wasn't comfortable with whatever I found. This webcam interest was recently increased when I read an article, here on CodeProject, that referred to an application that made use of a webcam. It was a Silverlight article and the ease with which one could utilize a webcam in Silverlight made me envious of WPF's little brother (or is it sister?). The VideoBrush in Silverlight is especially a nice touch.

It is with this pain and envy in mind that I decided to try my hand at creating a WPF control that could;

  1. Display webcam video with little coding effort,
  2. Allow saving of webcam video to harddisk, with little coding effort,
  3. Save the webcam video in a variety of video formats.

Background

With the previously mentioned goals in mind I created a WPF UserControl that has the following features;

  • Displays webcam video,
  • Enables saving of webcam videos to harddisk,
  • Enables saving of webcam videos in either; .wmv, .mp4, or .flv format.

The Webcam control makes heavy use of the Expression Encoder 4 SDK. You therefore need to have the SDK installed on your machine to make use of the UserControl. You can download the SDK from here.

Requirements

To make use of the Webcam control you require;

  • .NET Framework 4.0,
  • Expression Encoder SDK

Using the Webcam Control

To use the Webcam control in your WPF application add a reference to WebcamControl.dll and a using/imports statement for WebcamControl at the top of your class.

Add a reference to Microsoft.Expression.Encoder.dll . Do this by using the Add Reference dialog box, selecting the .NET tab, and selecting Microsoft.Expression.Encoder from the listbox. The Expression Encoder assemblies should be available if you have installed Expression Encoder 4.

The following example, which is the downloadable sample application, shows the use of the Webcam control. The sample application contains; a ContentControl that will host the Webcam control, two ComboBoxes for displaying the names of audio and video devices connected to the machine, and four buttons.

Imports Microsoft.Expression.Encoder.Devices
Imports WebcamControl

Class MainWindow
    Dim webCamCtrl As New Webcam

    Private Sub MainWindow_Loaded(ByVal sender As Object, _
                                  ByVal e As System.Windows.RoutedEventArgs) Handles Me.Loaded
        FindDevices()

        Dim path As String = "C:\VideoClips"

        If Directory.Exists(path) = False Then
            Directory.CreateDirectory(path)
        End If

        ' Set some properties of the Webcam control.
        webCamCtrl.VideoDirectory = path
        webCamCtrl.VidFormat = VideoFormat.wmv

        ' Set the Webcam control as the ContentControl's content.
        ContentControl1.Content = webCamCtrl

        VidDvcsComboBox.SelectedIndex = 0
        AudDvcsComboBox.SelectedIndex = 0
    End Sub

    ' Find available a/v devices.
    Private Sub FindDevices()
        Dim vidDevices = EncoderDevices.FindDevices(EncoderDeviceType.Video)
        Dim audDevices = EncoderDevices.FindDevices(EncoderDeviceType.Audio)

        For Each dvc In vidDevices
            VidDvcsComboBox.Items.Add(dvc.Name)
        Next

        For Each dvc In audDevices
            AudDvcsComboBox.Items.Add(dvc.Name)
        Next
    End Sub

    Private Sub StartButton_Click(ByVal sender As System.Object, _
                                  ByVal e As System.Windows.RoutedEventArgs) Handles StartButton.Click

        ' Display webcam images on control.
        Try
            webCamCtrl.StartCapture()
        Catch ex As Microsoft.Expression.Encoder.SystemErrorException
            MessageBox.Show("Device is in use by another application")
        End Try
    End Sub

    Private Sub EndButton_Click(ByVal sender As Object, _
                                ByVal e As System.Windows.RoutedEventArgs) Handles EndButton.Click

        ' Stop the display of webcam video.
        webCamCtrl.StopCapture()
    End Sub

    Private Sub RecordButton_Click(ByVal sender As System.Object, _
                                   ByVal e As System.Windows.RoutedEventArgs) Handles RecordButton.Click

        ' Start recording of webcam video to harddisk.
        webCamCtrl.StartRecording()
    End Sub

    Private Sub StopRecordButton_Click(ByVal sender As Object, _
                                       ByVal e As System.Windows.RoutedEventArgs) Handles StopRecordButton.Click

        ' Stop recording of webcam video to harddisk.
        webCamCtrl.StopRecording()
    End Sub

    Private Sub VidDvcsComboBox_SelectionChanged(ByVal sender As Object, _
                                                 ByVal e As System.Windows.Controls.SelectionChangedEventArgs) _
                                             Handles VidDvcsComboBox.SelectionChanged

        ' Set which video device to use.
        webCamCtrl.VideoDevice = VidDvcsComboBox.SelectedValue
    End Sub
   
    Private Sub AudDvcsComboBox_SelectionChanged(ByVal sender As Object, _
                                                 ByVal e As System.Windows.Controls.SelectionChangedEventArgs) _
                                             Handles AudDvcsComboBox.SelectionChanged

        ' Set which audio device to use.
        webCamCtrl.AudioDevice = AudDvcsComboBox.SelectedValue
    End Sub
End Class

As you can see from the sample code using the Webcam control is not a hard affair once you have the necessary references and imports/using statements.

NB: The VideoDevice and AudioDevice properties of Webcam control are dependency properties and can therefore be data-bound to the SelectedValue property of the necessary ComboBox.

Webcam

The following are the members of interest in class Webcam;

Properties

 NameDescriptionType
PropertyIcon.pngVideoDirectoryGets or Sets the folder where the recorded webcam video will be saved. This is a dependency property.String
PropertyIcon.pngVidFormatGets or Sets the video format in which the webcam video will be saved. This is a dependency property. (The default format is .wmv)VideoFormat
PropertyIcon.pngVideoDeviceGets or Sets the name of the video device to be used. This is a dependency property.String
PropertyIcon.pngAudioDeviceGets or Sets the name of the audio device to be used. This is a dependency property.String
PropertyIcon.pngIsRecordingGets a value indicating whether video recording is taking place. This is a read-only property.Boolean

Methods

 NameDescription
MethodIcon.pngStartCaptureDisplays webcam video on control. (Throws a Microsoft.Expression.Encoder.SystemErrorException if a specified device is already in use by another application)
MethodIcon.pngStopCaptureStops the capturing/display of webcam video. (Stops any current recording of webcam video)
MethodIcon.pngStartRecordingStarts the recording of webcam video to a video file. (Throws a DirectoryNotFoundException if the directory specified in the VideoDirectory property is not found)
MethodIcon.pngStopRecordingStops the recording of webcam video.

The Code

The XAML markup for the UserControl is;

<UserControl x:Class="Webcam" 
             xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation" 
             xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml" 
             Height="Auto" Width="Auto" MinHeight="100" MinWidth="100" 
             xmlns:d="http://schemas.microsoft.com/expression/blend/2008" 
             xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006"
             xmlns:wf="clr-namespace:System.Windows.Forms;assembly=System.Windows.Forms"
             mc:Ignorable="d" d:DesignWidth="320" d:DesignHeight="240" Name="Webcam">
    <Grid>
        <WindowsFormsHost Margin="0,0,0,0" Name="WinFormHost" Background="{x:Null}">
            <wf:Panel x:Name="WebcamPanel" Size="320,240" />
        </WindowsFormsHost>
    </Grid>
</UserControl>

The dimensions of the WinForm Panel are adjusted when the control is loaded so that the webcam video will occupy the entire area of the Panel's parent element.

Private Sub Webcam_Loaded(ByVal sender As Object, _
                          ByVal e As System.Windows.RoutedEventArgs) Handles Me.Loaded
    ' Set dimensions of WinForm Panel to current dimensions
    ' of the UserControl.
    Dim panelWidth As Integer = CInt(Me.ActualWidth)
    Dim panelHeight As Integer = CInt(Me.ActualHeight)

    WebcamPanel.Width = panelWidth
    WebcamPanel.Height = panelHeight
End Sub

As highlighted earlier, Webcam contains several properties and methods that aid in its operation. The VideoDevice dependency property is defined as follows;

''' <summary>
''' Gets or Sets the name of the video device to be used.
''' </summary>
Public Property VideoDevice() As String
    Get
        Return CType(GetValue(VideoDeviceProperty), String)
    End Get
    Set(ByVal value As String)
        SetValue(VideoDeviceProperty, value)
    End Set
End Property

Public Shared VideoDeviceProperty As DependencyProperty = _
    DependencyProperty.Register("VideoDevice", GetType(String), GetType(Webcam), _
                                New FrameworkPropertyMetadata(New PropertyChangedCallback( _
                                                              AddressOf VidDeviceChange)))

Private Shared Sub VidDeviceChange(ByVal source As DependencyObject, ByVal e As DependencyPropertyChangedEventArgs)
    Dim deviceName As String = CType(e.NewValue, String)
    Dim eDev = EncoderDevices.FindDevices(EncoderDeviceType.Video).Where _
               (Function(dv) dv.Name = deviceName)

    If (eDev.Count > 0) Then
        CType(source, Webcam).vidDevice = eDev.First
        CType(source, Webcam).Display()
    End If
End Sub

The StartCapture method displays the webcam video in the WinForm Panel, if the necessary properties are set;

''' <summary>
''' Display webcam video on control.
''' </summary>
Public Sub StartCapture()
    If (canCapture = False) Then
        canCapture = True
        Try
            Display()
        Catch ex As Microsoft.Expression.Encoder.SystemErrorException
            canCapture = False
            Throw New Microsoft.Expression.Encoder.SystemErrorException
        End Try
    Else
        Exit Sub
    End If
End Sub

' Display video from webcam.
Private Sub Display()
    If (canCapture = True) Then
        If (vidDevice IsNot Nothing) Then
            StopRecording()
            Dispose()

            job = New LiveJob

            deviceSource = job.AddDeviceSource(vidDevice, audDevice)
            deviceSource.PreviewWindow = New PreviewWindow(New HandleRef(WebcamPanel, WebcamPanel.Handle))

            job.ActivateSource(deviceSource)
        End If
    End If
End Sub

The StartRecording method records video from the webcam to the harddisk;

''' <summary>
''' Starts the recording of webcam video to a video file.
''' </summary>
Public Sub StartRecording()
    If (dir <> String.Empty AndAlso job IsNot Nothing) Then
        If (Directory.Exists(dir) = False) Then
            Throw New DirectoryNotFoundException("The specified directory does not exist")
            Exit Sub
        End If

        ' If canCapture is true then it means the control is capturing video
        ' from the webcam.
        If (canCapture = True) Then
            StopRecording()
            job.PublishFormats.Clear()

            Dim timeStamp As String = DateTime.Now.ToString
            timeStamp = timeStamp.Replace("/", "-")
            timeStamp = timeStamp.Replace(":", ".")
            Dim filePath As String = dir & "\WebcamVid " & timeStamp & "." & format

            Dim fileArchFormat As New FileArchivePublishFormat(filePath)
            job.PublishFormats.Add(fileArchFormat)
            job.StartEncoding()

            _isRecording = True
        End If
    End If
End Sub

The VideoFormat enumeration contains three members;

Public Enum VideoFormat
    wmv
    mp4
    flv
End Enum

You can take a look at the other properties and methods defined in class Webcam by downloading the src files from the download link at the top of this article.

Conclusion

I hope that you picked up something useful from this article. I'm a novice in audio-video-encoding-decoding matters so if you have any questions regarding such technicalities please try to post them in the associated forums here on CodeProject. Suggestions will be beneficial, as well as answers you receive to any technical queries that may be associated with this article's content. Thanks.

License

This article, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)

Share

About the Author

Meshack Musundi
Software Developer
Kenya Kenya
Meshack has about 7 years of programming experience initially starting off with Java before shifting to .NET, thanks to the allure of WPF.

Awards;

  • CodeProject MVP 2013

  • CodeProject MVP 2012



  • Best VB.NET article of January 2015

  • Best VB.NET article of August 2013

  • Best VB.NET article of February 2013

  • Best VB.NET article of October 2012

  • Best VB.NET article of July 2012

  • Best VB.NET article of February 2012

  • Best VB.NET article of January 2012

  • Best VB.NET article of November 2011

  • Best VB.NET article of June 2011

  • Best VB.NET article of May 2011

  • Best VB.NET article of March 2011

  • Best VB.NET article of February 2011

  • Best VB.NET article of January 2011

  • Best VB.NET article of December 2010

  • Best VB.NET article of November 2010


You may also be interested in...

Pro
Pro

Comments and Discussions


Discussions posted for the Published version of this article. Posting a message here will take you to the publicly available article in order to continue your conversation in public.
 
QuestionSystem.NullReferenceException when using WPF tabs Pin
Member 1125681016-Feb-17 10:42
memberMember 1125681016-Feb-17 10:42 
AnswerRe: System.NullReferenceException when using WPF tabs Pin
Meshack Musundi17-Feb-17 3:32
professionalMeshack Musundi17-Feb-17 3:32 
GeneralRe: System.NullReferenceException when using WPF tabs Pin
Member 1125681017-Feb-17 10:36
memberMember 1125681017-Feb-17 10:36 
GeneralRe: System.NullReferenceException when using WPF tabs Pin
Meshack Musundi18-Feb-17 3:10
professionalMeshack Musundi18-Feb-17 3:10 
QuestionReturn filename after snapshot or video Pin
Member 1231566316-Jan-17 7:13
memberMember 1231566316-Jan-17 7:13 
AnswerRe: Return filename after snapshot or video Pin
Meshack Musundi17-Jan-17 21:05
professionalMeshack Musundi17-Jan-17 21:05 
QuestionProblem with Microsoft.Expression.Encoder Pin
Andrey_Smolensk9-Jan-17 20:44
memberAndrey_Smolensk9-Jan-17 20:44 
AnswerRe: Problem with Microsoft.Expression.Encoder Pin
Meshack Musundi11-Jan-17 4:25
professionalMeshack Musundi11-Jan-17 4:25 
GeneralMy vote of 5 Pin
Member 1276138229-Sep-16 17:41
memberMember 1276138229-Sep-16 17:41 
QuestionTake snapshot to Image control Pin
Member 119749981-Jul-16 8:35
memberMember 119749981-Jul-16 8:35 
QuestionUsers have to install the Expression Encoder app to use this. Pin
jonavark6-Jun-16 9:09
memberjonavark6-Jun-16 9:09 
Questionpreview window always got still image or black image Pin
arfken030917-May-16 21:43
memberarfken030917-May-16 21:43 
AnswerRe: preview window always got still image or black image Pin
Meshack Musundi18-May-16 1:00
professionalMeshack Musundi18-May-16 1:00 
GeneralRe: preview window always got still image or black image Pin
arfken030918-May-16 7:27
memberarfken030918-May-16 7:27 
AnswerRe: preview window always got still image or black image Pin
gooyou17-Jan-17 4:59
membergooyou17-Jan-17 4:59 
QuestionMultiple Previews from the same source Pin
GoCo Software3-May-16 6:25
memberGoCo Software3-May-16 6:25 
AnswerRe: Multiple Previews from the same source Pin
Meshack Musundi3-May-16 22:56
professionalMeshack Musundi3-May-16 22:56 
GeneralRe: Multiple Previews from the same source Pin
GoCo Software4-May-16 6:27
memberGoCo Software4-May-16 6:27 
GeneralRe: Multiple Previews from the same source Pin
Meshack Musundi4-May-16 23:44
professionalMeshack Musundi4-May-16 23:44 
GeneralRe: Multiple Previews from the same source Pin
GoCo Software5-May-16 2:15
memberGoCo Software5-May-16 2:15 
QuestionWebcamControl.dll Pin
Member 1246467716-Apr-16 13:44
memberMember 1246467716-Apr-16 13:44 
GeneralRe: WebcamControl.dll Pin
Meshack Musundi17-Apr-16 23:17
professionalMeshack Musundi17-Apr-16 23:17 
GeneralRe: WebcamControl.dll Pin
Member 1246467718-Apr-16 4:27
memberMember 1246467718-Apr-16 4:27 
GeneralRe: WebcamControl.dll Pin
Meshack Musundi18-Apr-16 9:42
professionalMeshack Musundi18-Apr-16 9:42 
Questionwinforms version Pin
Jeric Canatuan18-Feb-16 5:56
memberJeric Canatuan18-Feb-16 5:56 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Praise Praise    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.

Permalink | Advertise | Privacy | Terms of Use | Mobile
Web01 | 2.8.170215.1 | Last Updated 18 Nov 2011
Article Copyright 2011 by Meshack Musundi
Everything else Copyright © CodeProject, 1999-2017
Layout: fixed | fluid