.NET (Core and Framework)

nagham_4ng wrote:

I guess that the prom

Bastard Programmer from Hell
If you can't read my code, try converting it here[^]

Quote:

... Our field engineers making changes to screens typically use laptops to edit screens that run on 23" monitors, so every time they open a screen, WF graciously resizes them (thanks MS!).

Imports System.ComponentModel
Imports System.Runtime.InteropServices

Public Class FormWithDesignSize
   Inherits Form
   Private Const DefaultMax As Int32 = 2000 'set this to whatever you need

   Private _MaxDesignWidth As Int32 = DefaultMax
   Private _MaxDesignHeight As Int32 = DefaultMax

   <Category("Design")> _
   <DisplayName("MaxDesignWidth")> _
   Public Property aaa_MaxDesignWidth() As Int32  'Prefix aaa_ is to force Designer code placement before ClientSize setting
      Get                                         ' avoids need to write customer serializer code
         Return _MaxDesignWidth
      End Get
      Set(ByVal value As Int32)
         _MaxDesignWidth = value
      End Set
   End Property

   <Category("Design")> _
   <DisplayName("MaxDesignHeight")> _
   Public Property aaa_MaxDesignHeight() As Int32  'Prefix aaa_ is to force Designer code placement before ClientSize setting
      Get                                          ' avoids need to write customer serializer code
         Return _MaxDesignHeight
      End Get
      Set(ByVal value As Int32)
         _MaxDesignHeight = value
      End Set
   End Property


   Protected Overrides Sub SetBoundsCore(ByVal x As Int32, ByVal y As Int32, ByVal width As Int32, ByVal height As Int32, ByVal specified As BoundsSpecified)
      If Me.DesignMode Then
         ' The Forms.Form.SetBoundsCore method limits the size based on SystemInformation.MaxWindowTrackSize

         ' From the GetSystemMetrics function documentation for SMCXMINTRACK: 
         '   "The minimum tracking width of a window, in pixels. The user cannot drag the window frame to a size 
         '    smaller than these dimensions. A window can override this value by processing the WMGETMINMAXINFO
         '    message."
         ' See: http://msdn.microsoft.com/en-us/library/windows/desktop/ms724385%28v=vs.85%29.aspx

         ' This message also appears to control the size set by the MoveWindow API, 
         ' so it is intercepted and the maximum size is set to MaxWidth by MaxHeight
         ' in the WndProc method when in DesignMode.

         ' Form.SetBoundsCore ultimately calls Forms.Control.SetBoundsCore that calls SetWindowPos but, 
         ' MoveWindow will be used instead to set the Window size when in the designer as it requires less
         ' parameters to achieve the desired effect.

         MoveWindow(Me.Handle, Me.Left, Me.Top, width, height, True)
      Else
         MyBase.SetBoundsCore(x, y, width, height, specified)
      End If
   End Sub

   Private Const WMGETMINMAXINFO As Int32 = &H24
   Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
      MyBase.WndProc(m)
      If Me.DesignMode AndAlso m.Msg = WMGETMINMAXINFO Then

         Dim MMI As New MINMAXINFO
         ' retrieve default MINMAXINFO values from the structure pointed to by m.LParam
         Marshal.PtrToStructure(m.LParam, MMI)

         ' reset the ptMaxTrackSize value
         MMI.ptMaxTrackSize = New POINTAPI(_MaxDesignWidth, _MaxDesignHeight)

         ' copy the modified structure back to LParam
         Marshal.StructureToPtr(MMI, m.LParam, True)
      End If

   End Sub

   <StructLayout(LayoutKind.Sequential)> _
   Private Class MINMAXINFO
       Public ptReserved As POINTAPI
       Public ptMaxSize As POINTAPI
       Public ptMaxPosition As POINTAPI
       Public ptMinTrackSize As POINTAPI
       Public ptMaxTrackSize As POINTAPI
   End Class

    <System.Runtime.InteropServices.StructLayout(Runtime.InteropServices.LayoutKind.Sequential)> _
    Public Structure POINTAPI
      Public X As Int32
      Public Y As Int32

      Public Sub New(ByVal X As Int32, ByVal Y As Int32)
         Me.X = X
         Me.Y = Y
      End Sub

      Public Overrides Function ToString() As String
         Return "(" & X.ToString() & ", " & Y.ToString() & ")"
      End Function
    End Structure

    <DllImport("user32.dll")> _
    Private Shared Function MoveWindow(ByVal hWnd As IntPtr, ByVal x As Int32, ByVal y As Int32, ByVal nWidth As Int32, ByVal nHeight As Int32, ByVal bRepaint As Boolean) As Boolean
    End Function

End Class