TRUNCATE/DELETE/DROP tables referenced by a foreign key constraint

SET @Query =
'WITH EliminateUnwanted (Name,[Object_ID],parent_object_id ,referenced_object_id)  AS
(
    SELECT
        [T].Name,
        [T].[Object_ID],
        [F].parent_object_id,
        [F].referenced_object_id
    FROM ' + @DBName + '.SYS.TABLES [T]
    LEFT JOIN ' + @DBName + '.SYS.FOREIGN_KEYS [F] ON [T].object_id = [F].parent_object_id
    WHERE [T].Name NOT IN (''SysDiagrams'', ''tmpTable'') AND [T].TYPE = ''U''
),
SetPriority (Name,[Object_ID],parent_object_id ,referenced_object_id, parentObjectName, Priorities)  AS
(
    SELECT
        *,
        OBJECT_NAME(referenced_object_id) AS referencedObjectName,
        CASE
            WHEN referenced_object_id IS NULL
                AND [Object_ID] NOT IN (SELECT ISNULL(referenced_object_id,'''') FROM EliminateUnwanted)
                THEN 0
            WHEN [Object_ID] NOT IN ( SELECT ISNULL(referenced_object_id,'''')
                  FROM EliminateUnwanted )
                THEN 2
            WHEN ([Object_ID] IN ( SELECT ISNULL(referenced_object_id,'''')
                  FROM EliminateUnwanted ) AND parent_object_id IS NULL)
                THEN 8
            WHEN [Object_ID] IN ( SELECT ISNULL([U2].referenced_object_id,'''')
                FROM EliminateUnwanted [U1]
                    LEFT JOIN EliminateUnwanted [U2]
                    ON [U1].referenced_object_id = [U2].parent_object_id
                WHERE [U1].referenced_object_id IS NOT NULL
                    )
                THEN 6
            ELSE 4
        END ''PRIORITY''
    FROM EliminateUnwanted
),
DuplicateRemoval (Occurence, Name,[Object_ID],parent_object_id,
       referenced_object_id, referencedObjectName, Priorities)  AS
(
    SELECT
        ROW_NUMBER() OVER(PARTITION BY NAME ORDER BY NAME) AS Occurence
        ,*
    FROM SetPriority
)
SELECT
    [Object_ID]
    ,MIN(Priorities) Priorities
FROM (
SELECT [DR1].Name
    ,[DR1].[Object_ID]
    ,[DR1].parent_object_id
    ,[DR1].referenced_object_id
    ,[DR1].referencedObjectName
    ,[DR1].Priorities + ISNULL([DR2].[Object_ID],1) - ISNULL([DR2].[Object_ID],0) Priorities
FROM DuplicateRemoval [DR1]
    LEFT JOIN  DuplicateRemoval [DR2]
    ON [DR1].Priorities = [DR2].Priorities
    AND [DR1].referenced_object_id = [DR2].parent_object_id ) Res
GROUP BY
    [Object_ID]
'

use master;
if object_id('dbo.sp_FlushTables', 'P') is not null
    drop procedure dbo.sp_FlushTables;
go

create procedure dbo.sp_FlushTables
(
     @TableFilter   varchar(256)
)
as
begin

    if @TableFilter = ''
        set @TableFilter = '%';

    declare @tables table
    (
         RowNumber          int not null
        ,object_id          int not null
        ,name               sysname not null
        ,referenced_name    sysname null
        ,parent_name        sysname null
        ,priority           int not null
    );

    with EliminateUnwanted ([object_id], name, parent_name, referenced_name) as
    (
        select
             t.[object_id]
            ,s.name + '.' + t.name
            ,sp.name + '.' + tp.name
            ,sr.name + '.' + tr.name
        from sys.tables t
            inner join sys.schemas as s
                on s.schema_id = t.schema_id
            left outer join sys.foreign_keys f 
                on t.object_id = f.parent_object_id
            left outer join sys.tables as tp
                on tp.object_id = f.parent_object_id
            left outer join sys.schemas as sp
                on sp.schema_id = tp.schema_id
            left outer join sys.tables as tr
                on tr.object_id = f.referenced_object_id
            left outer join sys.schemas as sr
                on sr.schema_id = tr.schema_id
        where t.type = 'U'
            --and t.name not in ('SysDiagrams', 'tmpTable')
            and t.name like @TableFilter
    ),
    SetPriority ([object_id], name, parent_name, referenced_name, priority) as
    (
        select
             [object_id]
            ,name
            ,parent_name
            ,referenced_name
            ,case
                when referenced_name is null 
                    and name not in 
                    (
                         select isnull(referenced_name, '') 
                         from EliminateUnwanted 
                     ) then 1
                when name not in 
                    ( 
                        select isnull(referenced_name, '')
                        from EliminateUnwanted
                     ) then 2
                when parent_name is null 
                    and name in 
                    ( 
                        select isnull(referenced_name, '')
                        from EliminateUnwanted 
                    ) then 4
                else 3
            end 
        from EliminateUnwanted
    ),
    DuplicateRemoval (occurence, [object_id], name, referenced_name, parent_name, priority) as
    (
        select
             row_number() over(partition by name order by name)
            ,[object_id]
            ,name
            ,referenced_name
            ,parent_name
            ,priority
        from SetPriority
    )
    insert into @tables
    select
        row_number() over(order by priority, name),
        object_id,
        name,
        referenced_name,
        parent_name,
        priority
    from DuplicateRemoval
    where Occurence = 1;

    while(select count(*) from @tables) > 0
    begin
        declare @tableName  varchar(512);
        declare @sql        nvarchar(1024);
        
        select top 1 @tableName = name
        from @tables;

        set @sql = N'select * from ' + @tableName;

        exec sp_executesql @sql;

        delete 
        from @tables 
        where name = @tableName;
    end

end
go

exec sys.sp_MS_marksystemobject 'sp_FlushTables';