A log4net Realtime Color Console for ASP.NET

Imports System.Net.Sockets
Imports System.Net
Module UdpLogListener
	Private ReadOnly Log As log4net.ILog = _
	 log4net.LogManager.GetLogger(System.Reflection.MethodBase.GetCurrentMethod().DeclaringType)

	Sub Main()

		Dim Port As Integer = 8081	   ' <-- remember to use the same port in your web/source app.
		Dim Sender As IPEndPoint
		Dim Client As UdpClient
		Dim Buffer As Byte()
		Dim LogLine As String

		Try
			Sender = New IPEndPoint(IPAddress.Any, 0)
			Client = New UdpClient(Port)

			While True
				Buffer = Client.Receive(Sender)
				LogLine = System.Text.Encoding.Default.GetString(Buffer)
				' The color	coded text is written to the console when Log.{level method} is called.
				' i.e. Log.Info("my info")
				' Optional: Replace your placeholders with whatever you like. [I]=Info, [D]=Debug, etc.
				'			More detail about placeholders in the UdpAppender config below.
				If LogLine.IndexOf("{INFO}") >= 0 Then
					Log.Info(LogLine.Replace("{INFO}", "[I] "))
				ElseIf LogLine.IndexOf("{DEBUG}") >= 0 Then
					Log.Debug(LogLine.Replace("{DEBUG}", "[D] "))
				ElseIf LogLine.IndexOf("{ERROR}") >= 0 Then
					Log.Error(LogLine.Replace("{ERROR}", "[E] "))
				ElseIf LogLine.IndexOf("{WARN}") >= 0 Then
					Log.Warn(LogLine.Replace("{WARN}", "[W] "))
				Else
					' Some other level.
					Log.Warn(LogLine)
				End If
			End While

		Catch e As Exception
			Console.WriteLine(e)
			Console.WriteLine(vbCrLf & "Press any key to close...")
			Console.ReadLine()
		End Try

	End Sub
End Module