Visual Basic

Imports System
Imports System.Runtime.Remoting
Imports System.Collections

Serializable()> _
Public Class SubmitEventArgs
    Inherits EventArgs

    Private message As String = Nothing
    Private userName As String = Nothing

    Public Sub New(ByVal contribution As String, _
        ByVal contributor As String)
        Me.message = contribution
        Me.userName = contributor
    End Sub ' New

    Public ReadOnly Property Contribution() As String
        Get
            Return message
        End Get
    End Property

    Public ReadOnly Property Contributor() As String
        Get
            Return userName
        End Get
    End Property
End Class ' SubmitEventArgs

Public Delegate Sub SubmissionEventHandler(ByVal sender As Object, _
    ByVal submitArgs As SubmitEventArgs)

Public Class ChatCoordinator
    Inherits MarshalByRefObject
    Public Sub New()
        Console.WriteLine("ChatCoordinator created. Instance: " & _
            Me.GetHashCode().ToString())
    End Sub ' New

    Public Overrides Function InitializeLifetimeService() As Object
        Return Nothing
    End Function ' InitializeLifetimeService

    Public Event Submission As SubmissionEventHandler

    Public Sub Submit(ByVal contribution As String, _
        ByVal contributor As String)
        Console.WriteLine("{0} says: {1}.", _
            contributor, contribution)
        Dim e As New SubmitEventArgs(contribution, contributor)
        Console.WriteLine("Broadcasting...")
        RaiseEvent Submission(Me, e)
    End Sub ' Submit
End Class ' ChatCoordinator

Imports System
Imports System.Diagnostics
Imports System.Runtime.Remoting
Imports System.Runtime.Remoting.Channels

Public Class Server
    Public Shared Sub Main()
        RemotingConfiguration.Configure("Central.config")
        Console.WriteLine("The host application is currently " & _
            "running. Press Enter to exit.")
        Console.ReadLine()
    End Sub ' Main
End Class ' Server

configuration>
    system.runtime.remoting>
        application>
            service>
                wellknown
                    mode="Singleton"
                    type="ChatCoordinator, ChatCoordinator"
                    objectUri="Chat"
                />
            /service>
            channels>
                channel ref="http" port="8080" />
            /channels>
        /application>
    /system.runtime.remoting>
/configuration>

Imports System
Imports System.Runtime.Remoting
Imports System.Runtime.Remoting.Channels
Imports Microsoft.VisualBasic

Public Class ChatClient
    Inherits MarshalByRefObject

    Public Overrides Function InitializeLifetimeService() As Object
        Return Nothing
    End Function

    Private userName As String = Nothing

    Public Sub New(ByVal [alias] As String)
        Me.userName = [alias]
    End Sub

    Public Sub Run()
        RemotingConfiguration.Configure("Client.config")
        Dim chatCenter As New ChatCoordinator
        AddHandler chatCenter.Submission, AddressOf _
            Me.SubmissionReceiver
        Dim userInput As String = ""
        While True
            Console.WriteLine("Press 0 (zero) and ENTER to Exit:")
            userInput = Console.ReadLine()
            If userInput = "0" Then Exit While
            chatCenter.Submit(userInput, userName)
        End While
        RemoveHandler chatCenter.Submission, AddressOf _
            Me.SubmissionReceiver
    End Sub

    Public Sub SubmissionReceiver(ByVal sender As Object, _
        ByVal args As SubmitEventArgs)
        If args.Contributor = userName Then
            Console.WriteLine("Your message was broadcast.")
        Else
            Console.WriteLine(args.Contributor & " says: " & _
                args.Contribution)
        End If
    End Sub ' SubmissionReceiver

    Public Shared Sub Main()
        Dim args() As String = Environment.GetCommandLineArgs()
        If args.Length <> 2 Then
            Console.WriteLine("You need to type an alias.")
            Return
        End If
        Dim client As New ChatClient(args(1))
        client.Run()
    End Sub ' Main
End Class ' ChatClient

configuration>
    system.runtime.remoting>
        application>
            client>
                wellknown
                    type="ChatCoordinator, ChatCoordinator"
                    url="http://localhost:8080/Chat"
                />
            /client>
            channels>
                channel ref="http" port="0" />
            /channels>
        /application>
    /system.runtime.remoting>
/configuration>

vbc /t:library CChatCoordinator.vb<br />
vbc /r:CChatCoordinator.dll CServer.vb<br />
vbc /r:CChatCoordinator.dll CChatClient.vb