I can't uderstand output, so i will show how to open and read *.txt file line by line using Open dialog box.
Sub GetDX200Data()
Dim sFileName As String, iNumFile As Integer
Dim sTmp As String, dstWsh As Worksheet
Dim iRow As Long
'On error goto Error handler
On Error GoTo Err_GetDX200Data
'set variable for destination worksheet
Set dstWsh = ThisWorkbook.Worksheets(1)
'get *.txt file name
sFileName = GetMyFileName()
'in case of Cancel button was pressed
If sFileName = "" Then GoTo Exit_GetDX200Data
'start import from first row
iRow = 1
'to open *.txt file, get number
iNumFile = FreeFile()
'open *.txt file
Open sFileName For Input As iNumFile
'until it's not then end of file
Do While Not EOF(iNumFile)
'read line to variable sTmp
Line Input #iNumFile, sTmp
'insert data into cell
dstWsh.Range("A" & iRow) = sTmp
'increase counter
iRow = iRow + 1
Loop
'close file
Close #iNumFile
Exit_GetDX200Data:
On Error Resume Next
'free memory used for object variable: worksheet
Set dstWsh = Nothing
Exit Sub
Err_GetDX200Data:
MsgBox Err.Description, vbExclamation, Err.Number
'goto Exit
Resume Exit_GetDX200Data
End Sub
And function used for call Open dialog box
'return: file name with path
Function GetMyFileName() As String
Dim sTmp As Variant 'subtype: String
sTmp = Application.GetOpenFilename("Text Files (*.txt),*.txt", 0, "Open DX file...", "Open", False)
'in case of 'Cancel' pressed
If CStr(sTmp) = CStr(False) Then sTmp = ""
GetMyFileName = CStr(sTmp)
End Function
Submit an article or tip