Visual Basic

Private Client As New TcpClient
Private _readBufferSize As Integer = 128
Private ClientStreamBuffer(_readBufferSize) As Byte

Public Event DataToProcess(ByVal Buffer() As Byte)
Public Event ConnectionStateChange(ByVal Connected As Boolean)

Public Sub Connect(ByVal Host As String, ByVal Port As String)

    Try
        Client.NoDelay = True

        Client.ReceiveTimeout = 30

        Client.BeginConnect(Host, Port, AddressOf ConnectionResponse, Nothing)

    Catch ex As Exception
        Debug.WriteLine("Connect Failure: " + ex.Message)
    End Try

End Sub

Private Sub ConnectionResponse(ByVal Ar As IAsyncResult)

    Try
          'accept the connection
          Client.EndConnect(Ar)

          RaiseEvent ConnectionStateChange(Client.Connected)

          'start an async read of the clients datastream
          Client.GetStream.BeginRead(ClientStreamBuffer, 0, _readBufferSize, AddressOf ClientStreamReader, Nothing)
    Catch ex As Exception
        Debug.WriteLine("TCPIP Connection Failed: " + ex.Message)
    End Try
End Sub

Private Sub ClientStreamReader(ByVal Ar As IAsyncResult)

    Try
        Dim bytesRead As Integer = Client.GetStream.EndRead(Ar)

        Dim bytesToProcess(bytesRead - 1) As Byte

        'Copy data off the buffer into the process array
        Array.Copy(ClientStreamBuffer, 0, bytesToProcess, 0, bytesRead)

        'do something like raise an event with BytesToProcess
        RaiseEvent DataToProcess(bytesToProcess)

        'Start the read again
        Client.GetStream.BeginRead(ClientStreamBuffer, 0, _readBufferSize, AddressOf ClientStreamReader, Nothing)

    Catch ex As Exception
        Debug.WriteLine("StreamReader Problem: " + ex.Message)
    End Try
End Sub

Private Sub TCPIPComms_DataToProcess(ByVal Buffer() As Byte) Handles Me.DataToProcess
    Debug.WriteLine("Data Buffer Available bytes: " + Buffer.Length.ToString)

    'Do something with the bytes...............
End Sub