Table of Contents
- Introduction
- Brief survey of the topic
- C# example
- XSL Features
- Brief survey of main XSL operators and constructions
- Usage of Cyrillic and East Asian fonts
- Building the bookmarks tree
- Building the table of contents
- Page numbering
- Logo insertion
- Hyperlink insertion
- Table rotation
- Gallery
- Conclusion
Introduction
There are lots of articles which describe how to convert XML documents to the documents of other types using the XSL Formatting Objects. Most of them describe how to obtain HTML from XML and only few tell about PDF documents.
Such articles usually demonstrate simple examples (how to build the table or perform the text output). But sometimes, we need to create representative reports or documents. In this case, developers face nontrivial problems – for example, creating the table of contents (using internal or external links), bookmark trees, picture galleries, etc. This article will help you to examine the main features of XSL schemes.
Brief Survey of the Topic
Generation of PDF documents is based on the Apache XML FOP technology that was initially written in Java language. But in our case, we use nFOP – the C# wrapper that is based on the Visual J#. This wrapper makes it easier to write pure .NET reporting modules. The generation of PDF documents is very simple and can be described in the following way:
We have an XML document (created by some application or manually) and XSLT scheme, with the help of which we obtain the XSL-FO document. The PDF file will be created on its basis. Then we compile the obtained XSL-FO document to PDF with the help of FOP.
C# Example
The process of PDF document generation can be described using a small example. Supposing there is a list of writers, who have their books and these books consist of articles, respectively:
This structure is represented by Author
and Book
classes.
public class Author
{
public List<Book> created;
public string name;
public int id;
...
}
public class Book
{
public int id;
public Props bookProps;
public List<Pare> articles;
...
}
C# language allows you to serialize any class to XML document. In this case, we can provide the following example:
FileStream fs = System.IO.File.Create("source.xml");
XmlSerializer s = new XmlSerializer(typeof(List<Author>));
List<Author> list = new List<Author>();
list.Add(writer);
list.Add(writer1);
s.Serialize(fs, list);
fs.Close();
Then, according to the scheme described above, the process of XLS-FO document generation is performed:
XslTransform xslt = new XslTransform();
xslt.Load("schema.xsl");
xslt.Transform("source.xml", "source.fo");
The last step is to call the methods of nfop
, which compiles XLS-FO to PDF:
java.io.FileInputStream streamFO = null;
java.io.FileOutputStream streamOut = null;
try
{
streamFO = new java.io.FileInputStream("source.fo");
streamOut = new java.io.FileOutputStream(fileName + ".pdf");
InputSource src = new InputSource(streamFO);
Driver driver = new Driver(src, streamOut);
driver.setRenderer(Driver.RENDER_PDF);
driver.run();
}
catch(FOPException ex)
{
Console.WriteLine(ex.Message);
throw;
}
catch (System.Exception ex)
{
Console.WriteLine(ex.Message);
throw;
}
finally
{
if (streamOut != null)
{
streamOut.close();
}
if (streamFO != null)
{
streamFO.close();
}
}
It is important to include the following references to the solution being developed:
vjslib.dll can be downloaded here.
nfop.dll can be downloaded here.
XSL Features
As it was mentioned above, the majority of articles about XSL-FO describe such common things as the output of the formatted text or the creation of tables. But often you need to add to the document:
- Table of contents with internal references to articles (taking into account that we do not know the page numbers beforehand as the document is generated dynamically)
- The bookmark tree (rather convenient tool for navigating in the document)
- Footnotes with definite blocks of the text and, perhaps, references to external web pages
- The picture gallery (it can be also dynamically saved by means of the C# language).
- The bookmark tree
- Table of contents with internal references to chapters of the document
- Page numbering
- Static picture (can be the company logo)
Brief Survey of Main XSL Operators and Constructions
XSL language includes all main constructions:
<xsl:if test="'condition'">
</xsl:if>
<xsl:choose>
<xsl:when test="'condition'">
</xsl:when>
<xsl:otherwise>
</xsl:otherwise>
</xsl:choose>
- for analog (processes a number of XML nodes with the same level of nesting):
<xsl:for-each select="Author">
</xsl:for-each>
You can access the definite node by index (if you know its number in the list beforehand):
<xsl:value-of select="/Column[1]"/>
Also you can use some variable as the index:
<xsl:variable name="index">
<xsl:value-of select="position()"/>
</xsl:variable>
...
<xsl:value-of select="Column[number($index)]"/>
number($index)
conversion returns the number, which was generated from the string
stored in $index
. If you do not use it, the $index
variable will possess “1
” as any value as is considered to be of the string
type by default.
If you use the position()
operator, it’s better to check also the condition:
<xsl:if test="position() != last()">
...
</xsl:if>
Here, position()
is the number of the current node of the XML document (last()
is the last in the list, respectively).
Usage of Cyrillic and East Asian Fonts
There is often a problem of using specific languages in reports. By default, they are not included in the list of nfop
fonts. To add new languages, you have to add a new font to the useconfig.xml file. The configuratiob file will look like the following:
="1.0"="UTF-8"
<configuration>
<fonts>
<font kerning="yes"
metrics-file="..\fonts\arialuni.xml" embed-file="..\fonts\arialuni.ttf">
<font-triplet name="arialuni" style="normal" weight="normal" />
<font-triplet name="arialuni" style="normal" weight="bold" />
<font-triplet name="arialuni" style="italic" weight="normal" />
<font-triplet name="arialuni" style="italic" weight="bold" />
</font>
</fonts>
</configuration>
Here, metrics-file
is a path to the font metric, embed-file
is a path to the font file.
In the example above, the standard arialuni.ttf font was added. It is a part of Windows OS (WINDOWS\Fonts\ARIALUNI.TTF) and is the most universal one. Fonts should be placed in the same folder as the configuration file.
Building the Bookmarks Tree
When building the bookmark tree (with references to the articles), you should specify an additional id
field in the nodes. With its help, references will be organized in the XSLT scheme.
We can create the static
class, which generates unique id
for each object that we need to refer to later:
public static class IDGenerator
{
private static int id = 0;
public static int Generate()
{
return id++;
}
}
Labels to refer on are placed when building the tables. We just add one more attribute to the current block, which will be used in references:
<fo:block>
<xsl:attribute name="id">
<xsl:value-of select="id"/>
</xsl:attribute>
</fo:block>
The process of building the tree is based on placing the blocks of such type:
<fox:outline>
<xsl:attribute name="internal-destination">
<xsl:value-of select="id"/>
</xsl:attribute>
<fox:label>
<xsl:value-of select="name"/>
</fox:label>
</fox:outline>
They can be placed as the nested ones and it will create the treelike structure.
Building the Table of Contents
The table of contents of the document is created in the similar way. The same id field (as in the previous example) is used for references:
<fo:basic-link>
<xsl:attribute name="internal-destination">
<xsl:value-of select="id"/>
</xsl:attribute>
<xsl:text>Chapter 1</xsl:text>
<fo:leader leader-pattern="dots"/>
<fo:page-number-citation>
<xsl:attribute name="ref-id">
<xsl:value-of select="id"/>
</xsl:attribute>
</fo:page-number-citation>
</fo:basic-link>
The <fo:leader leader-pattern="dots"/>
line fills space between the text and page number by dots.
Page Numbering
One more interesting moment is that we do not know exactly on which page the table will be located while building the PDF document. Here we can use an expression that will define the page number of the dynamically generated document automatically:
<fo:page-number-citation>
<xsl:attribute name="ref-id">
<xsl:value-of select="id"/>
</xsl:attribute>
</fo:page-number-citation>
Logo Insertion
XSL Templates allow you to create the static
content in any page region that will be repeated on each page. For example, the following code inserts the logo to the lower right corner of the document:
<fo:static-content flow-name="xsl-region-after" font-family="Arial">
<fo:block text-align="right" margin-right="25pt" >
<fo:external-graphic scaling="unifiorm" height="0.4in" width="1in"
src="file:///logo.JPG"/>
</fo:block>
</fo:static-content>
The building of the document frame can be organized in a similar way. You need to create four separate images for each border of the document (top, bottom, left and right), which can be then used as the background of the region (region-after
, region-before
, region-end
, region-start
).
Hyperlink Insertion
To insert external references, you can use the following construction:
<xsl:template name="ExternalLink">
<xsl:param name="link"/>
<xsl:param name="link_text"/>
<fo:basic-link font-size="10pt" font-weight="bold" color="blue">
<xsl:attribute name="external-destination">
<xsl:value-of select="$link"/>
</xsl:attribute>
<xsl:value-of select="$link_text"/>
</fo:basic-link>
</xsl:template>
Table Rotation
There is often a problem of displaying the tables with numerous columns. Such tables cannot be placed within the page borders.
Name
| Prop1
| Prop2
| Prop3
| …
| PropN
|
1
| Some data
| Some data
| Some data
| …
| Some data
|
2
| Some data
| Some data
| Some data
| …
| Some data
|
In this case, it is possible to perform table rotation, where a new table will correspond to each row:
Table 1 – first row
Name
| 1
|
Prop1
| Some data
|
Prop2
| Some data
|
Prop3
| Some data
|
…
| …
|
PropN
| Some data
|
Table 2 – second row
Name
| 2
|
Prop1
| Some data
|
Prop2
| Some data
|
Prop3
| Some data
|
…
| …
|
PropN
| Some data
|
Sometimes there is a nonstandard situation when it is necessary to process the data, which is stored in two related lists of nodes of the XML document. For example, you need to fill in the table where the first column Columns
contains the name of the data, the second one - Rows
- contains its values.
<Columns>
<Column>
<Title>Name</Title>
</Column>
<Column>
<Title>Phone Number</Title>
</Column>
</Columns>
<Rows>
<Row>
<Value>
<Link>Johny</Link>
</Value>
<Value>
<Link>555-55-55</Link>
</Value>
</Row>
<Row>
<Value>
<Link>Ann</Link>
</Value>
<Value>
<Link>333-60-00</Link>
</Value>
</Row>
</Rows>
To create the table from the given XML document, you can use the following pattern:
<xsl:template name="ParallelReading">
<xsl:for-each select="Rows">
<fo:table>
<fo:table-column background-color="#DCDCDC" column-width="20%"/>
<fo:table-column background-color="#FFFFFF" />
<fo:table-body>
<xsl:for-each select="Row">
<fo:table-row>
<fo:table-cell padding="4pt" border="1pt solid black">
<xsl:for-each select="../../Columns/Column">
<fo:block>
<xsl:value-of select="Title"/>
</fo:block>
</xsl:for-each>
</fo:table-cell>
<fo:table-cell padding="4pt" border="1pt solid black">
<xsl:for-each select="Value">
<fo:block>
<xsl:value-of select="Link"/>
</fo:block>
</xsl:for-each>
</fo:table-cell>
</fo:table-row>
</xsl:for-each>
</fo:table-body>
</fo:table>
</xsl:for-each>
</xsl:template>
Gallery
The process of creating the picture gallery can be described in the following way:
- The required pictures are saved to the temporary folder on the hard drive (programmatically).
- The XML document is created. It contains the full paths and the description of the saved files (this data will be used later in the XSLT scheme).
- The PDF document is generated. Pictures from the temporary folder are built in it.
- The temporary folder with its contents is deleted.
<Galery xmlns:xsi=http://www.w3.org/2001/XMLSchema-instance
xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<Picture>
<Pare>
<Name>Name</Name>
<Value>Blue hills</Value>
</Pare>
<Pare>
<Name>Path</Name>
<Value>E:/pdf_root/Blue hills.jpg</Value>
</Pare>
<Pare>
<Name>Size</Name>
<Value>28 521 bytes</Value>
</Pare>
<Pare>
<Name>Type</Name>
<Value>JPG File</Value>
</Pare>
<Pare>
<Name>Created</Name>
<Value>12 may 2010, 15:01:36</Value>
</Pare>
</Picture>
...
</Galery>
The pattern, which builds the gallery, is given below:
<fo:block text-align="center" font-size="25pt">
Gallery
</fo:block>
<fo:block>
<fo:table>
<fo:table-column/>
<fo:table-body>
<fo:table-row>
<fo:table-cell padding="2pt" border="1pt solid indigo" background-color="silver">
<fo:block>
<fo:table>
<fo:table-column column-width="1.5in"/>
<fo:table-column/>
<fo:table-body>
<xsl:for-each select="Galery/Picture">
<fo:table-row>
<fo:table-cell padding="2pt" border="0.75pt solid black"
background-color="lightgray">
<fo:block>
<fo:external-graphic display-align="center"
content-height="scale-to-fit" height="1.5in"
content-width="scale-to-fit">
<xsl:attribute name="src">
<xsl:value-of select="concat('file:',Pare[number(2)]/Value)"/>
</xsl:attribute>
</fo:external-graphic>
</fo:block>
</fo:table-cell>
<fo:table-cell padding="2pt" border="0.75pt solid black"
background-color="lightgray">
<fo:table>
<fo:table-column column-width="0.7in"/>
<fo:table-column/>
<fo:table-body>
<xsl:for-each select="Pare">
<fo:table-row>
<fo:table-cell padding="2pt" border="0.5pt solid black"
background-color="lavender">
<fo:block font-size="7pt" padding="2pt" >
<xsl:value-of select="Name"/>
</fo:block>
</fo:table-cell>
<fo:table-cell padding="2pt" border="0.5pt solid black"
background-color="lightgoldenrodyellow">
<fo:block font-size="7pt" padding="2pt" >
<xsl:value-of select="Value"/>
</fo:block>
</fo:table-cell>
</fo:table-row>
</xsl:for-each>
</fo:table-body>
</fo:table>
</fo:table-cell>
</fo:table-row>
</xsl:for-each>
</fo:table-body>
</fo:table>
</fo:block>
</fo:table-cell>
</fo:table-row>
</fo:table-body>
</fo:table>
</fo:block>
As a result, we receive the following table:
Conclusion
In this article, we introduced a brief description of creating the PDF report using the existing data in the program. Also we gave a brief survey of main constructions and operators of the XSL language. There are a lot of simple but rather nonstandard situations when we need to transpose tables, move between levels in the XML document, and create picture galleries.
For additional information, see the following links:
I hope that this article will be useful while developing your applications.
History
- 06/18/2010 - Source archive updated
- 06/22/2010 - Source archive updated
ApriorIT is a software research and development company specializing in cybersecurity and data management technology engineering. We work for a broad range of clients from Fortune 500 technology leaders to small innovative startups building unique solutions.
As Apriorit offers integrated research&development services for the software projects in such areas as endpoint security, network security, data security, embedded Systems, and virtualization, we have strong kernel and driver development skills, huge system programming expertise, and are reals fans of research projects.
Our specialty is reverse engineering, we apply it for security testing and security-related projects.
A separate department of Apriorit works on large-scale business SaaS solutions, handling tasks from business analysis, data architecture design, and web development to performance optimization and DevOps.
Official site: https://www.apriorit.com
Clutch profile: https://clutch.co/profile/apriorit
This member has not yet provided a Biography. Assume it's interesting and varied, and probably something to do with programming.