how to download file from ftp server using vb.net 2008

Question

0.00/5 (No votes)

See more:

hi
I HAD used this below code but the issue is the copyto function are not supporting to ms 2008 .. it only work in ms 2010

can anybody help me ?? for this

VB

Dim ftp As String = "ftp://xxxxxxxxxx.com/"

        'FTP Folder name. Leave blank if you want to Download file from root folder.
        Dim ftpFolder As String = "downloads/"

        Try
            'Create FTP Request.
            Dim request As FtpWebRequest = DirectCast(WebRequest.Create(Convert.ToString(ftp & ftpFolder) & fileName), FtpWebRequest)
            request.Method = WebRequestMethods.Ftp.DownloadFile

            'Enter FTP Server credentials.
            request.Credentials = New NetworkCredential("xxxxxxx", "xxxxxxx")
            request.UsePassive = True
            request.UseBinary = True
            request.EnableSsl = False

            'Fetch the Response and read it into a MemoryStream object.
            Dim resp As FtpWebResponse = DirectCast(request.GetResponse(), FtpWebResponse)
            Using stream As New MemoryStream()
                'Download the File.
                resp.GetResponseStream().Copyto(stream)
                Response.AddHeader("content-disposition", "attachment;filename=" & fileName)
                Response.Cache.SetCacheability(HttpCacheability.NoCache)
                Response.BinaryWrite(stream.ToArray())
                Response.End()
            End Using
        Catch ex As WebException
            Throw New Exception(TryCast(ex.Response, FtpWebResponse).StatusDescription)
        End Try

[edit}Removed FTP address and credentials[/edit]

Posted 24-Jun-15 3:00am

Shaii.J

Updated 24-Jun-15 3:19am

hypermellow

v2

Add a Solution

1 solution

Add a Solution

Add your solution here

Treat my content as plain text, not as HTML

Preview 0

…

Existing Members

Sign in to your account

...or Join us

Download, Vote, Comment, Publish.

Your Email
Password
Forgot your password?

Your Email
This email is in use. Do you need your password?
Optional Password

I have read and agree to the Terms of Service and Privacy Policy
Please subscribe me to the CodeProject newsletters

When answering a question please:

Read the question carefully.
Understand that English isn't everyone's first language so be lenient of bad spelling and grammar.
If a question is poorly phrased then either ask for clarification, ignore it, or edit the question and fix the problem. Insults are not welcome.
Don't tell someone to read the manual. Chances are they have and don't get it. Provide an answer or move on to the next question.

Let's work to help developers, not make them feel stupid.

This content, along with any associated source code and files, is licensed under The Code Project Open License (CPOL)

Richard Deeming · Answer 1 · 2015-06-24T05:13:00

It's fairly simple to provide your own version of the CopyTo method:

C#:

C#

using System;
using System.IO;

public static class StreamExtensions
{
    public static void CopyTo(this Stream source, Stream destination)
    {
        if (source == null) throw new ArgumentNullException("source");
        if (destination == null) throw new ArgumentNullException("destination");
        if (!source.CanRead) throw new NotSupportedException("Cannot read from the source stream.");
        if (!destination.CanWrite) throw new NotSupportedException("Cannot write to the destination stream.");

        int bytesRead;
        byte[] buffer = new byte[81920];
        while ((bytesRead = source.Read(buffer, 0, buffer.Length)) != 0)
        {
            destination.Write(buffer, 0, bytesRead);
        }
    }
}

VB.NET:

VB.NET

Imports System.IO
Imports System.Runtime.CompilerServices

Public Module StreamExtensions
    <Extension> _
    Public Sub CopyTo(ByVal source As Stream, ByVal destination As Stream)
        If source Is Nothing Then
            Throw New ArgumentNullException("source")
        End If
        If destination Is Nothing Then
            Throw New ArgumentNullException("destination")
        End If
        If Not source.CanRead Then
            Throw New NotSupportedException("Cannot read from the source stream.")
        End If
        If Not destination.CanWrite Then
            Throw New NotSupportedException("Cannot write to the destination stream.")
        End If

        Dim buffer As Byte() = New Byte(81919) {}
        Dim bytesRead As Integer = source.Read(buffer, 0, buffer.Length)
        While bytesRead <> 0
            destination.Write(buffer, 0, bytesRead)
            bytesRead = source.Read(buffer, 0, buffer.Length)
        End While
    End Sub
End Module