Vb.net group by and max value of records...

Question

0.00/5 (No votes)

See more:

Source Table

Ct	Ad	Qua	Price
A	1	34	700
A	2	53	600
A	3	654	500
B	3	45	1200
B	53	434	500
B	5	63	200
B	3	35	200
B	5	63	100 
C	31	45	2200
C	53	434	500
C	51	63	200
C	32	235	200
C	52	63	100

Result Table
Ct	Ad	Qua	Price 
A	1	34	700
B	3	45	1200
C	31	45	2200

What I have tried:

I want to linq query for that result table in vb.net.
"Ct" field must be groupped and i will get in that group "price" max.

My english is not good. Thank you very much.

Posted 12-Feb-20 4:49am

luthier

Updated 12-Feb-20 5:51am

v3

Add a Solution

2 solutions

Add a Solution

Add your solution here

Treat my content as plain text, not as HTML

Preview 0

…

Existing Members

Sign in to your account

...or Join us

Download, Vote, Comment, Publish.

Your Email
Password
Forgot your password?

Your Email
This email is in use. Do you need your password?
Optional Password

I have read and agree to the Terms of Service and Privacy Policy
Please subscribe me to the CodeProject newsletters

When answering a question please:

Read the question carefully.
Understand that English isn't everyone's first language so be lenient of bad spelling and grammar.
If a question is poorly phrased then either ask for clarification, ignore it, or edit the question and fix the problem. Insults are not welcome.
Don't tell someone to read the manual. Chances are they have and don't get it. Provide an answer or move on to the next question.

Let's work to help developers, not make them feel stupid.

This content, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)

Maciej Los · Accepted Answer · 2020-02-12T05:11:00

Check this out:

VB.NET

Dim dt As DataTable = New DataTable()
dt.Columns.AddRange(New DataColumn(){
		New DataColumn("Ct", Type.GetType("System.String")),
		New DataColumn("Ad", Type.GetType("System.Int32")),
		New DataColumn("Qua", Type.GetType("System.Int32")),
		New DataColumn("Price", Type.GetType("System.Int32"))})
dt.Rows.Add(New Object(){"A", 1, 34, 700})
dt.Rows.Add(New Object(){"A", 2, 53, 600})
dt.Rows.Add(New Object(){"A", 3, 654, 500})
dt.Rows.Add(New Object(){"B", 3, 45, 1200})
dt.Rows.Add(New Object(){"B", 53, 434, 500})
dt.Rows.Add(New Object(){"B", 5, 63, 200})
dt.Rows.Add(New Object(){"B", 3, 35, 200})
dt.Rows.Add(New Object(){"B", 5, 63, 100})
dt.Rows.Add(New Object(){"C", 31, 45, 2200})
dt.Rows.Add(New Object(){"C", 53, 434, 500})
dt.Rows.Add(New Object(){"C", 51, 63, 200})
dt.Rows.Add(New Object(){"C", 32, 235, 200})
dt.Rows.Add(New Object(){"C", 52, 63, 100})

Dim result = dt.AsEnumerable() _
	.GroupBy(Function(x) x.Field(Of String)("Ct")) _
	.Select(Function(grp) New With _
	{ _
		.Ct = grp.Key, _
		.Ad = grp.OrderByDescending(Function(x) x.Field(Of Integer)("Price")) _
			.Select(Function(x) x.Field(Of Integer)("Ad")).FirstOrDefault(), _
		.Qua = grp.OrderByDescending(Function(x) x.Field(Of Integer)("Price")) _
			.Select(Function(y) y.Field(Of Integer)("Qua")).FirstOrDefault(), _
		.Price = grp.Max(Function(z) z.Field(Of Integer)("Price")) _
	}) _
	.ToList()

Console.WriteLine(String.Format("{0} {1} {2} {3}", "Ct", "Ad", "Qua", "Price"))
For Each item In result
	Console.WriteLine(String.Format("{0} {1} {2} {3}", item.Ct, item.Ad, item.Qua, item.Price))
Next

Richard Deeming · Accepted Answer · 2020-02-12T05:51:00

Another solution:

Setup:

VB.NET

Dim dt As DataTable = New DataTable()
dt.Columns.AddRange(New DataColumn(){
    New DataColumn("Ct", GetType(String)),
    New DataColumn("Ad", GetType(Integer)),
    New DataColumn("Qua", GetType(Integer)),
    New DataColumn("Price", GetType(Integer))})
		
dt.Rows.Add(New Object(){"A", 1, 34, 700})
dt.Rows.Add(New Object(){"A", 2, 53, 600})
dt.Rows.Add(New Object(){"A", 3, 654, 500})
dt.Rows.Add(New Object(){"B", 3, 45, 1200})
dt.Rows.Add(New Object(){"B", 53, 434, 500})
dt.Rows.Add(New Object(){"B", 5, 63, 200})
dt.Rows.Add(New Object(){"B", 3, 35, 200})
dt.Rows.Add(New Object(){"B", 5, 63, 100})
dt.Rows.Add(New Object(){"C", 31, 45, 2200})
dt.Rows.Add(New Object(){"C", 53, 434, 500})
dt.Rows.Add(New Object(){"C", 51, 63, 200})
dt.Rows.Add(New Object(){"C", 32, 235, 200})
dt.Rows.Add(New Object(){"C", 52, 63, 100})

Query:

VB.NET

Dim result As DataTable = dt.AsEnumerable().
    GroupBy(Function(r) r.Field(Of String)("Ct"), Function(key, rows) rows.OrderByDescending(Function(r) r.Field(Of Integer)("Price")).First()).
    CopyToDataTable()

Vb.net group by and max value of records...

2 solutions

Solution 1

Solution 2

Add your solution here

Preview 0