MVP-VM (Model View Presenter - ViewModel) with Data Binding and BackgroundWorker in Windows Forms applications

Imports System.ComponentModel

Public Class SolverPresenter
    Private ReadOnly m_SolverViewModel As SolverViewModel
    Private ReadOnly m_Solver As AsynchronousSolver

    Public Sub New(ByVal solver As AsynchronousSolver)
        m_Solver = solver
        AddHandler m_Solver.AsyncCompleted, AddressOf Solver_AsyncCompleted
        m_SolverViewModel = New SolverViewModel(solver)
        m_SolverViewModel.InitializeBoundProperties()
    End Sub

    Public Event FindAsyncCompleted As AsyncCompletedEventHandler

    Public ReadOnly Property SolverViewModel As SolverViewModel
        Get
            Return m_SolverViewModel
        End Get
    End Property

    Public Sub FindClicked()
        With SolverViewModel
            .Answer = String.Empty
            .Validate()
            If .IsValid Then
                .UpdateModel()
                .ProgressBarVisible = True
                .ControlsEnabled = False
                m_Solver.FindSumOfMultiplesOfSeedsBelowMaxAsync()
            End If
        End With
    End Sub

    Public Sub CancelClicked()
        m_Solver.CancelAsync()
    End Sub

    Protected Overridable Sub OnFindAsyncCompleted(ByVal e As AsyncCompletedEventArgs)
        RaiseEvent FindAsyncCompleted(Me, e)
    End Sub

    Private Sub Solver_AsyncCompleted(ByVal sender As Object, ByVal e As AsyncCompletedEventArgs)
        OnFindAsyncCompleted(e)
        With SolverViewModel
            .ProgressPercentage = 0
            .ProgressBarVisible = False
            .ControlsEnabled = True
        End With
    End Sub
End Class