Click here to Skip to main content
Click here to Skip to main content
Go to top

Generic P2P Architecture, Tutorial and Example

, 14 Mar 2004
Rate this:
Please Sign up or sign in to vote.
Generic P2P architecture, tutorial and example that covers basic P2P strategy. Upon completing this tutorial, you will be proficient in basic P2P design and coding.

This generic P2P architecture tutorial was brought to you by Planet API – Searching thousands of ASPX / ASP.NET Public Webmethods / Public Webservices, Search Engine APIs, Novelty APIs, B2B APIs, Game APIs, P2P APIs, Fun APIs, AI Chatbot APIs, etc.

Overview of P2P Culture

P2P (Peer To Peer) is when multiple computers think collectively towards a shared objective. Computer programs that use less central servers and rely on a collection of computers such as Gnutella, distributed media streaming, networks of DCC based IRC fservers etc. tend to be referred to as being more P2P. Computer programs where many end-users communicate with few central services tend to be referred to as being less P2P or not P2P. To fully understand and leverage P2P technology, one must separate his or her self from the dogma that our computer programs must be united by servers in our physical possession to synchronize activities. Rather, think of our computer programs from a more digital-life oriented perspective and break the computer software up over multiple machines and make no single part of the software critical to the collective objective.

P2P Philosophy

“Single servants are less powerful then a single server but the collective of many servants is more powerful then any single server” - Daniel Stephen Rule.

For example, a large software company gives each employee a very small amount of responsibility. Even if this means you get your month’s coding done in a few days, it is more beneficial to the company as a whole to not rely on any single employee too much and allows the company more overall stability and to ultimately write larger more complex software packages than any single person is capable of. Your software is more P2P if you leverage this same principle to achieve more bandwidth and computing speed.

Basic P2P Terminology

Peer or Servant

A computer program that acts as both a client and a server for the entire P2P network.

Connection Manager

A light server application that provides a starting point for applications which enter a P2P network. The less the connection manager is involved in the objective of your overall application, the more P2P your application is. The more P2P your application is, the less strain on your own hardware.

Sample image

Simple P2P Chat Example

This example demonstrates a very simple but highly P2P application. This example consists of two fundamental P2P parts: a connection manager and a servant. The connection manager should be compiled and executed once. The servant should be compiled and its config.xml’s connectionmgr tag should be set to the IP address or domain name of the computer that is running the connection manager. Make multiple copies of the servant’s executable and config.xml and place them on multiple computers. Execute each servant on a different machine and they will contact the connection manager to resolve each other’s location and network with each other. Each servant will frequently ask the connection manager who is on the P2P network and keep their own publish list up to date. When a servant leaves the network, an updated list is published to all the other servants and they discontinue attempting to communicate with the servant who left.

Can I still try this out if I only have one computer to work with?

Yes. The connection manager assigns a new port number to each servant so each servant listens on a unique port number. You can run the servant executable as many times as you want on a single machine. For your first test, I would suggest running the connection manager once and then run the servant a couple of times on the same machine as the connection manager. Then chat in the servant windows to verify that the P2P network has been constructed on your computer. If you have other computers to work with, simply execute the servant on the other computers and chat to verify that they successfully joined the P2P network.

The configuration file:

  <config> 

Put the IP address of the server that has the connection manager here.

   <connectionmgr>127.0.0.1</connectionmgr> 

Leave this 85 unless you change the port that the connection manager sits on:

   <port>85</port>

List the IP addresses or domain names that you wish this servant to ignore:

  <bans>
    <ban>
    <target>1.1.1.1</target> 
    </ban>
    <ban>
     <target>fooUser234.fooISP23423.com</target> 
    </ban>
   </bans>
  </config>

What are the ban tags for?

The ban tags allow each servant to list the IP addresses or domain names that they do not wish to get data from.

Sample image

The Connection Manager

Add a peer to the connection manager’s knowledge of the P2P network.

Private Sub p2p_ConnectionRequest(Index As Integer, ByVal requestID As Long)
    iPortMax = iPortMax + 1
    Dim a As Integer
    For a = 1 To p2p.UBound
        Dim istate As Integer
        istate = p2p(a).State
        If istate = 0 Or istate = 8 Then
            Call EnterCriticalSection(tCritSection)
            RemovePeerByOffset CStr(a)
            p2p(a).Close
            p2p(a).Accept requestID
            AddPeer p2p(a).RemoteHostIP, CStr(iPortMax), CStr(a)
            Call LeaveCriticalSection(tCritSection)
            Exit Sub
        End If
        DoEvents
    Next a
    DoEvents
    Dim i As Integer
    i = p2p.UBound
    Call EnterCriticalSection(tCritSection)
    Load p2p(i + 1)
    p2p(i + 1).Accept requestID
    AddPeer p2p(i + 1).RemoteHostIP, CStr(iPortMax), CStr(i + 1)
    Call LeaveCriticalSection(tCritSection)
End Sub 

A servant wants a list of all its peers.

Private Sub p2p_DataArrival(Index As Integer, ByVal bytesTotal As Long)
    Dim a As String
    If p2p(Index).State <> 7 Then p2p(Index).Close: Exit Sub
    p2p(Index).GetData a
    If a = "needs peer list" Then
        On Error GoTo exit_critical_list
        Call EnterCriticalSection(tCritSection)
        Dim pPersonalPeerDoc As MSXML2.DOMDocument
        Set pPersonalPeerDoc = New MSXML2.DOMDocument
        pPersonalPeerDoc.loadXML pDoc.xml
        pPersonalPeerDoc.selectSingleNode("./peers/peer[offset = '" &_
                                           Index & "']/me").Text = "TRUE"
        p2p(Index).SendData pPersonalPeerDoc.xml
exit_critical_list:
        On Error Resume Next
        Call LeaveCriticalSection(tCritSection)
    Else
        MsgBox Index & " sent: " & a & " to the connection manager"
    End If
End Sub 

A servant left the network.

Private Sub p2p_Close(Index As Integer)
        Call EnterCriticalSection(tCritSection)
            RemovePeerByOffset CStr(Index)
        Call LeaveCriticalSection(tCritSection)
End Sub

The Servants

The connection manager has a new list of this servant’s peers.

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
    Dim document As String
    If Winsock1.State <> 7 Then Winsock1.Close: Exit Sub
    Winsock1.GetData document
    pDoc1.loadXML document

    Dim pPeerList As MSXML2.IXMLDOMNodeList
    Set pPeerList = pDoc1.selectNodes("./peers/peer/port")
    userList1.Clear
    Dim i As Integer
    For i = 0 To pPeerList.length - 1
        If pPeerList(i).Text = _
          pDoc1.selectSingleNode("./peers/peer[me = 'TRUE']/port").Text Then
            userList1.AddItem "*" & pPeerList(i).Text
        Else
            userList1.AddItem pPeerList(i).Text
        End If
    Next
    servants1(0).Close
    servants1(0).LocalPort = _
      CInt(pDoc1.selectSingleNode("./peers/peer[me = 'TRUE']/port").Text)
    servants1(0).Listen
End Sub

This servant is connecting to all of its peers and publishing some data to all of them.

Private Sub txtSend1_KeyPress(KeyAscii As Integer)
On Error Resume Next
 If KeyAscii = 13 Then
  iSendsLeft1 = pDoc1.selectNodes("./peers/peer").length
  Dim i As Integer
  For i = 0 To pDoc1.selectNodes("./peers/peer").length - 1
   Dim iIp As String
   Dim iPort As Integer
   iIp = _
    pDoc1.selectNodes("./peers/peer").Item(i).selectSingleNode("./ip").Text
   iPort = _
    CInt(pDoc1.selectNodes("./peers/peer").Item(i).selectSingleNode("./port").Text)
   Dim strState As String
   While send1.State = 6
       DoEvents
   Wend
   send1.Close
   send1.Connect iIp, iPort
  Next
 End If
 DoEvents
End Sub

A peer of this servant wants to connect.

Private Sub servants1_ConnectionRequest(Index As Integer,_
                                          ByVal requestID As Long)
    Dim remoteip As String
    Dim remoteaddy As String
    remoteip = servants1(Index).RemoteHostIP
    remoteaddy = servants1(Index).RemoteHost
    If (pConfig.selectNodes("./config/bans/ban[target = '"_
      & remoteip & "']").length = 0) _
      And (pConfig.selectNodes("./config/bans/ban[target = '" _
      & remoteaddy & "']").length = 0) Then
        Dim a As Integer
        For a = 1 To servants1.UBound
            If servants1(a).State = 0 Or servants1(a).State = 8 Then
                Call EnterCriticalSection(tCritSection)
                servants1(a).Close
                servants1(a).Accept requestID
                Call LeaveCriticalSection(tCritSection)
                Exit Sub
            End If
            DoEvents
        Next a
        DoEvents
        Call EnterCriticalSection(tCritSection)
        Dim i As Integer
        i = servants1.UBound
        Load servants1(i + 1)
        servants1(i + 1).Accept requestID
        Call LeaveCriticalSection(tCritSection)
    End If
End Sub

A peer of this servant has some data for it.

Private Sub servants1_DataArrival(Index As Integer,_
                                   ByVal bytesTotal As Long)
On Error Resume Next
    Dim a As String
    If servants1(Index).State <> 7 Then servants1(Index).Close: Exit Sub
    servants1(Index).GetData a
    txtChat1.Text = txtChat1.Text & vbCrLf & a
End Sub

Why don’t my P2P servants communicate with other servants on the Internet when they are behind a router?

Some routers have default communication restrictions called a “Firewall”. These restrictions are intended to prevent a virus from misusing your computer and to force you to explicitly disable them if and when you need more access to the Internet. One of the most common restrictions that harm P2P networks is when the router blocks most outgoing ports by default. You can test to see if your router is blocking a port by:

  1. Run a copy of the connection manager on a computer behind your router.
  2. On a computer outside the router on the Internet, open a DOS box and type in “telnet <ip router is on> 85”.
  3. Your connection manager on the computer behind the firewall should display:
    <peers>
        <peer>
            <ip>ip of peer</ip>
            <port>2224</port>
            <offset>1</offset>
            <me>FALSE</me>
        </peer>
    </peers>

If not then you need to enable port 85 in your router for the connection manager. This also has to be done for each peer behind a router with a built in firewall.

You can still leverage P2P technology on your personal network (behind your router) as long as all of your peers and your connection manager are behind your firewall. Each peer must be configured with the IP address of the connection manager that the router has assigned to it. I would highly suggest having the router assign the connection manager machine a static IP. This way, peers do not have to be reconfigured each time you reboot the box with the connection manager on it. The servants, however, can just get a dynamic IP address from your router every time they boot up because they will use the connection manager to resolve each other's location.

But I really need both servants behind routers and servants on the Internet to all be part of my P2P network.

This topic is outside the scope of this article, but in short here is one common solution used by other P2P technologies:

  1. Set your connection manager on a box that is intended to be a web server. If your connection manager is behind a router then configure your router to block all incoming ports but make the router forward port 85 connections to the machine that is running the connection manager.
  2. Have each servant report to the connection manager any peers that they are unable to contact. Have the connection manager determine if they are behind a port blocking router by seeing if the suspicious servant sends another heart beat. If most peers are complaining that they can’t connect to a suspicious servant but the suspicious servant continuously asks the connection manager for a user list then the connection manager can conclude that the servant is probably behind a port blocking router.
  3. If the connection manager makes this determination, have it notify the suspicious servant that it needs to pull from another peer. For the life of the suspicious servant instance, it pulls from another peer who publishes any data that it gets. The chosen peer must not itself be a suspicious peer behind a router.

This will slow the P2P network down but will allow peers behind port blocking routers to join the P2P network. I would not suggest having the connection manager just assume that a peer is suspicious instantly when the other peers complain about it, rather it should have a threshold of 2 or 3 complaints from each of the other peers before telling it that it is suspicious and assigning it a chosen peer to pull from.

Sample image

License

This article has no explicit license attached to it but may contain usage terms in the article text or the download files themselves. If in doubt please contact the author via the discussion board below.

A list of licenses authors might use can be found here

Share

About the Author

dzzxyz
Web Developer
United States United States
Keep on coding!

Comments and Discussions

 
GeneralMy vote of 5 Pinmember$t@t!c_V()1D24-May-12 4:04 
GeneralThanks, great code! Pinmemberitod18-Mar-09 1:02 
Generalhi!!! PinmemberAinJheL_mi28-Jun-06 0:29 
QuestionWhat if you can't run something on the server? Pinmemberteknarchy28-Sep-05 15:31 
Generalcommunicate between two servants each doesn't have global IP Pinmemberlvhuyen4-Jun-04 0:34 
GeneralRe: communicate between two servants each doesn't have global IP Pinmemberlvhuyen6-Jun-04 18:33 
GeneralThis article is worthless because this question is not answered Pinmemberkai122529-Jun-04 16:55 
GeneralServants Behind Router Pinmemberagentone28-May-04 3:55 
GeneralRe: Servants Behind Router PinmemberDaniel Stephen Rule28-May-04 4:37 
GeneralRe: Servants Behind Router Pinmemberagentone28-May-04 4:51 
GeneralRe: Servants Behind Router PinmemberDaniel Stephen Rule28-May-04 14:04 
GeneralRe: Servants Behind Router Pinmembercdemez17-Oct-06 2:31 
GeneralThis just what i need PinsussAnonymous20-Apr-04 10:24 
GeneralLinks / Hints for the firewall topic... PinmemberDKNYOli21-Mar-04 22:20 
GeneralRe: Links / Hints for the firewall topic... PinmemberDaniel Stephen Rule29-Mar-04 6:05 
GeneralAny C# code examples PinsussAnonymous18-Mar-04 10:50 
GeneralRe: Any C# code examples PinmemberAlex McMorris10-Mar-05 20:27 
GeneralA most excellent article PinmemberMetX17-Mar-04 4:44 
GeneralPerfect PinmemberJesterka17-Mar-04 0:01 
GeneralNuclear Waist Containment PinmemberDave Cross16-Mar-04 22:56 
Generalfirewall PinmemberJacee12-Mar-04 0:00 
GeneralRe: firewall PinmemberDanielStephenRule12-Mar-04 10:43 
GeneralKudos Pinmemberdd_tt9-Mar-04 16:39 
GeneralRe: Kudos PinmemberDerMeister11-Apr-04 3:57 
GeneralRe: Kudos PinmemberDaniel Stephen Rule11-Apr-04 7:57 

General General    News News    Suggestion Suggestion    Question Question    Bug Bug    Answer Answer    Joke Joke    Rant Rant    Admin Admin   

Use Ctrl+Left/Right to switch messages, Ctrl+Up/Down to switch threads, Ctrl+Shift+Left/Right to switch pages.

| Advertise | Privacy | Mobile
Web01 | 2.8.140916.1 | Last Updated 15 Mar 2004
Article Copyright 2004 by dzzxyz
Everything else Copyright © CodeProject, 1999-2014
Terms of Service
Layout: fixed | fluid