|
' ___________________________________________________
'
' � Hi-Integrity Systems 2007. All rights reserved.
' www.hisystems.com.au - Toby Wicks
' ___________________________________________________
'
''' --------------------------------------------------------------------------------
''' <summary>
''' This class extends DatabaseObjects by storing all objects associated with this
''' DatabaseObjects collection in memory. Any objects added via VolatileObjectAdd
''' or VolatileObjectDelete only affect the memory list until VolatileObjectsSave() is
''' called. VolatileObjectsSave will actually delete all objects in the database
''' and then save all objects in the memory list to the database.
''' </summary>
''' --------------------------------------------------------------------------------
'''
Public MustInherit Class DatabaseObjectsVolatile
Inherits DatabaseObjects
Implements IEnumerable
Private pobjParent As Object
Private pobjItems As IList
Private pobjItemsDeleted As IList = New ArrayList
''' --------------------------------------------------------------------------------
''' <summary>
''' Initializes a new DatabaseObjects with it's associated database.
''' </summary>
'''
''' <param name="objDatabase">
''' The database that this collection is associated with.
''' </param>
''' --------------------------------------------------------------------------------
Protected Sub New(ByVal objDatabase As Database)
MyBase.New(objDatabase)
pobjItems = MyBase.ObjectsList
End Sub
''' --------------------------------------------------------------------------------
''' <summary>
''' Initializes a new DatabaseObjects with it's associated database.
''' </summary>
'''
''' <param name="objDatabase">
''' The database that this collection is associated with.
''' </param>
'''
''' <param name="objParent">
''' The parent collection that this collection is associated with. This is often
''' useful so that the SubSet property can use the Parent to filter
''' by a particular value pertinent to the parent object. Using the object
''' is optional.
''' </param>
''' --------------------------------------------------------------------------------
Protected Sub New(ByVal objDatabase As Database, ByVal objParent As Object)
MyBase.New(objDatabase)
pobjParent = objParent
pobjItems = MyBase.ObjectsList
End Sub
''' --------------------------------------------------------------------------------
''' <summary>
''' Returns the parent object that this collection is associated with.
''' </summary>
''' --------------------------------------------------------------------------------
Protected ReadOnly Property Parent() As Object
Get
Return pobjParent
End Get
End Property
''' --------------------------------------------------------------------------------
''' <summary>
''' Adds an item to the in-memory list, and flags the item to be saved to the database
''' when VolatileObjectsSave() is called.
''' </summary>
''' --------------------------------------------------------------------------------
'''
Protected Sub VolatileObjectAdd(ByVal objItem As IDatabaseObject)
pobjItems.Add(objItem)
End Sub
''' --------------------------------------------------------------------------------
''' <summary>
''' Returns an item at the specific index in the in-memory list.
''' </summary>
''' --------------------------------------------------------------------------------
'''
Protected ReadOnly Property VolatileObjectByOrdinal(ByVal intIndex As Integer) As IDatabaseObject
Get
Return DirectCast(pobjItems(intIndex), IDatabaseObject)
End Get
End Property
''' --------------------------------------------------------------------------------
''' <summary>
''' Removes the item from the in-memory list, and flags the item to be deleted when
''' VolatileObjectsSave() is called.
''' </summary>
''' --------------------------------------------------------------------------------
'''
Protected Sub VolatileObjectDelete(ByVal objItem As IDatabaseObject)
pobjItemsDeleted.Add(objItem)
pobjItems.Remove(objItem)
End Sub
''' --------------------------------------------------------------------------------
''' <summary>
''' Firstly, all items flagged for deletion (via VolatileObjectDelete) are deleted
''' in the database.
''' Secondly, all items that have been added to the in-memory list (via VolatileObjectAdd)
''' are added/saved to the database.
''' </summary>
'''
''' <example>
''' <code>
''' Friend Sub SaveAll()
'''
''' Mybase.VolatileObjectsSave()
'''
''' End Sub
''' </code>
''' </example>
''' --------------------------------------------------------------------------------
'''
Protected Overridable Sub VolatileObjectsSave()
For Each objItem As IDatabaseObject In pobjItemsDeleted
Database.ObjectDelete(Me, objItem)
Next
For Each objItem As IDatabaseObject In pobjItems
Database.ObjectSave(Me, objItem)
Next
End Sub
''' --------------------------------------------------------------------------------
''' <summary>
''' Returns the number of items in the in-memory list.
''' </summary>
''' --------------------------------------------------------------------------------
'''
Protected ReadOnly Property VolatileObjectsCount() As Integer
Get
Return pobjItems.Count
End Get
End Property
''' --------------------------------------------------------------------------------
''' <summary>
''' Returns the enumerator for all objects currently in the in-memory list.
''' </summary>
''' --------------------------------------------------------------------------------
'''
Protected Function VolatileObjectsEnumerator() As System.Collections.IEnumerator Implements System.Collections.IEnumerable.GetEnumerator
Return pobjItems.GetEnumerator
End Function
End Class
|
By viewing downloads associated with this article you agree to the Terms of Service and the article's licence.
If a file you wish to view isn't highlighted, and is a text file (not binary), please
let us know and we'll add colourisation support for it.
This article has no explicit license attached to it but may contain usage terms in the article text or the download files themselves. If in doubt please contact the author via the discussion board below.
A list of licenses authors might use can be found here
This member has not yet provided a Biography. Assume it's interesting and varied, and probably something to do with programming.