I need To Call a Sub Routine present in the Main Project from a Dll is that possible if yes how?

Public Class ClassCallBackTest
   ' Option 1, define your callback signature  as a method with a boolean paramter
   Public Delegate Sub CallBack(ByVal enable As Boolean)

   Private ConstructorPassedCallBack As CallBack ' local copy of Delegate passed in constructor

   Public Sub New(ByVal CallBack As CallBack)
      Me.ConstructorPassedCallBack = CallBack
   End Sub

   Public Sub CallTheCallBack()
      If ConstructorPassedCallBack IsNot Nothing Then ConstructorPassedCallBack(True)
   End Sub

   ' Option 2, pass then callback to the method needing to call it
   Public Sub CallACallBack(ByVal CallBack As CallBack, ByVal enable As Boolean)
      If CallBack IsNot Nothing Then CallBack(enable)
   End Sub

   ' Option 3, pass then callback as an Action(Of Boolean) to the method needing to call it
   ' This just a different way to define the required signature.
   Public Sub CallACallBack2(ByVal CallBack As System.Action(Of Boolean), ByVal enable As Boolean)
      If CallBack IsNot Nothing Then CallBack(enable)
   End Sub
End Class

Public Class Form1
   Private Sub CallBackMethod(ByVal enable As Boolean)
      MsgBox("Enabled = " & enable.ToString())
   End Sub

   Private Sub CallBackMethod2(ByVal enable As Boolean)
      MsgBox("CallBackMethod2 called.  Enabled = " & enable.ToString())
   End Sub

   Private Sub CallBackMethod3(ByVal enable As Boolean)
      MsgBox("CallBackMethod3 called.  Enabled = " & enable.ToString())
   End Sub

   Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
      Dim test As New ClassLibrary1.ClassCallBackTest(AddressOf CallBackMethod)
      test.CallTheCallBack() ' use the constructor callback

      test.CallACallBack(AddressOf CallBackMethod2, False)

      test.CallACallBack2(AddressOf CallBackMethod3, True)
   End Sub
End Class