Visual Basic

27-Dec-13 17:33

Hello all!
I am working on a program that I hope will get me more familiar with Visual Basic. I have done lots of programming in other languages, and tons of VBA programming, but this is the first time I am trying to make something completely in VB.

The project is a screensaver that displays photos from a specified folder. The photos should pan and zoom in a pleasing fashion. Eventually I would like to add a fade effect between photos.

To get started I found an excellent photo screensaver project here:
http://blogs.msdn.com/b/vbteam/archive/2009/01/23/an-updated-screensaver-example-matt-gertz.aspx?Redirected=true[^]

Matt Gertz put together a fantastic project that does almost exactly what I want. So I modified the code a bit and use a second timer(1ms) on the form to control the animation of the images. Clearly I have no idea what I am doing, but I did get the basic sliding and zooming effects using things like:

Me.PictureBox1.Left = Me.PictureBox1.Left - 1
Me.PictureBox1.Height = Me.PictureBox1.Height + 1
Me.PictureBox1.Width = CInt(Me.PictureBox1.Height * SizeRatio)

Now that I have thoroughly wet my toes in VB, I wanted to stop in and ask the experts. I know that I am going about this image moving thing all wrong. I should probably be using some kind of ActiveX or OpenGL, or some other graphics engine.

Would any of you be kind enough to point me in the right direction?

Some sample VB projects would be immensely helpful.
In the meantime I will continue to play around with this. There are many flaws that I am happy to discuss if anyone wants. I could send the entire project I have edited if it would be helpful.

Thanks for your time and I look forward to your replies.
Nate

(It's probably worth mentioning that I am running VB Express 2010 on Windows 7 64 Pro.)

Eddy Vluggen29-Dec-13 3:13

29-Dec-13 3:13

Member 10488758 wrote:
I know that I am going about this image moving thing all wrong.

Nope, sounds like a good idea to use controls for this purpose. They're not optimized to be animated though. There's a different set that is, but more on that at the end of this post.

Alternatively, you could check out the forms' properties; it has an OnPaint[^] handler that you can override. You could nicely draw a bitmap offscreen (in a separate thread) and paint it when ready.

Protected Overrides Sub OnPaint(e As PaintEventArgs)
	MyBase.OnPaint(e)
	Using b = _generation.GenerateBitmap()
		e.Graphics.InterpolationMode = InterpolationMode.NearestNeighbor
		e.Graphics.PixelOffsetMode = PixelOffsetMode.Half
		e.Graphics.DrawImage(b, 0, 0, Width, Height)
	End Using
End Sub

Member 10488758 wrote:
I should probably be using some kind of ActiveX or OpenGL

You'd like to dive into the world of WPF[^]. It also uses Forms and Controls, but these are a bit more modern, and rendered using DirectX. Additionally there'll be easier animations, gradients and more of the like Smile | :)

Found two articles on CodeProject related to WPF Screensavers, but both are aiming at C#. There's no specific example for VB.NET (hint, hint)

Bastard Programmer from Hell Suspicious | :suss:

If you can't read my code, try converting it here[^]

Nate Schoonover29-Dec-13 5:37

29-Dec-13 5:37

Thanks for the info Eddy! Are you suggesting that VB probably isn't the best way to program a screensaver? LOL I have always hated C, but I can pick it back up if I need to. If I can make this program work it would be much easier since the majority of it has already been written for me!

Eddy Vluggen29-Dec-13 17:15

29-Dec-13 17:15

You're welcome Smile | :)

Nate Schoonover wrote:
Are you suggesting that VB probably isn't the best way to program a screensaver?

Depends on what you are doing; it's not VB that's slowing your graphics down, but WinForms.

Bastard Programmer from Hell Suspicious | :suss:

If you can't read my code, try converting it here[^]

Nate Schoonover31-Dec-13 9:00

31-Dec-13 9:00

Thanks again. Can you help me understand this a bit more? How is WinForms slowing the graphics, and how can I skip it?

I think that I should not be using the form timer for animations this seems hacky, and there is not much control over speed or framerate.

I would love to get this working in an ideal way with VB. I already have a solid working example that I would love to post for critique. Is anyone willing to help me fine tune this program a bit? And how can I post an example project here (if that is allowed)?

Eddy Vluggen2-Jan-14 9:18

2-Jan-14 9:18

Nate Schoonover wrote:
How is WinForms slowing the graphics, and how can I skip it?

The WinForm api is a set of controls, not designed with great graphics in mind - graphics cards didn't require dedicated coolers in those days. It doesn't use DirectX like WPF would, it would use the CPU for drawing.

Nate Schoonover wrote:
there is not much control over speed or framerate.

One doesn't control the framerate under Windows; Windows dictates how much CPU time your app will get, and then you go for the maximum amount of frames.

Now, you could draw yourself on a (base) WinForm, which means that it'll speed up a bit, since it requires one less picturebox is resources.

Nate Schoonover wrote:
And how can I post an example project here (if that is allowed)?

If you're planning to write an article on the subject, then that would be the place to upload the code. It'd be "in draft" and invisible, until it's working ofc Smile | :)

Bastard Programmer from Hell Suspicious | :suss:

If you can't read my code, try converting it here[^]

Nate Schoonover2-Jan-14 11:37

2-Jan-14 11:37

Thanks Eddy! I will get rid of the picturebox as you suggested, one less thing to slow things down. I think writing up a draft would be a good idea. I will post it in a few days.

I have a few other things I need to sort out first. I am having trouble with loading settings using the base code I borrowed from Gertz. http://blogs.msdn.com/b/vbteam/archive/2009/01/23/an-updated-screensaver-example-matt-gertz.aspx?[^]

Most of the example code works great, but when I install the screensaver and use the config mode to define the source folder and other settings, the final settings are not used when the screen saver executes via Windows.

This is strange because the settings are used correctly in preview mode. However, when the Windows timer sets off the screensaver all the settings go back to default. This is the correct behavior if the screensaver does not detect any previous settings, but I can't figure out why it would load settings correctly in preview mode and not the regular mode.

The settings are being stored correctly in the User\AppData folder. There is nothing obviously wrong with the code, I am afraid I am missing something stupid.

For what it's worth I posted the code to the Options form below, but I recon you will have to see it all together to really understand it.

Options.vb

Option Strict On

Imports System.Collections.ObjectModel

''' <summary>
''' This is the class that holds the Options information.  The Options information
'''   is defined as a class so that it can be easily serialized and deserialized.
''' </summary>
''' <remarks></remarks>
Public Class Options

#Region "Member variables"
    Private m_Speed As Integer = 3 'in seconds
    Private m_ShowTags As Boolean = True
    Private m_ShowDates As Boolean = True
    Private m_UseSubdirectories As Boolean = True
    Private m_Directory As String = "" 'directory to pull photos from
    Private m_files As ReadOnlyCollection(Of String) ' List of files
#End Region

#Region "Class Properties"
    ''' <summary>
    ''' Set or get whether or not to show the date
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property ShowDate() As Boolean
        Get
            Return m_ShowDates
        End Get
        Set(ByVal Value As Boolean)
            m_ShowDates = Value
        End Set
    End Property

    ''' <summary>
    ''' Set or get whether or not to look in subdirectories for pictures
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property UseSubdirectories() As Boolean
        Get
            Return m_UseSubdirectories
        End Get
        Set(ByVal Value As Boolean)
            m_UseSubdirectories = Value
        End Set
    End Property

    ''' <summary>
    ''' Set or get whether or not to show tags
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property ShowTags() As Boolean
        Get
            Return m_ShowTags
        End Get
        Set(ByVal Value As Boolean)
            m_ShowTags = Value
        End Set
    End Property

    ''' <summary>
    ''' Set or get which directory to look in for pictures
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property Directory() As String
        Get
            Return m_Directory
        End Get
        Set(ByVal Value As String)
            m_Directory = Value
        End Set
    End Property

    ''' <summary>
    ''' Set or get what speed at which to show pictures
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property Speed() As Integer
        Get
            Return m_Speed
        End Get
        Set(ByVal Value As Integer)
            m_Speed = Value
        End Set
    End Property

#End Region

#Region "Class Methods"
    ''' <summary>
    ''' This function loads the user defined options from the application settings file.
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub LoadOptions()
        Me.Speed = 16 'My.Settings.Speed
        Me.ShowDate = My.Settings.ShowDate
        Me.ShowTags = My.Settings.ShowTags
        Me.Directory = My.Settings.Directory
        Me.UseSubdirectories = My.Settings.UseSubdirectories

        If String.IsNullOrEmpty(Me.Directory) Then ' Default to "My Pictures" if not initialized
            Me.Directory = My.Computer.FileSystem.SpecialDirectories.MyPictures
         end If

        If Me.UseSubdirectories = True Then
            m_files = My.Computer.FileSystem.GetFiles(Me.Directory, FileIO.SearchOption.SearchAllSubDirectories, "*.jpg")
        Else
            m_files = My.Computer.FileSystem.GetFiles(Me.Directory, FileIO.SearchOption.SearchTopLevelOnly, "*.jpg")
        End If

    End Sub

    ''' <summary>
    ''' This function saves the user defined options to the application settings file.
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub SaveOptions()
        My.Settings.Speed = Me.Speed
        My.Settings.ShowDate = Me.ShowDate
        My.Settings.ShowTags = Me.ShowTags
        If Not String.IsNullOrEmpty(Directory) Then ' Don't bother saving
            My.Settings.Directory = Me.Directory
            My.Settings.Save()
        End If
        My.Settings.UseSubdirectories = Me.UseSubdirectories
        My.Settings.Save()


        If Me.UseSubdirectories = True Then
            m_files = My.Computer.FileSystem.GetFiles(Me.Directory, FileIO.SearchOption.SearchAllSubDirectories, "*.jpg")
        Else
            m_files = My.Computer.FileSystem.GetFiles(Me.Directory, FileIO.SearchOption.SearchTopLevelOnly, "*.jpg")
        End If

    End Sub

#End Region



End Class

And here is where the screensaver form is supposed to load the saved settings using the form's Load event:

Option Strict On

Imports System.Windows.Media.Imaging
Imports System.IO
Imports System.Collections.ObjectModel
Imports System.Collections.Generic

' This form is the main form for the screen saver. It does all the painting
'   of the screen, and handles when it should terminate and release control 
'   back to Windows.
Public Class frmScreenSaver

#Region "Variables"
    ' Declare the class variables that will be used for the Screen Saver.
    ' Options object that contains information about the user selected options
    Private m_Options As New Options()

    ' Random object to support the drawing
    Private m_Random As New Random()

    ' Used to for first setting MouseMove location
    Private m_IsActive As Boolean = False

    ' Used to determine if the Mouse has actually been moved
    Private m_MouseLocation As Point

    Private m_files As ReadOnlyCollection(Of String) ' List of files
    Private m_fileCount As Integer = 0
#End Region

#Region "Events"
    ''' <summary>
    ''' This subroutine initializes the Screen Saver form when it is loaded
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub frmSceenSaver_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Debug = False
        ' Load the Saved options. 
        m_Options.LoadOptions()

        ' Reset location of label
        SetLabelLocation()

        ' Set the speed based on the user defined Options.
        Me.tmrUpdateScreen.Interval = m_Options.Speed * 1000

        ' Enable the timers.
        Me.tmrUpdateScreen.Enabled = True
        Me.AnimationTimer.Enabled = True

        If m_Options.UseSubdirectories = True Then
            m_files = My.Computer.FileSystem.GetFiles(m_Options.Directory, FileIO.SearchOption.SearchAllSubDirectories, "*.jpg")
        Else
            m_files = My.Computer.FileSystem.GetFiles(m_Options.Directory, FileIO.SearchOption.SearchTopLevelOnly, "*.jpg")
        End If
        If m_files IsNot Nothing Then
            m_fileCount = m_files.Count
        Else
            Me.lblDescription.Text = "No pictures found!"
            SetLabelLocation()
        End If
        Windows.Forms.Cursor.Hide()
        If m_fileCount <> 0 Then
            DrawPicture()
        End If
    End Sub

I left off the rest of the event handles that control the picture drawing and animation, but if you think it would be helpful I can throw that up here too.

Thanks again for your time here! Just let me know if you have any questions about the code. I just can't figure out why the saved settings won't load when executing the screensaver in regular mode.

Nate

Eddy Vluggen4-Jan-14 3:41

4-Jan-14 3:41

Nate Schoonover wrote:
I think writing up a draft would be a good idea. I will post it in a few days.

Cool - loooking forward to the result Smile | :)

Nate Schoonover wrote:
The settings are being stored correctly in the User\AppData folder.

Your code looks good; if it were incorrect I'd expect it not to load in the preview-mode. I'm not sure whether a screensaver runs under the current users' credentials, or using a system-account. You could verify that by logging the Enivronment.UserName[^]. Next to that, there could be a difference in the current working-directory.

If you stay stuck, for say, a day or two, consider writing your own settings-class. Reading and writing that class to/from a file is fairly easy.

Bastard Programmer from Hell Suspicious | :suss:

If you can't read my code, try converting it here[^]

Nate Schoonover4-Jan-14 18:17

4-Jan-14 18:17

Thanks again Eddy. I am starting to think you are a one-man operation around here! I appreciate your patience!

Eddy wrote:
I'm not sure whether a screensaver runs under the current users' credentials, or using a system-account. You could verify that by logging the Environment.UserName.

Good idea! I checked and the user name remains the same regardless of execution method. Both the preview mode, and the regular mode indicate my Windows user name (Nate). It seems that the application is running strictly under my user credentials. My user account is not an administrator, but this is my computer so the admin account is locked up tight. I almost never use it.

I did notice that when running the config mode, if I click the "..." to open the folder dialog, the default folder is C:\Users\Nate\Pictures\... This is defined by the default folder assignment:

Me.Directory = My.Computer.FileSystem.SpecialDirectories.MyPictures

I can't navigate any higher than this with the dialog box that is given. I store my pictures under C:\Users\Public\Pictures\... and I can't navigate to this folder. I can't navigate beyond the My Pictures folder. This seems like a very restricted folder dialog box. I also couldn't find a Special.Directories assignment for a public folder via MSDN[^]. I know that I can access the public folders for the screensaver because when I hard code the folder location it works fine.

It looks like I may need to figure out my own settings file after all! I started digging around MSDN and found things like How to Persist User Settings[^]. As far as I can tell, this is exactly what Gertz used in his example screensaver.

Is there a better way to store basic application settings?

Eddy Vluggen5-Jan-14 1:25

DataGridView populates only first row

5-Jan-14 1:25

Nate Schoonover wrote:
I store my pictures under C:\Users\Public\Pictures\... and I can't navigate to this folder.

It should be accessible using the Explorer; if it's not, it won't be accessible from code either. It should be a writeable location under a default-installation. You can get the location with the snippet below;

Dim thePath As String = Environment.GetFolderPath(Environment.SpecialFolder.CommonPictures)

Nate Schoonover wrote:
Is there a better way to store basic application settings?

The advantage of the "My Settings"-editor in Visual Studio is that it's clean, well-documented and has a nice UI. The advantage of writing your own is having a bit more control. I've included a small example that shows how to serialize/deserialize a POCO using a BinaryFormatter. There are more formatters available, one of them being for XML.

Imports System.Runtime.Serialization.Formatters.Binary

Module Module1

    <Serializable()> _
    Public Class MySettings
        Public Property SomePath As String
        Public Property SomeInt As Integer
    End Class

    Sub Main()
        ' get location of public pictures
        Dim thePath As String = Environment.GetFolderPath(Environment.SpecialFolder.CommonPictures)

        ' Generate some settings
        Dim CurrentSettings As New MySettings
        CurrentSettings.SomePath = thePath
        CurrentSettings.SomeInt = 2

        ' Save settings
        Dim formatter As New BinaryFormatter
        Using s As New IO.FileStream(".\settings.bin", IO.FileMode.Create)
            formatter.Serialize(s, CurrentSettings)
        End Using

        ' Load settings again
        Dim PrevSavedSetting As MySettings
        Using s As New IO.FileStream(".\settings.bin", IO.FileMode.Open)
            PrevSavedSetting = formatter.Deserialize(s)
        End Using

        ' Write the settings we just read to screen
        Console.WriteLine(PrevSavedSetting.SomePath)
        Console.WriteLine(PrevSavedSetting.SomeInt)
        Console.ReadKey()
    End Sub

End Module

This will save (and read) the contents of the MySettings object in a file called "settings.bin" in the current working-directory of the application.

Happy coding Thumbs Up | :thumbsup:

Bastard Programmer from Hell Suspicious | :suss:

If you can't read my code, try converting it here[^]

Sonhospa27-Dec-13 9:16

Sonhospa

27-Dec-13 9:16

Hi,

I hope you all had a merry Christmas and nice holidays with your beloved ones! Rose | [Rose]

I try to retrieve data from text files and show them in a Datagrieview control. Each of the files is represented in an instance of "SoundConfigFile", which are collected in a generic List(of SoundConfigFile). The problem is: Only one row (containing the data collected from the first file) shows up in the Datagridview!?!

In the forms constructor, I set

dgvList.AutoGenerateColumns = True
dgvList.DataBindings.DefaultDataSourceUpdateMode = DataSourceUpdateMode.OnValidation

. The longer task of extracting the required data from files is handled in a separate thread:

Private Sub ThreadFunction()

    Try
        SoundConfigFiles = New List(Of SoundConfigFile)
        Dim dirs As String() = Directory.GetFiles(My.Settings.FSACDir, "sound.cfg", SearchOption.AllDirectories)
        Dim max As Integer = dirs.Count()
        Dim done As Integer = 0
        Dim percent As Integer = 0
        Dim msg As String = String.Empty

        For Each configfile As String In dirs
            SoundConfigFiles.Add(New SoundConfigFile(Me, configfile))
            done += 1
            percent = CInt(done / max * 100)
            msg = String.Format("{0} finished ({1}%)", configfile, percent)
            'update the UI thread
            UpdateForm(configfile, percent, msg)
        Next
    Catch ex As Exception
    End Try
End Sub 'ThreadFunction

The UI thread is then updated in

Public Sub UpdateForm(ByVal myItem As String, ByVal percent As Integer, ByVal msg As String)

    If Me.InvokeRequired Then
        Dim d As UpdateDelegate = AddressOf UpdateForm
        Me.Invoke(d, {myItem, percent, msg})
    Else
        Me.dgvList.DataSource = SoundConfigFiles
        Me.dgvList.Refresh()
        Me.ProgressBar1.Value = percent
        Me.myLabel.Text = msg
        Me.lblFinalMessage.Text = String.Format("{0} instances still open.", _
                                       SoundConfigFile.instances)

    End If
End Sub

I tried to find relevant information for hours now, but I can't get it to work. Does anyone of you have a good advice or can tell me what I'm doing wrong here? Confused | :confused:

Thank you,
Mick

Re: DataGridView populates only first row

Eddy Vluggen29-Dec-13 2:51

Re: DataGridView populates only first row

29-Dec-13 2:51

Let's see; we add item to a collection, set the datasource to the collection, get the next item. You stated that you only saw the first one.

Try setting the datasource to "null" before assigning the collection Smile | :)

Bastard Programmer from Hell Suspicious | :suss:

If you can't read my code, try converting it here[^]

Sonhospa29-Dec-13 7:08

Sonhospa

29-Dec-13 7:08

This works Big Grin | :-D

Thank you, Eddy! Cool | :cool:

But it's not enough to set the datasource to "Nothing" after startup (same result: only first row seen). I have do that (and afterwards assign the collection again) within the "UpdateUI" Sub. Doesn't that slow down the application massively? Is that a bug?

modified 29-Dec-13 13:41pm.

Re: DataGridView populates only first row

Eddy Vluggen29-Dec-13 17:12